label w02d06_s01:
    scene black
    with fade

    call setmdpathlockoutprefrences from _call_setmdpathlockoutprefrences
    call message_seatbelts from _call_message_seatbelts

    $ renpy.pause(2.0, hard='True')
    call theme_charlotte_dramatic from _call_theme_charlotte_dramatic
    $ renpy.pause(2.0, hard='True')

    scene stripmall_bg storefront_2640x1200:
        subpixel True
        xalign 0.9 yalign 0.1
        zoom ((2640.0/1920.0) * 1.2)
        easein (60.0*2.0) zoom 1.0
    show charlotte_pd stripmall groceries talklookright:
        subpixel True
        zoom 1.2 xalign 0.3 yalign 0.0
        easein 47.1 zoom 1.0 xalign 0.5 yalign 1.0
    show dreamsequcence_corona inv
    with dissolve

    $ renpy.pause(2.0, hard='True')

    char "Hey, it's me."
    pc "Hey you. Everything okay?"

    show stripmall_bg storefront_2640x1200
    show charlotte_pd stripmall groceries talklookleft
    with dissolve
    char "Yeah, I'm getting the last few things now."

    show stripmall_bg storefront_2640x1200
    show charlotte_pd stripmall groceries talklookright
    with dissolve
    char "Don't forget, you need to go pick up the dresses."
    pc "How could I forget?"

    show stripmall_bg storefront_2640x1200
    show charlotte_pd stripmall groceries eyeroll
    with dissolve
    char "Like you usually do."




    show stripmall_bg storefront_2640x1200
    show charlotte_pd stripmall groceries talklookright
    with dissolve
    char "Are you still at work? You should leave now if you want to make it."
    pc "Yeah, I'm leaving now."

    default w02d06_s01_had_to_do_something = False
    menu:
        "[abgreen]'I had to do something...'":
            $ w02d06_s01_had_to_do_something = True
            pc "Had to take care of some... unpleasant... business."

            show stripmall_bg storefront_2640x1200
            show charlotte_pd stripmall groceries talklookleft
            with dissolve
            char "Tell me all about it when you get home."
            pc "I will."
        "Say nothing.":
            $ w02d06_s01_had_to_do_something = False
            pc "..."

    pc "Is [macy_name] with you?"

    show stripmall_bg storefront_2640x1200
    show charlotte_pd stripmall groceries eyeroll eyesclosed
    with dissolve
    char "No."
    pc "Is she upset that I couldn't make it in time?"

    show stripmall_bg storefront_2640x1200
    show charlotte_pd stripmall groceries annoyed
    with dissolve
    char "She was being a complete dick about it, if I'm being honest."
    pc "That bad, eh?"

    show stripmall_bg storefront_2640x1200
    show charlotte_pd stripmall groceries eyeroll
    with dissolve
    char "Yeah. Sometimes, I just want to... ugh! you know?"














    pc "Don't worry, I'll talk to her when I get back."
    pc "So, did you pick it up?"

    show stripmall_bg storefront_2640x1200
    show charlotte_pd stripmall groceries annoyed
    with dissolve
    char "I did. Why did you have to preorder with a store all the way out here?"

    default w02d06_s01_explained = False
    menu:
        "[abgreen]Explain.":
            $ w02d06_s01_explained = True
            pc "Tradition."
            pc "When the first movie hit the stores, this was the only one in town that had a copy left on release day."
            pc "Ever since, [macy_name] and I have come here when the next episode is released."
            pc "We share an ice cream, pick up some popcorn, and then go home to watch it together."

            show stripmall_bg storefront_2640x1200
            show charlotte_pd stripmall groceries talklookleft
            with dissolve
            char "Well, if you're going to watch it with her tonight, you better..."
        "Don't.":

            $ w02d06_s01_explained = False
            pc "I'll tell you later."

            show stripmall_bg storefront_2640x1200
            show charlotte_pd stripmall groceries talklookleft
            with dissolve
            char "Okay. If you want to watch it with her tonight, you better..."

    show stripmall_bg storefront_2640x1200
    show charlotte_pd stripmall groceries drop1
    with dissolve
    char "Oh..."

    show stripmall_bg storefront_2640x1200
    show charlotte_pd stripmall groceries drop2
    with dissolve
    char "...shoot!"

    scene stripmall_backdrop backstreet
    show stripmall_bg backstreet empty
    show charlotte_pd stripmall groceries pickupdvd1 eyesclosed
    show dreamsequcence_corona inv
    with dissolve
    pc "What happened?"
    char "I dropped it. Hang on."
    char "I'm going to tuck you someplace nice and warm for a minute."

    default w02d06_s01_said_ok = False
    menu:
        "'Okay.'":
            $ w02d06_s01_said_ok = True
            pc "Okay."

    "You can hear her amusement over the phone."
    show stripmall_bg backstreet empty
    show charlotte_pd stripmall groceries pickupdvd1
    with dissolve
    char "It's your favorite place..."

    show stripmall_bg backstreet empty
    show charlotte_pd stripmall groceries pickupdvd1 eyesclosed
    with dissolve
    char "If it disconnects, I'll talk to you later."

    show stripmall_bg backstreet veryfar
    show charlotte_pd stripmall groceries pickupdvd2
    with dissolve
    "She tucks her phone away, and reaches for the fallen DVD."

    scene setpiece car daytime brad drive1:
        subpixel True
        zoom 1.1 xalign 0.8 yalign 0.2
        0.5
        ease 12.2 zoom 1.0
    show dreamsequcence_corona
    with dissolve
    brad_thought "Screw them."

    show setpiece car daytime brad drive2
    with dissolve
    brad_thought "Don't they understand I'm the victim here?!"

    show setpiece car daytime brad drink
    with dissolve
    brad "<gulp>"

    show setpiece car daytime brad drive2
    with dissolve
    brad_thought "I bet that bitch and her mother are behind this, too."

    show setpiece car daytime brad drive1
    with dissolve
    brad_thought "Shit, I need another one."

    show setpiece car daytime brad reach
    with dissolve
    brad "Plenty more where that came from."
    brad "Come here, you cheap piss flavoured..."

    scene stripmall_backdrop backstreet
    show stripmall_bg backstreet veryfar:
        subpixel True
        zoom 1.05 xalign 0.6 yalign 0.3
        0.5
        ease 18.3 zoom 1.0
    show black:
        alpha 0.0
    show charlotte_pd stripmall groceries pickupdvd2:
        subpixel True
        zoom 1.1 xalign 0.6 yalign 0.3
        0.5
        ease 18.3 zoom 1.0
        subpixel True
    show dreamsequcence_corona inv
    with fade
    char_thought "Don't drop the groceries, [charlotte_name]."

    show stripmall_bg backstreet veryfar
    show charlotte_pd stripmall groceries pickupdvd2 eyesclosed
    with dissolve
    char_thought "This fucking DVD is giving me no end of pain."

    show stripmall_bg backstreet far
    show charlotte_pd stripmall groceries pickupdvd2 eyesclosed
    with dissolve

    default w02d06_s01_yelled = False
    menu:
        "Yell!":
            $ w02d06_s01_yelled = True
            "You try to scream, to warn her, but no sound comes out."
        "[abgreen]Do nothing.":
            $ w02d06_s01_yelled = False
            "You are paralyzed, unable to do anything."

    show stripmall_bg backstreet far
    show charlotte_pd stripmall groceries pickupdvd2
    with dissolve
    char_thought "What do they like about these movies anyway?"

    show stripmall_bg backstreet medium
    show black:
        0.5
        linear 12.1 alpha 0.95
    show charlotte_pd stripmall groceries pickupdvd_lookatcamera eyesclosed
    with dissolve
    "Then, the realization hits her, too."
    char_thought "Oh..."

    show stripmall_bg backstreet medium
    show black
    show charlotte_pd stripmall groceries pickupdvd_lookatcamera
    with dissolve
    char_thought "It's that day, isn't it?"







    call music_fade_slow from _call_music_fade_slow_172

    show stripmall_bg backstreet medium
    show black
    show charlotte_pd stripmall groceries pickupdvd_lookatcamera eyesclosed
    with dissolve
    char_thought "Honey...?"


    show stripmall_bg backstreet close
    show black
    show charlotte_pd stripmall groceries pickupdvd_lookatcamera
    with dissolve
    char_thought "You know I love you, right?"

    default w02d06_s01_said_i_love_you = False
    menu:
        "[abgreen]'I love you, too.'":
            $ w02d06_s01_said_i_love_you = True
            call w02d06_s01_crash from _call_w02d06_s01_crash
            call theme_pc_sad from _call_theme_pc_sad_10

            pc "{size=-9}I love...{/size}"
            scene backdrop darkblue
            show setpiece livingroom night pc sleepcouch:
                subpixel True
                zoom 1.4 xalign 0.8 yalign 0.2
                0.5
                ease 37.0 zoom 1.0
            with fastopeneyestrans
            "But she's already gone."
        "Say nothing.":

            $ w02d06_s01_said_i_love_you = False
            call w02d06_s01_crash from _call_w02d06_s01_crash_1

            call theme_pc_sad from _call_theme_pc_sad_11

            pc "..."
            scene backdrop darkblue
            show setpiece livingroom night pc sleepcouch:
                subpixel True
                zoom 1.4 xalign 0.2 yalign 0.2
                0.5
                ease 37.0 zoom 1.0
            with fastopeneyestrans
            "Just like that, she's gone..."

    "You slowly come to your senses."
    "It feels like a weight is crushing down on your chest."
    "Your cheeks are wet, and so is the pillow below your head."

    menu:
        "Take a breath.":
            "You wipe your cheeks with the blanket and take a few deep breaths."

    "Slowly, the turmoil inside you dies down."
    "After a few minutes, the crushing feeling lifts, a little."
    "You lay back down, and let yourself drift away once more..."

    scene black
    with fade

    $ renpy.pause(2.0, hard='True')

    show text "{size=+54}{font=fonts/typeo___.ttf}Chapter three.{/font}{/size}" at truecenter
    with fade
    $ renpy.pause(2.0, hard='True')

    hide text
    with fade

    $ renpy.pause(1.0, hard='True')

    show text "{size=+54}{font=fonts/typeo___.ttf}'Bullet with butterfly wings.'{/font}{/size}" at truecenter
    with dissolve
    $ renpy.pause(3.0, hard='True')

    hide text
    with dissolve

    $ renpy.pause(1.0, hard='True')

    return

label w02d06_s01_crash:
    call sound_carcrash from _call_sound_carcrash
    show stripmall_bg backstreet close:
        easeout 0.9 zoom 1.6 xalign 0.3 yalign 0.4
    show black:
        linear 0.2 alpha 0.0
    show charlotte_pd stripmall groceries pickupdvd_lookatcamera:
        easeout 0.9 zoom 1.8 xalign 0.3 yalign 0.4
    show black as black2R:
        alpha 0.0
        0.4
        linear 0.5 alpha 1.0

    return
