label w04d03_s02:

    if denise_locked_out or macy_locked_out:

        if denise_have_coffee_ritual:
            scene kitchen_bg morning:
                subpixel True
                xalign 0.5 yalign 0.3 zoom 1.05
                0.5
                ease 8.3 zoom 1.0
            show denise_pd kitchen morning puggies holdcoffee:
                subpixel True
                xalign 0.5 yalign 0.3 zoom 1.1
                0.5
                ease 8.3 zoom 1.0
            with fade
            pause 1.2
            show kitchen_bg morning
            show denise_pd kitchen morning puggies givecoffee
            with dissolve

            deni "Here, [denise_adr_pc_as]."
            "You have your usual drink before setting off."
        else:

            scene kitchen_bg morning:
                subpixel True
                xalign 0.5 yalign 0.3 zoom 1.05
                0.5
                ease 8.3 zoom 1.0
            show denise_pd kitchen morning puggies neutral:
                subpixel True
                xalign 0.5 yalign 0.3 zoom 1.1
                0.5
                ease 8.3 zoom 1.0
            with fade
            "After saying goodbye to your [denise_rel_to_pc], you set off."

        scene black
        with fade

        jump w04d03_s02_end_scene

    "When your [denise_rel_to_pc] vacates the bathroom, you go in to finish up your preparations."
    "She's waiting for you in the kitchen when you return."

    if denise_have_coffee_ritual:

        scene kitchen_bg morning:
            subpixel True
            xalign 0.5 yalign 0.3 zoom 1.0
            0.5
            ease 38.3 zoom 1.1
        show denise_pd kitchen morning puggies holdcoffee:
            subpixel True
            xalign 0.5 yalign 0.3 zoom 1.0
            parallel:
                0.5
                ease 38.3 zoom 1.2
            parallel:
                1.2
                "denise_pd kitchen morning puggies givecoffee" with dissolve
        with fade

        pause 1.2

        deni "Here, [denise_adr_pc_as]."

        if w04d02_s03_picked_up_decaf:
            show kitchen_bg morning
            show denise_pd kitchen morning puggies neutral
            with dissolve
        else:
            show kitchen_bg morning
            show denise_pd kitchen morning puggies smile
            with dissolve

        pc "Thank you, angel."

        if w04d02_s03_picked_up_decaf:
            if pc_coffee == "tea":
                pc "Herbal?"

                show kitchen_bg morning
                show denise_pd kitchen morning puggies smile
                with dissolve
                if w04d02_s02_liked_decaf:
                    deni "Yeah."
                else:
                    deni "Yeah. It's a different one. I hope you like this better."
            else:
                pc "Decaf?"

                show kitchen_bg morning
                show denise_pd kitchen morning puggies smile
                with dissolve
                deni "Yeah."
        else:

            show kitchen_bg morning
            show denise_pd kitchen morning puggies neutral
            with dissolve

            if pc_coffee == "tea":
                deni "Before you ask, it's herbal."
                pc "Oh..."

                if w04d02_s02_liked_decaf:
                    show kitchen_bg morning
                    show denise_pd kitchen morning puggies angry
                    with dissolve
                    deni "You better get used to it, mister, because it's all you're getting here from now on."
                else:

                    show kitchen_bg morning
                    show denise_pd kitchen morning puggies unhappy
                    with dissolve
                    deni "Yeah. It's a different one. I hope you like this better."
            else:

                deni "Before you ask, it's decaf."
                pc "Oh."

                show kitchen_bg morning
                show denise_pd kitchen morning puggies angry
                with dissolve
                deni "You better get used to it, mister, because it's all you're getting here from now on."

        "You sip the hot beverage while your [denise_rel_to_pc] continues."

        show kitchen_bg morning
        show denise_pd kitchen morning puggies neutral
        with dissolve
        if w04d02_s03_picked_up_decaf:
            if pc_coffee == "tea":
                deni "And make sure you drink only fruit juice or herbal tea at the office, alright?"
            else:
                deni "And make sure you drink only fruit juice or decaf at the office, alright?"
        else:
            if pc_coffee == "tea":
                deni "And please think about drinking only fruit juice or herbal tea at the office, [denise_adr_pc_as]?"
            else:
                deni "And please think about drinking only fruit juice or decaf at the office, [denise_adr_pc_as]?"

            show kitchen_bg morning
            show denise_pd kitchen morning puggies unhappy
            with dissolve
            deni "For me?"
    else:

        scene kitchen_bg morning:
            subpixel True
            xalign 0.5 yalign 0.3 zoom 1.0
            0.5
            ease 38.3 zoom 1.1
        show denise_pd kitchen morning puggies neutral:
            subpixel True
            xalign 0.5 yalign 0.3 zoom 1.0
            0.5
            ease 38.3 zoom 1.2
        with fade

        if w04d02_s03_picked_up_decaf:
            deni "Now, remember... When you're at the office, make sure you drink only fruit juice, herbal tea or decaf, alright?"
        else:
            deni "Please [denise_adr_pc_as]... When you're at the office, think about drinking only fruit juice, herbal tea or decaf?"

            show kitchen_bg morning
            show denise_pd kitchen morning puggies unhappy
            with dissolve
            deni "For me?"

    if w04d02_s03_picked_up_decaf:
        if w04d02_s09_its_annoying or w04d02_s04_drag:
            pc "<sigh>"
            pc "Very well."

            show kitchen_bg morning
            show denise_pd kitchen morning puggies angry
            with dissolve
            deni "Don't act like that, [denise_adr_pc_as]. It's for your own benefit."
        else:

            pc "Sure thing, anything to make my angel happy."

            show kitchen_bg morning
            show denise_pd kitchen morning puggies happy
            with dissolve
            deni "[denise_adr_pc_as_cap]! It's for your benefit too, you know."

            show kitchen_bg morning
            show denise_pd kitchen morning puggies smile
            with dissolve
            deni "<giggle>"
    else:

        pc "I'm not promising anything, angel."
        show kitchen_bg morning
        show denise_pd kitchen morning puggies smile
        with dissolve
        deni "Well, you're not saying no either... I have a good hope you'll do what it takes to make your angel happy."

        show kitchen_bg morning
        show denise_pd kitchen morning puggies unhappy
        with dissolve
        deni "That's me... I'm your angel, remember?"

        default w04d03_s02_joked = False
        menu:
            "[abgreen]Joke.":
                $ w04d03_s02_joked = True
                pc "Wow, look at you, tugging away at those heart strings..."

                show kitchen_bg morning
                show denise_pd kitchen morning puggies smile
                with dissolve
                deni "I'm your [denise_rel_to_pc], I'm allowed."
            "Say nothing.":
                $ w04d03_s02_joked = False
                pc "..."

    show kitchen_bg morning
    show denise_pd kitchen morning puggies neutral
    with dissolve
    deni "And [denise_adr_pc_as]...?"
    pc "Yes?"

    show kitchen_bg morning
    show denise_pd kitchen morning puggies unhappy
    with dissolve
    deni "I'm sorry I didn't give you your massage today..."

    show kitchen_bg morning
    show denise_pd kitchen morning puggies neutral
    with dissolve
    deni "I'll make it up to you tomorrow."

    default w04d03_s02_tell_uncomfortable = False
    menu:
        "'Okay.'":
            $ w04d03_s02_tell_uncomfortable = False
            pc "That's okay angel. I know you will."

            show kitchen_bg morning
            show denise_pd kitchen morning puggies happy
            with dissolve
            deni "I promise..."
        "[abgreen]'Uncomfortable?'":

            $ w04d03_s02_tell_uncomfortable = True
            pc "Just... just tell me if this is making you uncomfortable, won't you?"

            show kitchen_bg morning
            show denise_pd kitchen morning puggies smile
            with dissolve
            deni "It's... it's not that. It's... something else."

            show kitchen_bg morning
            show denise_pd kitchen morning puggies happy
            with dissolve
            deni "I'd tell you if it was, I promise..."
            if denise_love <= 7:
                call denise_add_love from _call_denise_add_love_23

    if denise_love >= 7:

        show kitchen_bg morning
        show denise_pd kitchen morning puggies hug
        with dissolve
        pause 0.3

        show kitchen_bg morning
        show denise_pd kitchen morning puggies peck
        with dissolve
        pause 0.7

        show kitchen_bg morning
        show denise_pd kitchen morning puggies hug
        with dissolve

        deni "Mwah."

    show kitchen_bg morning
    show denise_pd kitchen morning puggies smile
    with dissolve
    deni "Drive safe."
    pc "I will."

    scene black
    with fade

    call music_fade_slow from _call_music_fade_slow_372

    if denise_have_coffee_ritual:
        "You drain the last dregs from your cup and accept the lunchbox your [denise_rel_to_pc] hands you, before you set off for work."
    else:
        "You accept the lunchbox your [denise_rel_to_pc] hands you and set off for work."

    label w04d03_s02_end_scene:

    pause 2.0

    return
