label w02d06_s02:

    scene black
    show setpiece kitchen morning pc wakeup laying:
        alpha 0.0
    show text "{size=+18}{font=fonts/typeo___.ttf}Saturday...{/font}{/size}" at truecenter
    with dissolve
    $ renpy.pause(2.0, hard='True')

    hide text
    with dissolve

    show setpiece kitchen morning pc wakeup laying:
        alpha 0.0
    show text "{size=+18}{font=fonts/typeo___.ttf}Nineish...{/font}{/size}" at truecenter
    with dissolve
    $ renpy.pause(1.0, hard='True')

    show setpiece kitchen morning pc wakeup laying:
        alpha 1.0
    with openeyestrans

    $ renpy.pause(1.0, hard='True')

    hide text
    with dissolve

    $ renpy.pause(1.0, hard='True')

    "After a fitful sleep, you're woken up by the sound of [denise_name] going into the bathroom."

    scene setpiece kitchen morning pc wakeup sitting
    with dissolve
    "You sit up and stare at the floor for a while..."
    "After about fifteen minutes, you reckon [denise_name] should be ready."
    menu:
        "Get up.":
            call music_fade_slow from _call_music_fade_slow_226
            scene black
            with fade
            "You get up, and walk over to the bathroom door."

    scene setpiece hallway morning bathroomdoor
    with fade
    menu:
        "[abgreen]Knock.":
            "You knock."
        "Just enter.":

            call sound_doorrattle from _call_sound_doorrattle_2
            "The door is locked."
            deni "Just a minute!"

    call theme_denise from _call_theme_denise_37
    "You hear the door being unlatched."
    deni "You can come in."

    scene bathroom_bg morning:
        subpixel True
        xalign 0.5 yalign 0.2 zoom 1.0
        0.5
        ease 19.2 zoom 1.1
    show denise_pd bathroom morning lowertowel happy closedeyes:
        subpixel True
        xalign 0.5 yalign 0.2 zoom 1.0
        0.5
        ease 19.2 zoom 1.2
    with fade

    deni "Good morning, [denise_adr_pc_as]."

    show denise_pd bathroom morning lowertowel happy
    with dissolve
    deni "Did you sleep well?"

    default w02d06_s02_pc_said_slept_well = False
    menu:
        "'Yeah.'":
            $ w02d06_s02_pc_said_slept_well = True
            pc "Yeah I did angel."

            show denise_pd bathroom morning lowertowel unhappy
            with dissolve
            deni "I don't think you're telling me the truth. You look a bit frazzled."
        "[abgreen]'Not really.'":

            $ w02d06_s02_pc_said_slept_well = False
            pc "Not really, angel."
            show denise_pd bathroom morning lowertowel unhappy
            with dissolve
            deni "Why not, [denise_adr_pc_as]?"

    pc "First things first. Turn 'round, angel."

    show denise_pd bathroom morning lowertowel lifthair norash
    with dissolve
    deni "Okay."

    "You put some lotion on your hands and start with your morning ritual."

    scene bathroom_bg morning applylotion:
        subpixel True
        zoom 1.15 xalign 0.0 yalign 0.0
        0.5
        ease 45.0 zoom 1.0
    show denise_pd bathroom applylotion norash neck eyesclosed:
        subpixel True
        zoom 1.3 xalign 0.0 yalign 0.0
        0.5
        ease 45.0 zoom 1.0
    with fade

    default w02d06_s02_pc_told_about_dream = False
    menu:
        "[abgreen]Tell about the dream.":
            $ w02d06_s02_pc_told_about_dream = True
            pc "I had a dream about your [charlotte_rel_to_denise]..."
            pc "It left me feeling sad."

            show denise_pd bathroom applylotion norash neck
            with dissolve
            deni "I'm sorry to hear that, [denise_adr_pc_as]."

            show denise_pd bathroom applylotion norash shoulder
            with dissolve
            deni "When I have a bad dream, I just cuddle up to [macy_name] to feel good."
        "Say nothing.":

            $ w02d06_s02_pc_told_about_dream = False
            pc "It's nothing, really."

            show denise_pd bathroom applylotion norash neck
            with dissolve
            deni "..."

            show denise_pd bathroom applylotion norash shoulder
            with dissolve
            deni "When I have trouble sleeping, I just cuddle up to [macy_name]."

    default w02d06_s02_denise_says_cuddle = False
    default w02d06_s02_pc_says_nice = False
    default w02d06_s02_pc_says_me_too = False

    if denise_love >= 9:
        $ w02d06_s02_denise_says_cuddle = True
    else:
        show denise_pd bathroom applylotion norash shoulder eyesclosed
        with dissolve
        deni "I wish you had someone to cuddle up to as well."
        menu:
            "[abgreen]'Me too.'":
                $ w02d06_s02_pc_says_me_too = True
                pc "Me too, angel."
                if denise_love >= 7:
                    $ w02d06_s02_denise_says_cuddle = True
                else:
                    $ w02d06_s02_denise_says_cuddle = False
                    jump w02d06_s02_cuddle_convo_done
            "'Don't need cuddles.'":

                $ w02d06_s02_pc_says_me_too = False
                $ w02d06_s02_denise_says_cuddle = False
                $ w02d06_s02_pc_says_nice = False

    if w02d06_s02_denise_says_cuddle:
        show denise_pd bathroom applylotion norash flanks eyesclosed
        with dissolve
        deni "You know what?"

        show denise_pd bathroom applylotion norash flanks
        with dissolve
        if w02d06_s02_pc_told_about_dream:
            deni "Next time you have a bad dream, I can come over and you can cuddle up to me."
        else:
            deni "Next time you have trouble sleeping, I can come over and you can cuddle up to me."

        menu:
            "[abgreen]'Sounds good.'":
                $ w02d06_s02_pc_says_nice = True
                pc "That sounds really nice, angel."

                show denise_pd bathroom applylotion belly eyesclosed
                with dissolve
                deni "[macy_name] says I'm really clingy too, so you don't have to worry about pushing me off the couch."
                pc "That's good to know, I guess."

                show denise_pd bathroom applylotion belly
                with dissolve
                deni "..."

                if denise_love >= 10:

                    show denise_pd bathroom applylotion underboob eyesclosed
                    with dissolve
                    deni "You know, if you were to move your hands around like this, I'd sleep really well too."

                    pc "Euh..."

                    show denise_pd bathroom applylotion underboob
                    with dissolve
                    deni "Did I say something weird?"

                    menu:
                        "'Yeah.'":
                            pc "Yeah."
                            pc "I'm still not sure how I feel about the idea of touching you like this."
                            show denise_pd bathroom applylotion underboob eyesclosed
                            with dissolve
                            deni "I know how I feel about it."

                            show denise_pd bathroom applylotion underboob
                            with dissolve
                            deni "I like it, [denise_adr_pc_as]. I like it a lot."
                        "[abgreen]'Nah.'":
                            pc "Nah."
                            pc "Maybe I would have thought so before."
                            pc "But we've grown quite intimate over the last weeks, haven't we?"

                            show denise_pd bathroom applylotion underboob eyesclosed
                            with dissolve
                            deni "Yeah. I like it when we're intimate."

                            show denise_pd bathroom applylotion underboob
                            with dissolve
                            deni "Just a bit higher on the left, [denise_adr_pc_as]."
            "'No need.'":

                $ w02d06_s02_pc_says_nice = False

    if not w02d06_s02_pc_says_nice:
        show denise_pd bathroom applylotion norash flanks
        with dissolve
        pc "That's okay angel, I'll manage without cuddles."

        show denise_pd bathroom applylotion norash flanks eyesclosed
        with dissolve
        if w02d06_s02_denise_says_cuddle:
            deni "Okay. Just tell me if you change your mind."
        else:
            deni "..."

    label w02d06_s02_cuddle_convo_done:

    scene black
    with fade
    "You massage her a bit more before moving on."

    scene bathroom_bg morning applylotion thighs:
        subpixel True
        xalign 0.9 yalign 0.05
        0.5
        ease 17.3 zoom 1.2
    show denise pd bathroom applylotion thighs eyesclosed:
        subpixel True
        xalign 0.9 yalign 0.05
        0.5
        ease 17.3 zoom 1.4
    with fade

    pc "How did you sleep, angel?"

    show denise pd bathroom applylotion thighs
    with dissolve
    deni "I slept pretty good."

    show denise pd bathroom applylotion thighs eyesclosed
    with dissolve
    deni "I think I've made up my mind."

    show denise pd bathroom applylotion thighs2 eyesclosed
    with dissolve
    deni "I know what I need to do to make us all happier."
    pc "You do?"

    show denise pd bathroom applylotion thighs2
    with dissolve
    deni "Yeah."

    scene bathroom_bg morning:
        zoom 1.3 yalign 1.0 xalign 0.5
    show denise_pd bathroom morning closeup embrace eyesclosed:
        yalign 1.0 xalign 0.5
    with fade
    deni "Thank you, [denise_adr_pc_as]."

    show denise_pd bathroom morning closeup embrace
    deni "That felt wonderful."

    pause 1.0
    show denise_pd bathroom morning closeup peck
    with dissolve
    pause 0.7
    show denise_pd bathroom morning closeup embrace
    with dissolve
    deni "Mwah."

    deni "I feel really relieved, now that I've made my decision."
    default w02d06_s02_cautious = False
    menu:
        "[abgreen]Be enthusiastic.":
            $ w02d06_s02_cautious = False
            pc "I'm happy to hear that."
            pc "What do you need?"

            scene bathroom_bg morning:
                subpixel True
                zoom 1.3 yalign 1.0 xalign 0.5
                0.5
                ease 2.2 zoom 1.0
            show denise_pd bathroom morning towel neutral:
                subpixel True
                zoom 1.2 yalign 1.0 xalign 0.5
                0.5
                ease 2.2 zoom 1.0
            with dissolve
        "Be cautious.":

            $ w02d06_s02_cautious = True
            pc "I like that you're taking this so serious."
            pc "But please keep in mind that it may not go the way you intended."

            scene bathroom_bg morning:
                subpixel True
                zoom 1.3 yalign 1.0 xalign 0.5
                0.5
                ease 2.2 zoom 1.0
            show denise_pd bathroom morning towel neutral:
                subpixel True
                zoom 1.2 yalign 1.0 xalign 0.5
                0.5
                ease 2.2 zoom 1.0
            with dissolve
            deni "Someone wise told me that if I do something with a pure heart, my efforts will be rewarded."
            pc "Just don't be disappointed if it doesn't work out.."

            show denise_pd bathroom morning towel smiling
            with dissolve
            deni "It will work out, with your help."
            pc "My help?"

            show denise_pd bathroom morning towel happy
            with dissolve
            deni "Yes."

            show denise_pd bathroom morning towel neutral
            with dissolve

    deni "First of all, I want you and [macy_name] to start getting along."

    default w02d06_s02_pc_blames_macy = False
    menu:
        "[abgreen]'Me too.'":
            $ w02d06_s02_pc_blames_macy = False
            pc "I'd like that too, angel."

            show denise_pd bathroom morning towel smiling
            with dissolve
            deni "Good."
        "'That'll be difficult.'":

            $ w02d06_s02_pc_blames_macy = True
            pc "She's making that nearly impossible with her attitude, angel."

            show denise_pd bathroom morning towel angry
            with dissolve
            deni "Now, now, what did you use to say to [macy_name] and me when we were fighting?"
            menu:
                "'It takes two...'":
                    pc "I said: 'it takes two people to have an argument.'"

                    show denise_pd bathroom morning towel happy
                    with dissolve
                    deni "Yes, you did!"
                "'I don't remember.'":

                    pc "I don't remember."

                    show denise_pd bathroom morning towel neutral
                    with dissolve
                    deni "You said: 'it takes two people to have an argument.'"

                    show denise_pd bathroom morning towel happy
                    with dissolve
                    deni "Ring any bells, [denise_adr_pc_as]?"
                    pc "..."

            show denise_pd bathroom morning towel smiling
            with dissolve
            deni "So, with that cleared up..."

    scene bathroom_bg morning:
        subpixel True
        yalign 0.3 xalign 0.5
        0.5
        ease 16.2 zoom 1.1
    show denise_pd bathroom morning towel neutral:
        subpixel True
        yalign 0.3 xalign 0.5
        0.5
        ease 16.2 zoom 1.2
    with dissolve
    deni "I want you to spend some time together."

    show denise_pd bathroom morning towel smiling
    with dissolve
    deni "Specifically, I want you to go out for drinks."

    default w02d06_s02_pc_no_thanks = False
    menu:
        "[abgreen]'Okay.'":
            $ w02d06_s02_pc_no_thanks = False
            pc "Sure, angel."

            show denise_pd bathroom morning towel happy
            with dissolve
            deni "Oh, that was easy."
        "'No thanks.'":

            $ w02d06_s02_pc_no_thanks = True
            pc "I'm not sure I want to..."

            show denise_pd bathroom morning towel unhappy
            with dissolve
            deni "Don't you want to patch things up between you?"
            pc "Well..."

            show denise_pd bathroom morning towel angry
            with dissolve
            deni "Of course you do!"

            show denise_pd bathroom morning towel neutral
            with dissolve
            if not w02d05_s01_its_a_bad_thing:
                deni "And you said yourself that having a drink sometimes helps people to open up to each other."
            else:
                deni "I think going out and having a relaxed drink together will help you to open up to each other."

            show denise_pd bathroom morning towel smiling
            with dissolve
            deni "Plus, [macy_name] has already agreed."

            show denise_pd bathroom morning towel unhappy
            with dissolve
            deni "If you cancel now, you'll hurt her feelings."

            pc "If you put it that way..."

    show denise_pd bathroom morning towel smiling
    with dissolve
    deni "Good!"

    show denise_pd bathroom morning towel neutral
    with dissolve
    deni "I'll tell her to get ready for tonight."

    menu:
        "[abgreen]'Okay.'":
            pc "Okay, angel."

            show denise_pd bathroom morning towel happy
            with dissolve
            deni "Now, please let me finish up in here..."

            play audio [ "<silence 0.5>", "sounds/doorslam.ogg" ]
            scene setpiece hallway morning bathroomdoor:
                subpixel True
                zoom 1.1 xalign 0.3 yalign 0.5
                0.5
                ease 2.1 zoom 1.0
            with fade
            with hpunch
            "You are quickly evicted from the bathroom."
        "'Wait, what?!'":

            pc "Wait, tonight?! You never told me..."

            show denise_pd bathroom morning towel happy
            with dissolve
            deni "Can't back out now..."

            play audio [ "<silence 0.5>", "sounds/doorslam.ogg" ]
            scene setpiece hallway morning bathroomdoor:
                subpixel True
                zoom 1.1 xalign 0.3 yalign 0.5
                0.5
                ease 2.1 zoom 1.0
            with fade
            with hpunch
            "Before you can get another word in, she evicts you from the bathroom and closes the door in your face."

    if w02d06_s02_cautious or w02d06_s02_pc_blames_macy or w02d06_s02_pc_no_thanks:
        pc_thought "Ahhh... did my youngest [denise_rel_to_pc] just corner me into a date with my oldest [macy_rel_to_pc]?"
    else:
        pc_thought "Did my youngest [denise_rel_to_pc] just set me up on a date with my oldest [macy_rel_to_pc]?"

    scene black
    with fade

    pause 2.0

    return
