label w01d06_s03:

    "After breakfast, [denise_name] gets dressed while you unpack the box that was delivered yesterday."
    "Inside the box, there's a list of subjects for [denise_name] to study."

    scene kitchen_bg afternoon
    show denise_pd kitchen afternoon camisole neutral:
        xpos 1.0 xanchor 0.0
        4.0
        ease 2.3 xalign 0.5
    with fade

    "There are also some teaching guides for the various subjects for you to use, and a few stacks of print-outs with exercises and quizzes."
    "A letter included by Mrs. Farthingsworth gives a brief overview of the various materials and how you should use them."

    pc "So, angel, it seems we have a variety of subjects we can cover."
    pc "Where do you want to start?"

    show denise_pd kitchen afternoon camisole smile
    with dissolve
    deni "I think I'll start out with some history today."

    show denise_pd kitchen afternoon camisole neutral
    with dissolve
    deni "We were about to cover the renaissance, when... eh..."

    show denise_pd kitchen afternoon camisole unhappy
    with dissolve
    deni "We were about to cover the renaissance."

    show denise_pd kitchen afternoon camisole neutral
    with dissolve
    pc "Sure thing, angel."
    pc "How do you want to do this?"

    show denise_pd kitchen afternoon camisole smile
    with dissolve
    deni "For now, I think I can manage on my own mostly."

    show denise_pd kitchen afternoon camisole happy
    with dissolve
    deni "I'll tell you when I need some help."

    show denise_pd kitchen afternoon camisole happy:
        subpixel True
        0.7
        easeout 3.2 xpos 0.0 xanchor 1.0

    pc "Very well."
    pc "I'll just get my laptop and hobby a bit."

    scene kitchen_bg afternoon study
    show denise_pd kitchen afternoon study sittable neutral
    show pc_pd kitchen afternoon study sittable neutral
    show black:
        alpha 0.0
    with fade

    "You pull out your laptop as [denise_name] cracks open her history book."

    default w01d06_s03_spent_time = "games"
    menu:
        "Play music.":
            show pc_pd kitchen afternoon study sittable music
            with dissolve
            $ w01d06_s03_spent_time = "music"
            "You start to play some music."

            show denise_pd kitchen afternoon study sittable unhappy
            with dissolve
            deni "[denise_adr_pc_as_cap]...! How can I concentrate with you making so much noise?!"
            pc "Sorry..."

            show denise_pd kitchen afternoon study sittable looktablet
            with dissolve
            "You put in your earphones so you don't disturb [denise_name], and listen to some music for a while."
        "Play games.":

            show pc_pd kitchen afternoon study sittable game
            with dissolve
            $ w01d06_s03_spent_time = "games"
            "You play some games for a while."

            show denise_pd kitchen afternoon study sittable looktablet
            with dissolve
            "You die six times in a row because you roleplayed your character build instead of maxing damage output."
        "[abgreen]Do some coding.":

            show pc_pd kitchen afternoon study sittable coding
            with dissolve
            $ w01d06_s03_spent_time = "coding"
            "You monkey around a bit with some new software framework everyone is raving about."

            show denise_pd kitchen afternoon study sittable looktablet
            with dissolve
            "It's neat, but you don't see a way to use it in the projects you're currently working on."

    show black:
        alpha 0.0
        ease 1.0 alpha 1.0
        ease 1.0 alpha 0.0

    show pc_pd kitchen afternoon study sittable neutral
    with dissolve
    "After an hour or so has passed, you take a break from what you are doing and look up at your [denise_rel_to_pc]."
    pc "How are you doing, angel?"

    show kitchen_bg afternoon study:
        subpixel True
        xalign 0.0 yalign 0.75
        0.5
        ease 8.0 zoom 1.1
    show pc_pd kitchen afternoon study sittable neutral:
        subpixel True
        xalign 0.0 yalign 0.75
        0.5
        ease 8.0 zoom 1.2
    show denise_pd kitchen afternoon study sittable smile:
        subpixel True
        xalign 0.0 yalign 0.75
        0.5
        ease 8.0 zoom 1.2
    with dissolve
    "She looks up from her reading and stretches for a moment, before continuing."

    window hide
    pause 2.5

    deni "Good."
    deni "I'm reading about the art of the renaissance, and how it was different from the period that came before."

    show kitchen_bg afternoon study:
        subpixel True
        0.5
        ease 14.0 zoom 1.0
    show pc_pd kitchen afternoon study sittable neutral:
        subpixel True
        0.5
        ease 14.0 zoom 1.0
    show denise_pd kitchen afternoon study sittable looktablet:
        subpixel True
        0.5
        ease 14.0 zoom 1.0
    with dissolve
    deni "It's really interesting to read about how, after years of stagnation, all these new ideas and ways of thinking and doing things developed."

    show denise_pd kitchen afternoon study sittable neutral
    with dissolve
    pc "It is a very interesting period in European history."
    pc "Say, I think I saw an ad the other day about an exhibition of renaissance art at the museum."
    pc "Do you want to go?"

    show denise_pd kitchen afternoon study sittable unhappy
    with dissolve
    deni "What are they showing?"
    pc "Hang on, I'll go to their website..."

    scene black
    with fade
    "You pull up the museum website."
    "[denise_name] jumps into your lap to read the page together with you."

    scene kitchen_bg afternoon sitinlap:
        subpixel True
        xalign 1.0 yalign 0.0 zoom 1.3
        0.5
        easein 24 zoom 1.0
    show denise_pd kitchen afternoon study sitinlap relaxed:
        subpixel True
        xalign 1.0 yalign 0.0 zoom 1.6
        0.5
        easein 24 zoom 1.0
    show pc_pd kitchen afternoon study sitinlap museum_website:
        subpixel True
        xalign 1.0 yalign 0.0 zoom 1.6
        0.5
        easein 24 zoom 1.0
    with fade

    pc "Paintings from the renaissance and the baroque period..."

    show pc_pd kitchen afternoon study sitinlap titian
    with dissolve
    pc "With works from Furini, Guercino and Massys, and many more..."

    show pc_pd kitchen afternoon study sitinlap rubens_venus_adonis
    with dissolve
    deni "Oh, it says there's even some work by Rubens on display..."

    show denise_pd kitchen afternoon study sitinlap happy
    with dissolve
    deni "I read about him."
    pc "He's famous for painting full bodied figures."

    show denise_pd kitchen afternoon study sitinlap lookwebsite
    show pc_pd kitchen afternoon study sitinlap rubens_paris
    with dissolve
    "[denise_name] spends a while looking at some of his and similar artworks on the web."

    show pc_pd kitchen afternoon study sitinlap sleeping_venus
    with dissolve
    show denise_pd kitchen afternoon study sitinlap happy
    with dissolve
    deni "Those are some really firm ladies."

    show denise_pd kitchen afternoon study sitinlap relaxed
    with dissolve
    pc "Yeah."

    show denise_pd kitchen afternoon study sitinlap lookwebsite
    with dissolve
    pc "Back in that time period, notions were quite different on what the ideal physical shape should be."
    deni "I guess so."
    deni "How come it was so different from now?"

    menu:
        "'Don't know.'":
            show denise_pd kitchen afternoon study sitinlap relaxed
            with dissolve
            pc "I don't really know, angel."
        "[abgreen]'Fashions change.'":

            pc "Well, fashions change over time, and from culture to culture."
            show pc_pd kitchen afternoon study sitinlap jacobvl_venus
            with dissolve
            pc "At this moment in time in this culture, the mainstream notion is that thin is more fashionable."

            show pc_pd kitchen afternoon study sitinlap monet
            with dissolve
            pc "But even now it's shifting, and just a few decades ago, fashion dictated women to be much more skinny."

            menu:
                "[abgreen]'But not everyone feels that way.'":
                    show denise_pd kitchen afternoon study sitinlap happy
                    with dissolve
                    pc "Of course, even now many people don't subscribe to this mainstream beauty notion."
                    pc "Opinions on what is beautiful come in as many shapes and sizes as there are people."
                "Leave it at that.":
                    pc "..."

            show denise_pd kitchen afternoon study sitinlap relaxed
            with dissolve
            deni "I see..."

    show denise_pd kitchen afternoon study sitinlap happy
    with dissolve
    deni "Is it strange that I really like the way these nudes were painted?"
    pc "Not at all, they're revered as great works of art after all."

    show denise_pd kitchen afternoon study sitinlap lookwebsite
    with dissolve
    pc "What do you like about them?"

    show pc_pd kitchen afternoon study sitinlap sleeping_venus
    with dissolve
    deni "Well, they look like real people, with full bodies..."
    deni "Like you can reach in and squeeze them..."
    deni "But they are painted in so much detail, and you can see the artist painted them with love."
    show pc_pd kitchen afternoon study sitinlap furini_ldgt_buttocks
    with dissolve
    deni "..and they make me think my butt isn't so big after all."

    default w01d06_s03_pc_said_butt_is_perfect = False
    default w01d06_s03_pc_went_to_far = False
    menu:
        "[abgreen]'Your butt is perfect.'":
            $ w01d06_s03_pc_said_butt_is_perfect = True
            pc "Don't say that. You have a perfect butt, angel."

            show denise_pd kitchen afternoon study sitinlap relaxed
            with dissolve
            deni "..."
            pc "Did I say something wrong?"

            if denise_love >= 7:

                show denise_pd kitchen afternoon study sitinlap happy
                with dissolve
                deni "I should find it very weird to hear you say that to me, but it makes me happy actually."
                deni "Thank you for the compliment, [denise_adr_pc_as]."

                menu:
                    "Heap it on.":
                        $ w01d06_s03_pc_went_to_far = True
                        pc "I'm telling the truth..."
                        pc "It really is perfect, round and..."

                        show denise_pd kitchen afternoon study sitinlap shocked
                        with dissolve
                        deni "[denise_adr_pc_as_cap], you know when I said it didn't feel weird when you talked about my butt?"
                        pc "Yes?"
                        deni "Well, now it does. Very much."
                        call denise_remove_love from _call_denise_remove_love_1
                        deni "I think you should stop talking about my butt."
                        pc "Ehm, you're probably right."
                    "[abgreen]Don't overdo it.":

                        $ w01d06_s03_pc_went_to_far = False
                        pc "You're welcome, angel."
            else:
                $ w01d06_s03_pc_went_to_far = True

                show denise_pd kitchen afternoon study sitinlap shocked
                with dissolve
                deni "I think it's weird that you talk about my butt that way."
                call denise_remove_love from _call_denise_remove_love_2
                pc "Ehm, you're probably right."
        "Say nothing.":

            $ w01d06_s03_pc_said_butt_is_perfect = False
            $ w01d06_s03_pc_went_to_far = False

            show denise_pd kitchen afternoon study sitinlap relaxed
            with dissolve
            pc "..."

    show denise_pd kitchen afternoon study sitinlap lookwebsite
    with dissolve
    "Your attention now focused on that part of your [denise_rel_to_pc]s anatomy..."

    show kitchen_bg afternoon sitinlap:
        subpixel True
        xalign 1.0 yalign 1.0
        0.5
        ease 8 zoom 1.2
    show denise_pd kitchen afternoon study sitinlap lookwebsite:
        subpixel True
        xalign 1.0 yalign 1.0
        0.5
        ease 8 zoom 1.4
    show pc_pd kitchen afternoon study sitinlap titian:
        subpixel True
        xalign 1.0 yalign 1.0
        0.5
        ease 8 zoom 1.4
    with dissolve
    "...you find yourself becoming very much aware of it sitting right on top of you."

    show pc_pd kitchen afternoon study sitinlap rubens_venus_adonis
    with dissolve
    with hpunch
    "Before you can do anything to prevent it, your body stirs in reaction."

    pc_thought "Oh no! Please don't let her notice."

    show kitchen_bg afternoon sitinlap:
        subpixel True
        xalign 1.0 yalign 1.0
        0.5
        ease 8 zoom 1.0
    show denise_pd kitchen afternoon study sitinlap lookwebsite:
        subpixel True
        xalign 1.0 yalign 1.0
        0.5
        ease 8 zoom 1.0
    show pc_pd kitchen afternoon study sitinlap museum_website:
        subpixel True
        0.5
        ease 8 zoom 1.0
    with dissolve
    "[denise_name] has her attention fully focused on the webpages in front of her."

    show denise_pd kitchen afternoon study sitinlap happy
    with dissolve
    deni "I think I'd really like to go see the exhibition, [denise_adr_pc_as]."

    show denise_pd kitchen afternoon study sitinlap uneasy
    with dissolve
    deni "If it's not too busy that is."

    "Glad for the distraction, you answer your [denise_rel_to_pc]."
    show denise_pd kitchen afternoon study sitinlap relaxed
    with dissolve
    pc "Ehm... I don't think it will be, angel."

    pc "It seems it's been going on for a while, and closes next week."
    pc "If you want to go, we should go tomorrow."

    show denise_pd kitchen afternoon study sitinlap happy
    with dissolve
    deni "Yay! I want to go, [denise_adr_pc_as]!"
    deni "If we go really early, maybe we'll have the place to ourselves."

    show denise_pd kitchen afternoon study sitinlap lookwebsite
    with dissolve
    "Her enthusiastic gesturing shifts her weight from side to side, doing nothing to bring relief to your current situation."

    show pc_pd kitchen afternoon study sitinlap furini_ldgt_buttocks
    with dissolve
    "Quite the opposite, in fact."

    show denise_pd kitchen afternoon study sitinlap relaxed
    with dissolve
    if w01d05_s06_embarassed:
        "Something happens that has to do with, as you so eloquently explained yesterday: 'Eh.. you know, blood flowing into certain body parts...'"
    else:
        "As you explained just yesterday, certain blood vessels widen, and blood flows into special chambers which then inflate like balloons."

    show kitchen_bg afternoon sitinlap:
        subpixel True
        xalign 1.0 yalign 0.0
        0.5
        ease 26 zoom 1.2
    show pc_pd kitchen afternoon study sitinlap furini_ldgt_buttocks:
        subpixel True
        xalign 1.0 yalign 0.0
        0.5
        ease 26 zoom 1.4
    show denise_pd kitchen afternoon study sitinlap shocked:
        subpixel True
        xalign 1.0 yalign 0.0
        0.5
        ease 26 zoom 1.4
    with dissolve
    deni_thought "Wait, is he..."
    deni_thought "Oh no..."

    show denise_pd kitchen afternoon study sitinlap uneasy
    with dissolve
    deni_thought "I mustn't freak out, it'll only embarrass him again."
    deni_thought "Quick, think about something else."

    show denise_pd kitchen afternoon study sitinlap shocked
    with dissolve
    deni_thought "Puppies, puppies, puppies, puppies!"
    pc_thought "She tensed up. Did she notice? Oh please god I hope she didn't notice."

    show denise_pd kitchen afternoon study sitinlap uneasy
    with dissolve
    pc_thought "I have to get out of here, fast!"

    menu:
        "Excuse yourself.":
            pc "Sorry angel, I think I need to go and use the restroom. Really quickly!"

    show denise_pd kitchen afternoon study sitinlap shocked
    with dissolve
    deni "Yes, yes! Of course!"

    scene black
    with fade
    "Relieved, she quickly scrambles off of your lap..."

    scene kitchen_bg afternoon
    with fade
    "You rush out the door, awkwardly trying to angle your body to hide your predicament."

    show denise_pd kitchen afternoon camisole unhappy:
        xpos 0.0 xanchor 1.0
        0.5
        easein 1.5 xalign 0.5
    with dissolve
    deni_thought "Oh my goooosh..."
    deni_thought "Again...?"

    if not w01d03_s08_pc_likes_chunky_chicas:
        call music_fade_slow from _call_music_fade_slow_85

    show denise_pd kitchen afternoon camisole neutral
    with dissolve
    deni_thought "It must be all those nude ladies we just looked at."

    if w01d03_s08_pc_likes_chunky_chicas:
        show denise_pd kitchen afternoon camisole smile
        with dissolve
    else:
        show denise_pd kitchen afternoon camisole smile:
            0.5
            easeout 2.5 xpos 0.0 xanchor 1.0
        with dissolve

    deni_thought "After all, he did mention visual stimulation can cause it to happen."

    if w01d03_s08_pc_likes_chunky_chicas:
        show denise_pd kitchen afternoon camisole neutral
        with dissolve
        deni_thought "They really did have a lot of chunky... chicas... back then."

        show denise_pd kitchen afternoon camisole angry
        with dissolve
        deni_thought "Hey... wait a minute!"

        call music_fade_slow from _call_music_fade_slow_86

        show denise_pd kitchen afternoon camisole unhappy
        with dissolve
        deni_thought "Now I understand why everyone's always giggling about that ice cream!"

        show denise_pd kitchen afternoon camisole unhappy:
            0.5
            easeout 2.5 xpos 0.0 xanchor 1.0
        with dissolve

        deni "D'oh..."

    scene black
    with dissolve
    pause 2.0
    return
