label w01d03_s01:
    scene black
    show text "{size=+18}{font=fonts/typeo___.ttf}Wednesday...{/font}{/size}" at truecenter
    with fade

    $ renpy.pause(2.0, hard='True')

    scene black
    with fade

    deni "{size=-8}[denise_adr_pc_as_cap]...{/size}"

    pc "Hmmm..."
    deni "{size=-4}[denise_adr_pc_as_cap]...{/size}"

    pc "..."

    call theme_denise from _call_theme_denise_4
    deni "[denise_adr_pc_as_cap]!"

    scene setpiece kitchen morning denise towel wakeup
    with openeyestrans

    deni "Wake up, sleepyhead!"
    pc "<yawn>"
    pc "What's the matter, angel?"

    deni "I need your help to put on the ointment."
    deni "I can't reach there myself."

    scene black
    with closeeyestrans
    pc "Okay, gimme a second to get up. I'll come to the bathroom."

    scene setpiece kitchen morning denise towel wakeup
    with openeyestrans
    deni "Don't be long..."

    scene black
    with fade
    "You get up and join [denise_name] in the bathroom."

    scene setpiece hallway morning bathroomdoor
    with fade
    menu:
        "[abgreen]Knock.":
            "You knock."
            deni "Come in."
        "Just enter.":

            "The door is unlocked."

    scene bathroom_bg morning
    show denise_pd bathroom morning towel smiling
    with fade
    "You enter the bathroom."

    pc "Turn around and I'll put it on."

    show denise_pd bathroom morning towel lifthair rash
    with dissolve
    "[denise_name] turns around and lifts her hair."

    pc "Wait, this isn't working."

    show denise_pd bathroom morning towel neutral
    with dissolve
    pc "I can't apply it everywhere. You'll need lower the towel."

    show denise_pd bathroom morning towel unhappy
    with dissolve
    deni "Do I have to, [denise_adr_pc_as]?"
    pc "I'm afraid so, angel."
    deni "I feel weird, [denise_adr_pc_as]. I'm not used to being undressed in front of you."

    default w01d03_s01_understanding_about_ointment = False
    menu:
        "[abgreen]Be understanding.":
            $ w01d03_s01_understanding_about_ointment = True
            show denise_pd bathroom morning towel neutral
            with dissolve
            pc "I know angel, but you want that rash to be over, right?"
            pc "Besides, when I put it on you the last time you had that rash, you didn't have a problem with it."

            show denise_pd bathroom morning towel smiling
            with dissolve
            deni "That was different. I was little then. I don't even really remember."
            pc "You're still little to me, angel."

            show denise_pd bathroom morning towel angry
            with dissolve
            deni "No I'm not."

            show denise_pd bathroom morning unhappy
            with dissolve
            deni "But I guess you're right."
            deni "..."

            show denise_pd bathroom morning towel angry
            with dissolve
            deni "No peeking though!"
            pc "I promise, no peeking angel."

            deni "..."

            show denise_pd bathroom morning towel neutral
            with dissolve
            deni "Okay then..."
        "Be impatient.":

            $ w01d03_s01_understanding_about_ointment = False
            show denise_pd bathroom morning towel neutral
            with dissolve
            pc "I don't have time for this, [denise_name]."

            show denise_pd bathroom morning unhappy
            with dissolve
            pc "Do you want me to apply it or not?"

            show denise_pd bathroom morning towel angry
            with dissolve
            deni "Gee, why are you so mean about it?"

            show denise_pd bathroom morning unhappy
            with dissolve
            deni "I'm just uncomfortable about it, that's all."

            pc "Lower the towel and turn around, please."

            show denise_pd bathroom morning towel angry
            with dissolve
            deni "..."
            call denise_add_angst from _call_denise_add_angst_1

    deni "Close your eyes."

    default w01d03_s01_didntwanttocloseyes = False
    label w01d03_s01.close_eyes_menu:
    menu:
        "[abgreen]Close your eyes.":
            scene black
            with closeeyestrans
            "You close your eyes."

        "Don't." if not w01d03_s01_didntwanttocloseyes:
            $ w01d03_s01_didntwanttocloseyes = True
            pc_thought "I don't really think that's an option here."
            pc_thought "Besides, what am I, some kind of weirdo getting off on his [denise_rel_to_pc]? Sheesh man!"
            jump w01d03_s01.close_eyes_menu

    "There's a sound of rustling fabric."

    deni "You can open them now."

    menu:
        "Open your eyes.":
            scene bathroom_bg morning
            show denise_pd bathroom morning lowertowel unhappy
            with openeyestrans

    deni "And no peeking, you hear!"

    pc "Yes, angel."
    deni "Good."

    show denise_pd bathroom morning lowertowel lifthair rash
    with dissolve
    "[denise_name] turns around and raises up her hair."
    "She is clearly uncomfortable about it."

    pc_thought "Wait, I can see her..."
    with hpunch

    pc_thought "Let's... just look the other way and not embarrass her."
    pc_thought "She's jumpy enough as it is."

    pc_thought "..."
    pc_thought "Gotta say, girl's got some headlights on her."
    with hpunch
    pc_thought "Cripes, what am I thinking. Let's just get on with it."

    "You put some of the ointment on your hands."

    scene setpiece bathroom morning denise applylotion shoulders
    with fade

    "You apply it to her shoulders..."
    "...rubbing it gently onto the bright red spots on her skin."
    "You feel the tension in her muscles as your fingers move over her skin."

    pc "You okay, angel?"
    deni "Uh-huh."
    deni "It feels a bit cold, but it's not bad."
    deni "And it really helps with the itchy feeling."

    pc "That's good, angel."
    pc "I'm going to apply it a bit lower on your back now."

    deni "..."
    deni "Okay, [denise_adr_pc_as]."

    scene setpiece bathroom morning denise applylotion back
    with dissolve
    "You rub the ointment on the red spots on her back."
    "Your fingers softly caress the affected areas of her sensitive skin."
    "Under your hands, you feel some of the tension drain out of her."

    deni "Hmmm..."
    pc "Does that feel good, angel?"
    deni "Yes, [denise_adr_pc_as]."
    pc "You let me know if you're uncomfortable, okay?"
    deni "I will, [denise_adr_pc_as]."
    deni "..."
    deni "Hmmm..."

    pc "Just a few spots on your sides, and we're done."
    deni "...Okay."

    scene setpiece bathroom morning denise applylotion flanks
    with dissolve
    "You rub some ointment on the spots on her sides."
    "Most of the nervous tension has left her body, and she doesn't jump as you touch her skin."

    deni "..."
    deni "You're actually pretty good at this."
    pc "You think so?"
    deni "Uh-huh."
    pc "I used to give your [charlotte_rel_to_denise] backrubs all the time."
    pc "She couldn't get enough of it."

    deni "..."
    deni "I understand why."
    deni "<sigh>"
    deni "..."

    pc "That's it, all done."

    deni "Close your eyes again, [denise_adr_pc_as]."

    scene black
    with closeeyestrans

    deni "..."
    deni "Okay, you can look again."

    scene bathroom_bg morning
    show denise_pd bathroom morning towel neutral
    with openeyestrans

    pc "That wasn't so bad, was it?"

    show denise_pd bathroom morning towel smiling
    with dissolve
    deni "No, [denise_adr_pc_as]. It actually felt kinda nice."
    deni "And the ointment smells nice, too."

    pc "Good to hear, angel. I'll leave you to it."

    show denise_pd bathroom morning towel happy
    with dissolve
    deni "Thanks, [denise_adr_pc_as]."

    if w01d03_s01_understanding_about_ointment:
        show denise_pd bathroom morning closeup embrace
        with dissolve
        pause 1.0
        show denise_pd bathroom morning closeup peck
        with dissolve
        pc "Whoa!"

        show denise_pd bathroom morning closeup embrace
        with dissolve
        deni "You're the best!"

    show denise_pd bathroom morning towel smiling
    with dissolve
    deni "Now, git!"

    call sound_doorslam from _call_sound_doorslam
    scene setpiece hallway morning bathroomdoor
    with hpunch
    "Again, you are persuasively ushered out."
    "You leave [denise_name] to finish up in the bathroom."

    scene black
    with fade

    return
