label pro_s02:
    scene black
    show text "{size=+54}{font=fonts/typeo___.ttf}Chapter one.{/font}{/size}" at truecenter
    with fade
    $ renpy.pause(2.0, hard='True')

    hide text
    with fade

    $ renpy.pause(1.0, hard='True')

    scene black
    show text "{size=+54}{font=fonts/typeo___.ttf}'Broken face.'{/font}{/size}" at truecenter
    with fade
    $ renpy.pause(3.0, hard='True')

    scene black
    with fade
    call theme_drunk from _call_theme_drunk

    pc_thought "It's kinda nippy out."
    pc_thought "I should have worn a coat."

    scene outside_bg city night
    show charlotte_pd outside night eveningwear walk_right
    show dreamsequcence_corona inv
    with fade
    "You stumble along the deserted streets."

    "A woman walks a few feet ahead of you."

    show charlotte_pd outside night eveningwear walk_left_followme
    with dissolve
    "You know her. Intimately. You think."

    scene outside_bg city night
    show outside_bg city night as ocn2:
        subpixel True
        xalign 0.0 alpha 0.8 zoom 2.0
        easein 2.5 alpha 0.3 zoom 1.0
    show outside_bg city night as ocn3:
        subpixel True
        xalign 1.0 alpha 0.8 zoom 2.0
        easein 2.5 alpha 0.3 zoom 1.0
    show charlotte_pd outside night eveningwear walk_left_followme
    show charlotte_pd outside night eveningwear walk_left_followme as conewlf:
        subpixel True
        xpos 0.2 xanchor 0.5 alpha 0.8
        parallel:
            easein 2.5 xpos 0.5
        parallel:
            easein 2.5 alpha 0.2
            alpha 0.0
    show charlotte_pd outside night eveningwear walk_left_followme as conewlf3:
        subpixel True
        xpos 0.8 xanchor 0.5 alpha 0.8
        parallel:
            easein 2.5 xpos 0.5
        parallel:
            easein 2.5 alpha 0.2
            alpha 0.0
    show dreamsequcence_corona inv
    with dissolve
    "Drunk as you are, it takes all your effort to ensure your feet stay connected to the street."

    scene outside_bg city night
    show charlotte_pd outside night eveningwear walk_left_lookback
    show dreamsequcence_corona inv
    with hpunch
    "A little pebble awkwardly shifts under your sole, and almost makes you lose your footing."

    show charlotte_pd outside night eveningwear walk_left_reachback
    with dissolve
    char "Don't fall behind, old man!"
    pc_thought "Heh, I'd settle for 'don't fall'."

    show charlotte_pd outside night eveningwear walk_right
    with dissolve
    "Your next words come out as slurred as hers."

    show charlotte_pd outside night eveningwear walk_left
    with dissolve
    menu:
        "'Who are you calling old?'":
            pc "Who are you calling old?! You're no spring chicken yourself, you know!"
            "You giggle a bit to yourself at that."

            show charlotte_pd outside night eveningwear walk_right
            with dissolve
            char "What a peculiar thing to shay to me! <hic>"

            show charlotte_pd outside night eveningwear walk_left
            with dissolve
            char "Just for that, I'll leave you behind if you don't keep up."
        "[abgreen]'The street tried to trip me up!'":

            pc "The bloody street is out to get me I swear! It's the second time it tried to trip me up."
            "You giggle a bit to yourself at that."

            show charlotte_pd outside night eveningwear walk_right
            with dissolve
            char "I never realized you were such a lightweight! <hic>"

            show charlotte_pd outside night eveningwear walk_left
            with dissolve
            char "Now, keep up, or do I have to carry you?"

    show charlotte_pd outside night eveningwear walk_right
    with dissolve
    "She keeps walking in front of you."

    show charlotte_pd outside night eveningwear walk_left
    with dissolve
    "Amazingly steady, given that she surely had as much to drink as you did."
    "You, however, seem to end up bouncing off the wall on your left every few steps."

    show charlotte_pd outside night eveningwear walk_right
    with dissolve
    default intro_looked_at_behind = False
    menu:
        "[abgreen]Look at her behind.":
            $ intro_looked_at_behind = True

            "You rest your eyes on her swaying backside, and decide it gives you a nice focal point as you stagger along the pavement."

            show charlotte_pd outside night eveningwear walk_right_stretch
            with dissolve
            char "What's that? You like what you see? <chuckle>"
            pc "Shit, did I say something out loud?"

            show charlotte_pd outside night eveningwear walk_right_stretch_reach
            with dissolve
            char "Out of the mouths of babes and drunks, I guess."
        "Don't.":
            "You wrest your eyes away and make a non-trivial effort to keep up, barely succeeding."

    scene outside_bg crossroad night
    show charlotte_pd outside night eveningwear walk_left
    show dreamsequcence_corona inv
    with fade

    "You walk along in silence for a bit."

    "A thought hits you, and you stumble to a stop, swaying slightly as you do."

    scene outside_bg crossroad night
    show outside_bg crossroad night as ocn2:
        subpixel True
        xalign 0.0 alpha 0.8 zoom 2.0
        easein 2.5 alpha 0.3 zoom 1.0
    show outside_bg crossroad night as ocn3:
        subpixel True
        xalign 1.0 alpha 0.8 zoom 2.0
        easein 2.5 alpha 0.3 zoom 1.0
    show charlotte_pd outside night eveningwear walk_left
    show charlotte_pd outside night eveningwear walk_left as conewl:
        subpixel True
        xpos 0.2 xanchor 0.5 alpha 0.8
        parallel:
            easein 2.5 xpos 0.5
        parallel:
            easein 2.5 alpha 0.2
            alpha 0.0
    show charlotte_pd outside night eveningwear walk_left as conewl3:
        subpixel True
        xpos 0.8 xanchor 0.5 alpha 0.8
        parallel:
            easein 2.5 xpos 0.5
        parallel:
            easein 2.5 alpha 0.2
            alpha 0.0
    show dreamsequcence_corona inv
    with dissolve
    pause 1.5
    pc "..."
    pc "Remind me, how did we get this drunk?"

    show charlotte_pd outside night eveningwear walk_right
    with dissolve
    char "Did you forget? We went out to do shotsh."

    show charlotte_pd outside night eveningwear walk_left
    with dissolve
    char "You two suggested it."

    show charlotte_pd outside night eveningwear walk_left_lookback
    with dissolve
    char "'Shotsh'... <giggle>"

    menu:
        "[abgreen]'Oh yeah...'":
            pc "Yeah I remember. I think."
        "'Did I?'":
            pc "I can't remember. Did I shuggest shots?"

    show charlotte_pd outside night eveningwear walk_left_reachback
    with dissolve
    char "Well, actually, you just suggested drinks. Four beers in, I suggested making them shots. <hic> crap!"

    call music_fade_slow from _call_music_fade_slow_2

    show charlotte_pd outside night eveningwear walk_right
    with dissolve
    pc "Ah. I shee. That makes more sense."

    "You start to stumble in a mostly forward direction again."

    if intro_looked_at_behind:
        call theme_macy_sad from _call_theme_macy_sad
        scene black
        with fastcloseeyestrans

        scene outside_bg city night
        show outside_bg city night as ocn2:
            subpixel True
            xalign 0.0 alpha 0.8 zoom 2.0
            easein 2.5 alpha 0.3 zoom 1.0
        show outside_bg city night as ocn3:
            subpixel True
            xalign 1.0 alpha 0.8 zoom 2.0
            easein 2.5 alpha 0.3 zoom 1.0
        show macy_pd outside night eveningwear stretch
        show macy_pd outside night eveningwear stretch as mones2:
            subpixel True
            xpos 0.2 xanchor 0.5 alpha 0.8
            parallel:
                easein 2.5 xpos 0.5
            parallel:
                easein 2.5 alpha 0.2
                alpha 0.0
        show macy_pd outside night eveningwear stretch as mones3:
            subpixel True
            xpos 0.8 xanchor 0.5 alpha 0.8
            parallel:
                easein 2.5 xpos 0.5
            parallel:
                easein 2.5 alpha 0.2
                alpha 0.0
        with fastopeneyestrans

        pause 1.2
        macy "{i}What's that? You like what you see? <chuckle>{/i}"

        call music_fade_slow from _call_music_fade_slow_3

        window hide
        pause 0.2
        scene black
        with fastcloseeyestrans
        pause 1.0

        scene outside_bg crossroad night
        show charlotte_pd outside night eveningwear walk_right
        show dreamsequcence_corona inv
        with fastopeneyestrans

        pc_thought "What the...?!"

        show charlotte_pd outside night eveningwear walk_left_lookback
        char "What's wrong?"
        pc "Nothing, I thought I... saw... something..."

        show charlotte_pd outside night eveningwear walk_left_followme
        char "Lightweight! <chuckle>"
        char "Just don't <hic> crap... Don't puke all over yourself okay? Let's go."

        show charlotte_pd outside night eveningwear walk_right
        pc "Yeah, yeah. I'm coming."

    call theme_charlotte from _call_theme_charlotte

    scene outside_bg park night
    show charlotte_pd outside night eveningwear walk_left
    show dreamsequcence_corona inv
    with fade

    char "Good. Now, the real question is: do you remember how to get home?"
    pc "Yeah, just follow this... thing... and when we get to... that there... then we... eh."

    show charlotte_pd outside night eveningwear walk_left_lookback
    with dissolve
    char "Got it all under control, I see."

    pc "Yeah."

    show charlotte_pd outside night eveningwear walk_right
    with dissolve
    pc "Sheesh, aren't you cold?"
    menu:
        "[abgreen]'Come close.'":
            pc "Hold up for a second, stand close and let me warm you up."

            show charlotte_pd outside night eveningwear standandface
            with dissolve
            "She stops, and turns to look at you."
            "Her face is achingly familiar to you."
            char "To warm {i}me{/i} up, or warm {i}you{/i} up?"
        "'Take my coat.'":

            pc "Here, you can take my coat."

            show charlotte_pd outside night eveningwear standandface
            with dissolve
            "She stops, and turns to look at you."
            "Her face is achingly familiar to you."
            char "<chuckle> You must be more drunk than I thought. You're not wearing a <hic> coat, stupid."

    "She launches into a lilting monologue."
    char "Don't you know? <hic> You don't know. <hic> Don't you know, women dressed to go out are immune to the cold."
    char "It's in our geny... our genefy... <hic> crap. It's in our DNA."
    char "All the ladies who couldn't take it died off centuries ago."
    char "It's because you bastards force us to wear these flimsy little <hic>, crap! <giggle>"

    "The hiccup has made her lose her train of thought, and she walks up close to you."

    scene outside_bg lookuplights night
    show charlotte_pd outside night eveningwear hug
    show dreamsequcence_corona inv
    with fade

    "You feel the warmth of her body radiate into yours even before she presses against you."
    "She gazes unsteadily into your eyes."

    $ intro_complimented = False
    menu:
        "[abgreen]Compliment her.":
            $ intro_complimented = True
            pc "You look wonderful tonight."
            char "I do, eh?"
            char "I'm not sure if you should say such things to me."
        "Say nothing.":
            pc "..."
            char "Struck dumb by my radiant beauty, eh?"
            char "I'll take that as a compliment. <hic> Dumbass!"

    $ intro_kissed_on_mouth = False
    menu:
        "Kiss her cheek.":
            show charlotte_pd outside night eveningwear kisscheek
            with dissolve
            "You lean in, and plant a light kiss on her cheek."

            show charlotte_pd outside night eveningwear hug
            char "Someone's getting a bit frisky."
        "[abgreen]Kiss her mouth.":

            $ intro_kissed_on_mouth = True
            show charlotte_pd outside night eveningwear kissmouth
            with dissolve
            "You lean in, with the intention to give her a peck on the mouth."
            "Even brushing her lips lightly with yours, you can taste the heady flavour of alcohol on them."

            show charlotte_pd outside night eveningwear kissmouth eyesclosed
            with dissolve
            "You linger a few heartbeats too long for it to still count as a peck."

            show charlotte_pd outside night eveningwear hug
            char "Well, that is definitely not appropriate."
        "Do nothing.":

            "You stand for a few seconds, drinking in the image of her face."
            char "You are weird. You know that, right?"

    call music_fade_slow from _call_music_fade_slow_4

    if intro_kissed_on_mouth:
        scene outside_bg park night
        show charlotte_pd outside night eveningwear walk_right_stretch
        show dreamsequcence_corona inv
        with fade
    else:
        scene outside_bg park night
        show charlotte_pd outside night eveningwear walk_right
        show dreamsequcence_corona inv
        with fade

    "She breaks away from you and starts walking."

    if intro_kissed_on_mouth:
        show charlotte_pd outside night eveningwear walk_right_stretch_reach
        with dissolve
    char "C'mon, let's get our drunk asses home."

    "You start walking again."

    if intro_kissed_on_mouth:

        call theme_macy_sad from _call_theme_macy_sad_1
        scene black
        with fastcloseeyestrans

        scene outside_bg lookuplights night
        show outside_bg lookuplights night as oln2:
            subpixel True
            xalign 0.0 alpha 0.8 zoom 2.0
            easein 2.5 alpha 0.0 zoom 1.0
        show outside_bg lookuplights night as ooln3:
            subpixel True
            xalign 1.0 alpha 0.8 zoom 2.0
            easein 2.5 alpha 0.0 zoom 1.0
        show macy_pd outside night eveningwear closeup
        show macy_pd outside night eveningwear closeup as monekm2:
            subpixel True
            xpos 0.2 xanchor 0.5 alpha 0.8
            parallel:
                easein 2.5 xpos 0.5
            parallel:
                easein 2.5 alpha 0.2
                alpha 0.0
        show macy_pd outside night eveningwear closeup as monekm3:
            subpixel True
            xpos 0.8 xanchor 0.5 alpha 0.8
            parallel:
                easein 2.5 xpos 0.5
            parallel:
                easein 2.5 alpha 0.2
                alpha 0.0
        with fastopeneyestrans
        pause 2.5

        show macy_pd outside night eveningwear kissmouth
        pause 0.2
        show macy_pd outside night eveningwear kissmouth eyesclosed
        with dissolve
        pause 1.2

        show macy_pd outside night eveningwear closeup
        with dissolve

        macy "{i}Well, that is definitely not appropriate.{/i}"

        window hide
        pause 0.2

        scene black
        with fade
        pc_thought "What is happening?!"

        scene outside_bg lookuplights night
        show macy_pd outside night eveningwear laugh
        with fade

        pause 0.4
        scene black
        with fade

        scene outside_bg lookuplights night
        show macy_pd outside night eveningwear lean closedeyes
        with fade
        pause 0.2
        show macy_pd outside night eveningwear lean
        with dissolve

        call music_fade_slow from _call_music_fade_slow_5

        pause 0.4
        scene black
        with fastcloseeyestrans

        pause 1.0
        scene outside_bg park night
        show charlotte_pd outside night eveningwear standandface
        show dreamsequcence_corona inv
        with fastopeneyestrans

        char "Seeing things again? Should I be <hic> worried?"
        pc "No, no I'm fine. Let'sh go."
        char "..."
        char "If you're sure..."

    show charlotte_pd outside night eveningwear walk_left
    with dissolve
    "You walk for a few more minutes in silence."

    scene outside_bg woodlandroad night
    show outside_bg woodlandroad night as own2:
        subpixel True
        xalign 0.0 alpha 0.8 zoom 2.0
        easein 2.5 alpha 0.0 zoom 1.0
    show outside_bg woodlandroad night as own3:
        subpixel True
        xalign 1.0 alpha 0.8 zoom 2.0
        easein 2.5 alpha 0.0 zoom 1.0
    show charlotte_pd outside night eveningwear walk_right:
        xalign 0.3
    show charlotte_pd outside night eveningwear walk_right as conewr2:
        subpixel True
        xpos 0.0 xanchor 0.3 alpha 0.8
        parallel:
            easein 2.5 xpos 0.3
        parallel:
            easein 2.5 alpha 0.2
            alpha 0.0
    show charlotte_pd outside night eveningwear walk_right as conewr3:
        subpixel True
        xpos 0.6 xanchor 0.3 alpha 0.8
        parallel:
            easein 2.5 xpos 0.3
        parallel:
            easein 2.5 alpha 0.2
            alpha 0.0
    show dreamsequcence_corona inv
    with fade

    "The streets don't stop swaying. If anything, it's getting worse."

    show charlotte_pd outside night eveningwear walk_left_lookback
    with dissolve
    "Finally, a familiar row of houses comes into view."
    "You fish the keys out of your pocket, and fumble with them for a minute or so."

    show charlotte_pd outside night eveningwear standandface
    with dissolve
    char "Here, let <hic> me."

    "You hand her your keys, and she quickly has the door open."
    "You follow her in."

    return
