label w01d01_s02:
    "After a short drive, you arrive at your workplace."

    call theme_pc from _call_theme_pc_4
    scene setpiece office midday building
    with fade

    pc_thought "CompuPartner 3000 Ltd."
    pc_thought "Subsidiary of Aer Calidus Holding inc."
    pc_thought "If there is any justice in this world, the jumble of fonts alone should have been grounds for immediate termination of employment for someone."
    pc_thought "Fun fact: CompuPartner 3000 was not established in the year 3000, but in 1989."
    pc_thought "That's quite venerable for a software company."
    pc_thought "Of course, now it's mostly just serving a slowly shrinking group of customers, to keep a few poorly aged applications running."
    pc_thought "But it pays the bills. Just."

    scene black
    with fade
    "You go inside, grab a mug of something that could be tea, coffee or dishwater, and find your desk."

    scene setpiece office midday desk
    with fade
    "You plug your laptop into the external monitor, boot up, and get to work, starting with your mail."
    "Some requests from support for help."
    "A fresh batch of tickets and tasks to be finished by the end of the week."
    "A missive from management on the importance of registering hours daily in all four different registration systems before the end of work."

    call music_fade_slow from _call_music_fade_slow_36
    "You look up as you sense someone standing near your desk."

    call theme_brooke from _call_theme_brooke_1

    scene backdrop officemidday
    show setpiece office midday brooke vignette:
        subpixel True
        yalign 1.0
        0.5
        ease 7.0 yalign 0.0
    with fade

    pause 7.0

    $ persistent.unlock_brook_at_office = True

    $ tmp = renpy.input("What's her name? (press enter for '[brooke_name]'")
    $ tmp = tmp.strip()
    if tmp != "":
        $ brooke_name = tmp

    $ persistent.brooke_name = brooke_name
    $ met_brooke = True

    scene office_bg midday
    show brooke_pd office midday cubicle smile
    with dissolve
    pc_thought "[brooke_name] has worked here longer than me, although she's probably a year or two younger than me."
    pc_thought "She's now the team lead for the Mobile App team, housed here by the holding to fill up the plentiful empty office space that resulted from repeated downsizing."
    pc_thought "It's the only product that's consistently showing growing profits instead of shrinking ones."

    menu:
        "Say hi.":
            pc "Hi, [brooke_name]. What's up?"

    show brooke_pd office midday cubicle happy
    with dissolve
    broo "Good morning, [player_name]. How was your weekend?"

    menu:
        "[abgreen]Be nice.":
            pc "Yeah, it was... good. I guess. Finally watched that last season of Gambit of Seats, right in time for the next one."
            pc "Eh, so how was yours?"

            show brooke_pd office midday cubicle talk
            with dissolve
            broo "Really good actually. I went to a wine tasting in the country with some of my friends."
            show brooke_pd office midday cubicle flirt
            with dissolve
            broo "We booked this B&B because none of us wanted to be the designated driver, which was just as well as the wine was delicious."
            show brooke_pd office midday cubicle happy
            with dissolve
            broo "It was a lovely weekend."
            show brooke_pd office midday cubicle talk
            with dissolve
            broo "Anyways, I won't bore you with all the details."
        "Be dismissive.":

            pc "Just fine. Listen, I got an awful lot to do so..."
            show brooke_pd office midday cubicle talk
            with dissolve
            broo "Sure, sure. I understand."

    show brooke_pd office midday cubicle serious
    with dissolve
    broo "I just came by to tell you they moved the meeting times again."
    show brooke_pd office midday cubicle talk
    with dissolve
    broo "Pre-postmortem meeting for planning refinements is now from one thirty to three thirty."
    show brooke_pd office midday cubicle serious
    with dissolve
    broo "People don't want to start at three anymore since the meetings are always running long."
    show brooke_pd office midday cubicle smile
    with dissolve
    broo "Product management wants you to sit in again on account of the interface with the legacy software."

    pc "I... see. Thanks for the heads-up. I'll make sure I'm ready."

    show brooke_pd office midday cubicle concern
    with dissolve
    broo "..."
    show brooke_pd office midday cubicle serious
    with dissolve
    broo "You seem to have second thoughts, am I right?"
    show brooke_pd office midday cubicle concern
    with dissolve
    broo "It's okay, so do I. What's your honest opinion?"

    show brooke_pd office midday cubicle concern
    with dissolve
    menu:
        "[abgreen]Be honest.":
            pc "Well, it seems to me that some managers don't really understand what's going on."
            pc "So they're having a lot of meetings to try and get 'in control'."
            pc "But instead, they mostly take up the time of the people who do understand what needs doing, and just want to get on with it."
            pc "Back when I managed a couple of teams, we had a fraction of the meetings we have here, and effective output was a lot higher."
        "Be evasive.":

            pc "It's not my place to question their policies, really."
            pc "It's up to them to set the rules, I'm not managing any teams anymore."

    show brooke_pd office midday cubicle smile
    with dissolve
    broo "Wait, you were a manager before? When was that?"

    pc "That was before I came to work here."
    menu:
        "[abgreen]Elaborate.":
            pc "And it wasn't management per se, not like here."
            pc "It was a lot more hands on, stepping in to do the work that needed doing together."
            pc "But all the same, I did run a few teams, spread out all over."
            pc "Lots of traveling. I loved that, even if it meant I was away from home often."
        "Don't.":

            pc "That's all in the past now."

    show brooke_pd office midday cubicle talk
    with dissolve
    broo "If you don't mind me asking, why did you go back to being a code monkey?"
    show brooke_pd office midday cubicle happy
    with dissolve
    broo "I mean, no offence, but they're keeping you guys on the legacy applications team on a pretty short leash here."

    menu:
        "[abgreen]Tell her.":
            show brooke_pd office midday cubicle concern
            with dissolve
            pc "I went through a pretty dark period in my life a few years back."
            pc "I... just couldn't handle it all anymore."
            menu:
                "[abgreen]'I needed to take care of my [group_adr_as].'":
                    pc "I couldn't continue working as I was {i}and{/i} take care of my [group_adr_as]."
                    pc "I needed to ease off and focus on them."
                "'I needed to get myself together.'":
                    pc "I just couldn't keep up anymore."
                    pc "I needed to ease off and get myself together."

            pc "I had to take a step back, and long story short, I ended up here..."
            pc "...doing something I could handle with everything that was going on, and to help take my mind off... things."

            pc_thought "I'm not going to tell her that the salary barely leaves enough to provide for my girls after paying off our debts."
            pc_thought "With [macy_name] helping out a little, we make ends meet, and that's what counts."

            show brooke_pd office midday cubicle worried
            with dissolve
            broo "I'm sorry to hear that."
        "Don't.":

            show brooke_pd office midday cubicle concern
            with dissolve
            pc "Honestly, I don't really want to talk about that."

            show brooke_pd office midday cubicle worried
            with dissolve
            broo "I'm sorry, I didn't mean to pry."

    show brooke_pd office midday cubicle concern
    with dissolve
    broo "..."
    show brooke_pd office midday cubicle worried
    with dissolve

    broo "Say, if you ever feel the need to talk to someone, I'm willing to listen."

    show brooke_pd office midday cubicle flirt
    with dissolve
    broo "And if you don't, we could, I don't know, maybe just have a friendly drink."

    show brooke_pd office midday cubicle happy
    with dissolve
    pc "Thanks, I appreciate that."

    show brooke_pd office midday cubicle smile
    with dissolve
    broo "Sure. I'll see you later."

    pc "Bye."

    call music_fade_slow from _call_music_fade_slow_37
    scene setpiece office midday desk
    with fade
    "You slog your way through the rest of the day in relative peace, and even get a decent amount of work in on your laptop during the many meetings."

    return
