label pro_s03:

    scene livingroom_bg night
    show charlotte_pd livingroom night eveningwear walk
    show dreamsequcence_corona inv
    with fade

    pc "So... home."
    scene livingroom_bg night
    show charlotte_pd livingroom night eveningwear welcome
    show dreamsequcence_corona inv
    with dissolve
    char "Yeah, home, crappy home."

    call theme_charlotte from _call_theme_charlotte_2

    menu:
        "[abgreen]Find an excuse to hold her.":
            pc "I'm still cold."
            show charlotte_pd livingroom night eveningwear holdouthand
            with dissolve
            char "And drunk."
            pc "Very drunk."
            pc "You look cold too. Come here."
        "Don't.":
            show charlotte_pd livingroom night eveningwear holdouthand
            with dissolve
            char "Hey, drunkard. Are you still cold?"
            char "You look cold."
            char "Let me <hic> warm you up a bit."

    show charlotte_pd livingroom night eveningwear closeup
    with dissolve
    "She unsteadily walks up to you, and settles into your arms with a sigh."

    menu:
        "[abgreen]'I've missed you.'":
            pc "You know I've missed you."

            show charlotte_pd livingroom night eveningwear kisscheek
            with dissolve
            char "Missed me?"
            char "What have you <hic> crap! What have you missed about me? <hic>"
            pc "Holding you close always made me feel good."

            show charlotte_pd livingroom night eveningwear closeup
            with dissolve
            char "Me too."
        "'I've missed this.'":

            pc "You know I've missed this."

            show charlotte_pd livingroom night eveningwear kisscheek
            with dissolve
            char "I have too. We used to do this all the <hic> crap..."

            show charlotte_pd livingroom night eveningwear closeup
            with dissolve
            char "...we used to do this all the time."

    pc "Why did we stop?"
    char "Stop what?"
    pc "This. Being close."

    show charlotte_pd livingroom night eveningwear unhappy
    with dissolve

    char "You know why."
    pc "Yeah. The accident."

    show charlotte_pd livingroom night eveningwear serious2
    with dissolve
    char "..."
    char "I..."
    char "I don't want to talk about that right now."

    pc "..."

    show charlotte_pd livingroom night eveningwear unhappy eyesclosed
    with dissolve
    "You hold each other in silence for a bit."
    "The heat from her body soaks into yours, radiating out from where you are pressed together."

    show charlotte_pd livingroom night eveningwear serious3 eyesclosed
    with dissolve
    "On the other side of the thin layers of fabric separating you, you can feel her heart beating."
    "It's beating fast."

    show charlotte_pd livingroom night eveningwear serious3
    with dissolve
    "Her breath is getting short, and ragged."

    show charlotte_pd livingroom night eveningwear serious1
    with dissolve
    "She looks up into your eyes."

    menu:
        "[abgreen]Look back at her.":
            "You look into her dark eyes, and a pang of melancholy surges through your body."
            "You inhale sharply, letting out a sound that is somewhere in between a sigh and a sob."

            "You're not sure if it's the alcohol or the moment, but you have a distinct feeling of vertigo as the world seems to shrink until those eyes are all that's left."
            "Without even thinking about it, you let go of control, and the moment takes over."

            show charlotte_pd livingroom night eveningwear kissmouth
            with dissolve
            "She rises up to meet your mouth."
        "Kiss.":

            "As you look onto those painfully familiar features, you can no longer hold back."
            "The touch of her body through the fabric as she leans against you electrifies your skin."

            show charlotte_pd livingroom night eveningwear kissmouth
            with dissolve
            "You lean in, and she rises to meet your mouth."

    show charlotte_pd livingroom night eveningwear kissmouth eyesclosed
    with dissolve
    "Your lips touch tenderly."
    "Time stops, and you stand there, together, for a few moments, or an eternity."
    "She stirs against you."

    show charlotte_pd livingroom night eveningwear serious1
    with dissolve
    char "Please..."
    "You are not sure if she wants you to continue, or if she wants you to stop..."

    menu:
        "Ease off.":
            show charlotte_pd livingroom night eveningwear kissmouth eyesclosed
            with dissolve
            "You try to ease off, but every inch you back out, she presses in."
            "Her fingers dig into the back of your head, preventing you from breaking the kiss."

            show charlotte_pd livingroom night eveningwear tongue1 eyesclosed
            with dissolve
            "Her lips part, and her tongue meets yours as you do the same."
        "[abgreen]Press on.":

            show charlotte_pd livingroom night eveningwear kissmouth eyesclosed
            with dissolve
            "You press on, and she matches your advance, pressing right back in to you."
            "She is every bit as eager as you are, digging her fingers into the back of your head and pulling you in."

            show charlotte_pd livingroom night eveningwear tongue1 eyesclosed
            with dissolve
            "Your lips part, and your tongue meets hers as she does the same."

    char "Mhmmm..."

    show charlotte_pd livingroom night eveningwear tongue2 eyesclosed
    with dissolve
    "Her body is pressing up against you, rubbing against you with an unbridled urgency."
    "Your body responds in kind, hardening, pressing back against hers."
    "Your tongues flick and dart around each other, probing and caressing."

    show charlotte_pd livingroom night eveningwear tongue1 eyesclosed
    with dissolve
    char "Uhm..."
    "Her mouth tastes like the sweet, intoxicating flavour of the alcohol you consumed together."
    "Any measure of inhibition that may have been left in you now drains from your bodies as your kisses intensify."

    show charlotte_pd livingroom night eveningwear tongue2 eyesclosed
    with dissolve
    char "Hmmm..."
    "You are unable to think, unsure if you're under the influence, or if it's the passion rushing through your blood that is making you yield control."
    "You just know you have only one desire; for this moment to last for ever and ever."

    call music_fade_slow from _call_music_fade_slow_26

    scene black
    with fastcloseeyestrans

    char "Hmmm..."

    call theme_macy_sad from _call_theme_macy_sad_3

    scene livingroom_bg night
    show livingroom_bg night as lbn2:
        subpixel True
        xalign 0.0 alpha 0.8 zoom 2.0
        easein 4.0 alpha 0.0 zoom 1.0
    show livingroom_bg night as lbn3:
        subpixel True
        xalign 1.0 alpha 0.8 zoom 2.0
        easein 4.0 alpha 0.0 zoom 1.0
    show macy_pd livingroom night eveningwear closeup serious
    show macy_pd livingroom night eveningwear closeup serious as mlnes2:
        subpixel True
        xpos 0.2 xanchor 0.5 alpha 0.8
        parallel:
            easein 4.0 xpos 0.5
        parallel:
            easein 4.0 alpha 0.2
            alpha 0.0
    show macy_pd livingroom night eveningwear closeup serious as mlnes3:
        subpixel True
        xpos 0.8 xanchor 0.5 alpha 0.8
        parallel:
            easein 4.0 xpos 0.5
        parallel:
            easein 4.0 alpha 0.2
            alpha 0.0
    with fastopeneyestrans

    macy "I don't want to talk about that right now."
    window hide
    show macy_pd livingroom night eveningwear closeup serious eyesclosed
    pause 2.0

    scene black
    with fastcloseeyestrans
    pc_thought "What the..."

    scene livingroom_bg night
    show charlotte_pd livingroom night eveningwear tongue2 eyesclosed
    show dreamsequcence_corona inv
    with fastopeneyestrans
    char "Hmmm..."
    pause 0.5

    scene livingroom_bg night
    show livingroom_bg night as lbn2:
        subpixel True
        xalign 0.0 alpha 0.8 zoom 2.0
        easein 4.0 alpha 0.0 zoom 1.0
    show livingroom_bg night as lbn3:
        subpixel True
        xalign 1.0 alpha 0.8 zoom 2.0
        easein 4.0 alpha 0.0 zoom 1.0
    show macy_pd livingroom night eveningwear tongue2 eyesclosed
    show macy_pd livingroom night eveningwear tongue2 eyesclosed as mlnet22:
        subpixel True
        xpos 0.2 xanchor 0.5 alpha 0.8
        parallel:
            easein 4.0 xpos 0.5
        parallel:
            easein 4.0 alpha 0.2
            alpha 0.0
    show macy_pd livingroom night eveningwear tongue2 eyesclosed as mlnet23:
        subpixel True
        xpos 0.8 xanchor 0.5 alpha 0.8
        parallel:
            easein 4.0 xpos 0.5
        parallel:
            easein 4.0 alpha 0.2
            alpha 0.0
    with dissolve

    macy "Mhmmm..."
    show macy_pd livingroom night eveningwear tongue1 eyesclosed
    with dissolve
    macy "Uhm... hmmm..."

    show macy_pd livingroom night eveningwear tongue2 eyesclosed
    with dissolve
    pause 0.4
    show macy_pd livingroom night eveningwear tongue2
    with dissolve
    pc "Wait... wait!"

    show macy_pd livingroom night eveningwear closeup shock
    with dissolve
    "She stands looking at you with labored breath."
    macy "Don't. Please..."

    "As the realization of what you just did dawns on you, you stand petrified. Horrified."

    show macy_pd livingroom night eveningwear closeup scared
    with dissolve
    pc "I'm sorry. I'm so sorry princess."

    macy "..."

    show macy_pd livingroom night eveningwear dont
    with dissolve
    "You break away from her, and a wave of guilt washes over you, drowning out any other thought."
    pc "I didn't mean to force myself on you."

    show macy_pd livingroom night eveningwear please
    with dissolve
    macy "No, [macy_adr_pc_as], you..."

    call music_fade_slow from _call_music_fade_slow_27

    pc "I'm so sorry. I... I thought you were... "
    scene setpiece livingroom night charlotte photo
    with fade
    pc "Her..."

    call theme_macy_mad from _call_theme_macy_mad

    scene livingroom_bg night
    show macy_pd livingroom night eveningwear please eyesclosed
    with fade
    macy "..."

    show macy_pd livingroom night eveningwear please
    with dissolve
    "She just looks back at you, stunned, as if you'd just struck her in the face."

    macy "You..."

    show macy_pd livingroom night eveningwear angry
    with dissolve
    macy "You...! "

    show macy_pd livingroom night eveningwear abouttopunch
    with dissolve
    extend "FUCKING...! BASTARD!!!"

    call sound_punch from _call_sound_punch
    scene livingroom_bg night
    show macy_pd livingroom night eveningwear punch
    with hpunch
    "You hear something crunch inside your face when her fist connects with it."

    scene black
    with fastcloseeyestrans
    "The world goes black for a moment."
    "A sickly sweet, metallic taste hits your palate."
    "The pain of the hit doesn't {i}really{/i} register... "

    scene livingroom_bg night
    show macy_pd livingroom night eveningwear abouttopunch
    with fastopeneyestrans
    pause 0.3

    call sound_punch from _call_sound_punch_1
    scene livingroom_bg night
    show macy_pd livingroom night eveningwear punch
    with hpunch
    extend "until right before the second one lands."

    call music_fade_slow from _call_music_fade_slow_28


    scene black
    with fastcloseeyestrans
    "As you fall to your knees, she rushes out of the room..."

    call sound_doorslam from _call_sound_doorslam_3
    with hpunch
    "...slamming the door behind her."

    call theme_pc_sad from _call_theme_pc_sad_4

    scene livingroom_bg night
    with openeyestrans
    "You scramble to your feet, cupping your nose."
    "An intense feeling of dread comes over you, mixed, surprisingly, with an utterly misplaced glimmer of pride at the sheer force of her left."

    pc_thought "My princess..."
    pc_thought "Oh fuck..."
    pc_thought "Oh fuck oh fuck oh fuck!"
    pc_thought "What have I done to you?!"

    call music_fade_slow from _call_music_fade_slow_29
    pc_thought "..."

    scene black
    with fade

    pause 1.0

    return
