label w01d07_s02:
    scene kitchen_bg morning
    with fade

    "You take a quick bite while [denise_name] finishes in the bathroom."

    scene black
    with fade
    "After, you take your turn in the bathroom and get dressed."

    call theme_macy from _call_theme_macy_14
    scene kitchen_bg morning
    show macy_pd kitchen morning nightwear neutral:
        subpixel True
        xanchor 1.0 xpos 0.0
        0.5
        easein 3.2 xalign 0.5
    with fade

    "When you return from the bathroom, [macy_name] is already up."

    default w01d07_s02_pc_said_princess = True
    menu:
        "'Good morning, [macy_name].'":
            $ w01d07_s02_pc_said_princess = False
            pc "Good morning, [macy_name]."
        "[abgreen]'Good morning, princess.'":

            $ w01d07_s02_pc_said_princess = True

            pc "Good morning, princess."

            show macy_pd kitchen morning nightwear annoyed
            with dissolve
            macy "..."

            show macy_pd kitchen morning nightwear neutral
            with dissolve

    macy "Good morning, [player_name]."
    macy "Going out somewhere?"

    pc "Didn't [denise_name] tell you?"
    pc "We're going to the museum."
    pc "Care to join us?"

    show macy_pd kitchen morning nightwear smile
    with dissolve
    macy "Museum... museum... let me think..."

    show macy_pd kitchen morning nightwear shocked
    with dissolve
    macy "Uh... No thanks!"

    show macy_pd kitchen morning nightwear eyeroll
    with dissolve
    macy "If I want to see a dinosaur, I can just watch you lounging on the couch."

    pc "Very funny."

    call music_fade_slow from _call_music_fade_slow_150

    show macy_pd kitchen morning nightwear smile
    with dissolve
    macy "I know, it's so weird. I have no clue why I'm gifted with the talent of laughter."

    show macy_pd kitchen morning nightwear neutral
    with dissolve
    macy "I sure didn't get that from you."

    pc "Ouch..."

    call theme_denise from _call_theme_denise_28
    show macy_pd kitchen morning nightwear shocked:
        subpixel True
        yalign 1.0
        0.5
        ease 0.2 zoom 1.01
        ease 0.2 zoom 1.0
    with dissolve
    "At that moment, [denise_name] enters the room."

    scene setpiece kitchen morning denise doorway gypsyboho vignette:
        subpixel True
        yalign 1.0
        ease 12.0 yalign 0.0
    with fade

    pause

    $ persistent.unlock_d_boho_dress = True

    scene kitchen_bg morning
    show macy_pd kitchen morning nightwear shocked:
        subpixel True
        xalign 0.5
        0.5
        ease 1.8 xalign 0.25
        0.5
        ease 0.7 xalign 0.75
    show denise_pd kitchen morning gypsyboho smile:
        subpixel True
        xanchor 0.0 xpos 1.0
        0.5
        easein 2.1 xalign 0.75
        0.2
        ease 0.9 xalign 0.25

    with fade

    pc "..."
    macy "..."

    menu:
        "[abgreen]'Wow!'":
            "Before you can speak up, [macy_name] interrupts."
        "Say nothing.":
            pc "..."

    macy "Whoa!"

    show denise_pd kitchen morning gypsyboho unhappy
    with dissolve
    deni "What?!"

    macy "You look..."

    show macy_pd kitchen morning nightwear smile
    with dissolve
    macy "...stunning."

    show denise_pd kitchen morning gypsyboho happy
    with dissolve
    deni "Really?"

    show macy_pd kitchen morning nightwear shocked
    with dissolve
    macy "Yeah. All that for a stuffy museum?"

    show denise_pd kitchen morning gypsyboho unhappy
    with dissolve
    deni "It's not stuffy. It's art."

    show denise_pd kitchen morning gypsyboho happy
    with dissolve
    deni "And I'm going out on a date with my [denise_adr_pc_as]."

    show denise_pd kitchen morning gypsyboho smile
    with dissolve
    deni "Why shouldn't I look nice?"

    show macy_pd kitchen morning nightwear neutral
    with dissolve
    macy "No reason, just saying."

    show macy_pd kitchen morning nightwear smile
    with dissolve
    macy "Dayum, I gotta step my game up with you around."

    show denise_pd kitchen morning gypsyboho happy
    with dissolve
    deni "Heehee..."

    show denise_pd kitchen morning gypsyboho smile
    with dissolve
    deni "What do you think, [denise_adr_pc_as]?"

    default w01d07_s02_pc_thought_dress_was_amazing = True
    menu:
        "[abgreen]'You look amazing.'":
            $ w01d07_s02_pc_thought_dress_was_amazing = True
            pc "You look absolutely amazing, angel."

            show denise_pd kitchen morning gypsyboho unhappy
            with dissolve
            deni "You don't think it's too much for a museum?"
            pc "No, you look absolutely perfect."

            show denise_pd kitchen morning gypsyboho happy
            with dissolve
            deni "Thank you, [denise_adr_pc_as]."
        "'You look nice.'":

            $ w01d07_s02_pc_thought_dress_was_amazing = False
            pc "It's nice."

            show denise_pd kitchen morning gypsyboho happy
            with dissolve
            deni "..."

            show macy_pd kitchen morning nightwear shocked
            with dissolve
            macy "Just nice?"

            show macy_pd kitchen morning nightwear annoyed
            with dissolve
            macy "You must need new specs or something."

    pc "We should get going if we want to beat the crowd."

    show denise_pd kitchen morning gypsyboho smile
    with dissolve
    deni "Yes please."

    show denise_pd kitchen morning gypsyboho unhappy
    with dissolve
    deni "I don't like crowds."

    show macy_pd kitchen morning nightwear neutral
    with dissolve
    macy "Have fun."

    call music_fade_slow from _call_music_fade_slow_151
    show denise_pd kitchen morning gypsyboho smile:
        subpixel True
        0.5
        easeout 2.4 xanchor 0.0 xpos 1.0
    show macy_pd kitchen morning nightwear neutral:
        subpixel True
        1.3
        ease 0.7 xalign 0.5
    with dissolve
    deni "See you, [denise_adr_macy_as]!"

    show macy_pd kitchen morning nightwear neutral:
        subpixel True
        0.5
        ease 2.7 xpos 0.0 xanchor 1.0
    macy "Take good care of her..."

    pc "I will."

    scene black
    pause 2.0

    return
