label w02d03_s05:

    scene livingroom_couch_bg night:
        subpixel True
        xalign 0.6 yalign 0.0 zoom 1.2
        0.5
        ease 35.0 zoom 1.0
    show denise_pd livingroom night couch playphone:
        subpixel True
        xalign 0.6 yalign 0.0 zoom 1.4
        0.5
        ease 35.0 zoom 1.0
    with fade

    call theme_denise from _call_theme_denise_19

    "Something feels different this evening."

    show denise_pd livingroom night couch talk
    with dissolve
    pause 0.5
    show denise_pd livingroom night couch playphone
    with dissolve
    "You catch her watching you, when you're not looking."

    pc_thought "I wonder what that is about..."

    scene black
    with fade

    scene livingroom_couch_bg night:
        subpixel True
        xalign 0.6 yalign 0.0 zoom 1.0
        0.5
        ease 45.0 zoom 1.2
    show denise_pd livingroom night couch playphone:
        subpixel True
        xalign 0.6 yalign 0.0 zoom 1.0
        0.5
        ease 45.0 zoom 1.4
    with fade

    pause 0.5

    show denise_pd livingroom night couch talk
    with dissolve

    pause 0.5

    show denise_pd livingroom night couch playphone
    with dissolve
    "After observing you like this for a while, [denise_name] speaks up."

    show denise_pd livingroom night couch thoughtfull
    with dissolve
    deni "[denise_adr_pc_as_cap], can I ask you something?"
    pc "Always, angel."

    show denise_pd livingroom night couch unhappy
    with dissolve
    deni "Are you feeling anxious at all, lately?"
    pc_thought "Ah, thinking about her panic attack."

    default w02d03_s05_be_rolemodel = False
    menu:
        "Be a role model.":
            $ w02d03_s05_be_rolemodel = True
            pc "Of course, angel."
            pc "But I try not to let it control me."
            pc "I hear breathing exercises can really help with that."
        "[abgreen]Relate to her.":

            $ w02d03_s05_be_rolemodel = False
            pc "I'm sure everyone does, from time to time."
            pc "And when I do, it's not easy."
            pc "But, I know there's people around me that love me and care for me, and that helps me get through it."

    show denise_pd livingroom night couch sad
    with dissolve
    deni "I see, [denise_adr_pc_as]."

    show denise_pd livingroom night couch headrub sad
    with dissolve
    deni_thought "Anxiety, that's another one from the list of symptoms."

    show denise_pd livingroom night couch headrub sad eyesclosed
    with dissolve
    deni_thought "I really need to talk to someone about this."

    pc "Do you want to watch a movie?"

    show denise_pd livingroom night couch talk
    with dissolve
    deni "Sure."

    show denise_pd livingroom night couch thoughtfull
    with dissolve
    deni "Can we see that Insecti-Guy: Into the Insecti-Sphere?"

    menu:
        "Nerdy answer.":
            pc "Is that the one where they used color offset instead of focus blur to create a depth of field effect?"

            show denise_pd livingroom night couch headrub sad
            with dissolve
            deni "Did they? I just heard it is weird and funny."
        "[abgreen]Normal answer.":
            pc "Is that the one where there's a bunch of Insecti-Guys from different universes working together?"

            show denise_pd livingroom night couch angry
            with dissolve
            deni "[denise_adr_pc_as_cap]! Spoiler much?!"

            show denise_pd livingroom night couch headrub sad
            with dissolve
            deni "I just heard it is weird and funny."

    pc "Let me see if there's some ice cream left in the fridge before we get started."

    show denise_pd livingroom night couch headrub happy
    with dissolve
    deni "Oh yeah, I forgot about that."

    scene black
    with fade

    scene livingroom_couch_bg night:
        subpixel True
        xalign 0.6 yalign 0.0 zoom 1.15
        0.5
        ease 45.0 zoom 1.0
    show denise_pd livingroom night couch icecream:
        subpixel True
        xalign 0.6 yalign 0.0 zoom 1.3
        0.5
        ease 45.0 zoom 1.0
    with fade
    "You watch the movie together."

    show denise_pd livingroom night couch icecream eat
    with dissolve
    "For some reason you can't quite put your finger on, it jumbles a whole bunch of wildly different art styles while still managing to look awesome and present a cohesive story."

    show denise_pd livingroom night couch icecream feed
    with dissolve
    "It's pretty entertaining too."

    scene black
    with fade
    scene livingroom_couch_bg night
    show denise_pd livingroom night couch headrub happy
    with fade
    "It's getting quite late when the movie ends."

    show denise_pd livingroom night couch talk
    with dissolve
    deni "Shouldn't [macy_name] be home by now?"

    call music_fade_slow from _call_music_fade_slow_94

    pc "Yeah. Maybe something happened at work and she needed to stay a bit later?"

    show denise_pd livingroom night couch thoughtfull
    with dissolve
    deni "Why didn't she call then?"

    default w02d03_s05_called_up = False
    menu:
        "Reassure [denise_name].":
            $ w02d03_s05_called_up = False
            pc "I'm sure it's nothing."

            show denise_pd livingroom night couch unhappy
            with dissolve
            deni "I don't like it."

            show denise_pd livingroom night couch playphone
            with dissolve
            deni "I'm going to call her."
        "[abgreen]Call up [macy_name].":

            $ w02d03_s05_called_up = True
            pc "Yeah, you're right."
            pc "Why don't you give her a ring?"

            show denise_pd livingroom night couch playphone
            with dissolve
            deni "I will, [denise_adr_pc_as]."

    "At that moment, it's your phone that rings."

    show livingroom_couch_bg night:
        subpixel True
        xalign 0.6 yalign 0.0
        0.5
        ease 6.3 zoom 1.1
    show denise_pd livingroom night couch solo looksurprised:
        subpixel True
        xalign 0.6 yalign 0.0
        0.5
        ease 6.3 zoom 1.2
    with dissolve
    "You stand up and step towards the kitchen."

    scene black
    with fade
    "The number is not in your contacts, but after a few seconds your phone resolves it as 'district police station'."

    call theme_trouble from _call_theme_trouble
    "A stream of memories about the last time you got a call like this comes flooding in."

    scene kitchen_bg lookatsink nighttime
    show denise_pd kitchen night neutral:
        subpixel True
        xpos 0.0 xanchor 1.0 yalign 0.0
        3.2
        ease 6.2 xalign 0.0
    with fade

    menu:
        "Pick up.":
            "With some trepidation, you pick it up."
            menu:
                "[abgreen]Speak up.":
                    "You muster all your courage..."
                    pc "[player_name] speaking..."
                    macy "[player_name], it's me."
                "Hold your breath.":
                    pc "..."
                    macy "[player_name], are you there?"

    show denise_pd kitchen night unhappy:
        subpixel True
        .7
        parallel:
            ease 0.15 zoom 1.01
            ease 0.15 zoom 1.0
        parallel:
            0.45
            ease 0.9 xalign 0.5
    with dissolve
    pc "[macy_name]?!"

    menu:
        "'What happened?'":
            pc "What happened to you?"
            macy "Long story. I'm okay."
        "[abgreen]'Are you okay?'":
            pc "Are you okay?"
            macy "Yeah, yeah I am."
        "'Why are you calling from this number?'":
            pc "Why are you calling from this number?"
            macy "Phone's gone. Long story. I'm okay."

    macy "Listen..."

    show denise_pd kitchen night angry:
        0.5
        ease 0.4 xalign 0.48
        parallel:
            ease 0.8 xalign 0.52
            ease 0.8 xalign 0.48
            repeat
    with dissolve
    "Before [macy_name] can continue, [denise_name] jumps in."

    show denise_pd kitchen night unhappy
    with dissolve
    deni "Is that [macy_name]?!"

    show denise_pd kitchen night angry
    with dissolve
    deni "Why didn't she call?!"

    show denise_pd kitchen night unhappy
    with dissolve
    deni "Is she okay?!"

    show denise_pd kitchen night angry
    with dissolve
    deni "Did anything happen?!"

    show denise_pd kitchen night unhappy
    with dissolve
    deni "Where is she?!"

    show denise_pd kitchen night angry
    with dissolve
    deni "Is something wrong?!"

    show denise_pd kitchen night unhappy
    with dissolve
    deni "What happened?!"

    default w02d03_s05_hush_denise = False
    menu:
        "Hush her.":
            $ w02d03_s05_hush_denise = True
            pc "Hush, angel, let me talk with her first."

            show denise_pd kitchen night angry
            with dissolve
            "You continue talking with [macy_name]."
        "[abgreen]Reassure her.":
            $ w02d03_s05_hush_denise = False
            pc "Hang on, [macy_name]."
            pc "Yes it's [macy_name], she says she's fine."

            show denise_pd kitchen night angry
            with dissolve
            deni "What happened?"
            pc "I'm trying to find that out."

            show denise_pd kitchen night unhappy
            with dissolve
            deni "Right."

            show denise_pd kitchen night angry
            with dissolve
            deni "Well, go on!"
            "You get back to the phone."

    macy "She's freaking out, right?"
    pc "A little."

    show denise_pd kitchen night unhappy
    with dissolve
    deni "..."

    macy "Listen, I really need you to come pick me up at the police station."
    macy "I... ran into some trouble."

    menu:
        "'What happened?'":
            pc "What happened to you?"
            macy "I'll tell you later."
            macy "Please come."
            pc "Yeah, I'm coming."
        "[abgreen]'On my way.'":

            pc "I'm on my way."

    macy "They say they'll text you the address."
    pc "No need, I know where it is."
    pc "I've been there before."

    pc "I'll be there in about fifteen minutes."

    if macy_love >= 5:
        macy "Okay... please hurry."
    else:
        macy "Okay..."

    "You hang up."

    pc "I'm sorry, angel, I have to go."
    pc "I have to pick up [macy_name]."

    scene black
    with fade

    "You spend a few more minutes answering questions from your youngest [denise_rel_to_pc] about what happened to [macy_name]."
    "Most of them with 'I don't know', in one form or another."
    "After you point out that [denise_name] can ask her [macy_rel_to_denise] in person after you've gone and picked her up, you are quickly ushered to your car."

    pause 2.0

    return
