label w02d02_s06:

    "Time passes quickly, and [macy_name] arrives home just as you're in the bathroom preparing for bed."

    call theme_household from _call_theme_household_11
    scene kitchen_bg lookatsink nighttime:
        subpixel True
        zoom 1.1 xalign 1.0 yalign 0.2
        0.5
        ease 17.4 zoom 1.0
    show denise_pd kitchen night angry:
        subpixel True
        zoom 1.2 xanchor 0.0 xpos 1.0 yalign 0.2
        0.5
        parallel:
            ease 17.4 zoom 1.0
        parallel:
            ease 1.8 xalign 0.3
    show macy_pd kitchen night workwear neutral:
        subpixel True
        zoom 1.2 xanchor 0.0 xpos 1.0 yalign 0.2
        0.5
        parallel:
            ease 17.4 zoom 1.0
        parallel:
            1.4
            ease 2.6 xalign 0.70
    with fade

    "[denise_name] stayed up this evening, and pulls [macy_name] into the kitchen as she enters the hallway."

    show denise_pd kitchen night unhappy
    with dissolve
    deni "Fighting again during dinner! Seriously?"

    show macy_pd kitchen night workwear shocked
    with dissolve
    macy "What?!"

    show denise_pd kitchen night angry
    with dissolve
    deni "And over nothing!"
    if denise_love >=7:
        show denise_pd kitchen night smile
        with dissolve
        deni "In the last few weeks, [denise_adr_pc_as] and me have been getting closer than ever."

        show denise_pd kitchen night happy
        with dissolve
        deni "He's really loving and kind."

        show denise_pd kitchen night neutral
        with dissolve
        deni "You'd see that too if you only gave him a chance."
    else:
        show denise_pd kitchen night unhappy
        with dissolve
        deni "I know my relationship with [denise_adr_pc_as] could be better..."

        show denise_pd kitchen night neutral
        with dissolve
        deni "...but I'm really trying to get closer to him and appreciate him more, and so should you."

    show macy_pd kitchen night workwear thoughtful
    with dissolve
    macy "I... I know, okay."

    show macy_pd kitchen night workwear frown
    with dissolve
    macy "Don't bug me about it."

    show denise_pd kitchen night angry
    with dissolve
    deni "No, it's not okay."

    show denise_pd kitchen night unhappy
    with dissolve
    deni "You're always fighting and it is going to drive us apart."

    show denise_pd kitchen night neutral
    with dissolve
    deni "And I don't want us to be apart, ever."

    show denise_pd kitchen night unhappy
    with dissolve
    deni "I don't want to lose anyone anymore."

    show macy_pd kitchen night workwear thoughtful
    with dissolve
    macy "I... I know, muppet."

    show denise_pd kitchen night angry
    with dissolve
    deni "Why do you do that?"

    show denise_pd kitchen night unhappy
    with dissolve
    deni "Why are you always picking fights with him?"

    if denise_love >=7:
        show denise_pd kitchen night happy
        with dissolve
        deni "He's a really loving person."
    else:
        show denise_pd kitchen night neutral
        with dissolve
        deni "And even though it doesn't always show, I know deep down that he is a really loving person."

    show denise_pd kitchen night unhappy
    with dissolve
    deni "You'd see that, if you'd let yourself."

    show macy_pd kitchen night workwear frown
    with dissolve
    macy "Don't you think I know?!"

    show macy_pd kitchen night workwear shocked
    with dissolve
    macy "Don't you think I want to, more than anything in the world!"

    show macy_pd kitchen night workwear sad
    with dissolve
    macy "But I... I can't. I mustn't."

    show denise_pd kitchen night angry
    with dissolve
    deni "You're always saying that!"

    show denise_pd kitchen night unhappy
    with dissolve
    deni "Why not?"

    show macy_pd kitchen night workwear frown
    with dissolve
    macy "Because!"

    show macy_pd kitchen night workwear shocked
    with dissolve
    macy "Because I get people hurt!"

    show macy_pd kitchen night workwear sad
    with dissolve
    macy "And I don't want to hurt anyone else."

    show macy_pd kitchen night workwear thoughtful
    with dissolve
    macy "Especially him, and you."

    show denise_pd kitchen night angry
    with dissolve
    deni "Well you are hurting him."

    show denise_pd kitchen night unhappy
    with dissolve
    deni "And me."

    show macy_pd kitchen night workwear sad
    with dissolve
    macy "I know. I'm sorry."

    show macy_pd kitchen night workwear neutral
    with dissolve
    macy "Trust me, it's better like this."

    show macy_pd kitchen night workwear thoughtful
    with dissolve
    macy "If you only knew what I..."

    show macy_pd kitchen night workwear sad
    with dissolve
    macy "If you knew, you'd understand."

    show denise_pd kitchen night angry
    with dissolve
    deni "No, I won't accept that."
    show denise_pd kitchen night neutral
    with dissolve
    deni "I'm going to find a way to make it right."

    show denise_pd kitchen night smile
    with dissolve
    deni "To make all of it right."

    show denise_pd kitchen night unhappy
    with dissolve
    deni "Whether you like it or not."

    play audio [ "<silence 2.3>", "sounds/doorslam.ogg" ]
    show denise_pd kitchen night unhappy:
        subpixel True
        0.5
        ease 1.8 xanchor 0.0 xpos 1.0
    show macy_pd kitchen night workwear sad:
        subpixel True
        0.8
        ease 1.3 xalign 0.5
    with dissolve
    "She leaves the room just as you enter."

    menu:
        "[abgreen]'Everything okay?'":
            pc "Everything alright with you two?"

            show macy_pd kitchen night workwear thoughtful
            with dissolve
            macy "I don't know..."

            show macy_pd kitchen night workwear sad
            with dissolve
            macy "Not really..."
        "Say nothing.":

            pc "..."

    show macy_pd kitchen night workwear neutral
    with dissolve
    macy "Listen... I..."

    show macy_pd kitchen night workwear sad
    with dissolve
    macy "I'm sorry about earlier. During dinner."

    default w02d02_s06_me_too = False
    menu:
        "[abgreen]'Me too.'":
            $ w02d02_s06_me_too = True
            pc "I'm sorry too."
            pc "We shouldn't let it get out of hand like that."

            show macy_pd kitchen night workwear thoughtful
            with dissolve
            macy "Yeah... I'm sorry about that."
        "'Don't worry.'":

            $ w02d02_s06_me_too = False
            pc "Water under the bridge. Don't worry about it."

            show macy_pd kitchen night workwear thoughtful
            with dissolve
            macy "But I do. It's hurting my [macy_adr_denise_as]."

    show macy_pd kitchen night workwear sad
    with dissolve
    macy "It's getting pretty late."

    call music_fade_slow from _call_music_fade_slow_113

    show macy_pd kitchen night workwear neutral
    with dissolve
    macy "Goodnight, [player_name]."

    default w02d02_s06_said_princess = True
    menu:
        "'Goodnight, [macy_name].'":
            $ w02d02_s06_said_princess = False
            pc "Goodnight, [macy_name]."

            show macy_pd kitchen night workwear thoughtful:
                subpixel True
                0.5
                ease 2.1 xanchor 0.0 xpos 1.0
            with dissolve
        "[abgreen]'Goodnight, princess.'":


            $ w02d02_s06_said_princess = True
            pc "Goodnight, princess."

            show macy_pd kitchen night workwear secretsmile:
                subpixel True
                0.5
                ease 2.1 xanchor 0.0 xpos 1.0
            with dissolve

    "She leaves the room, and you prepare the couch for bedtime."

    scene black
    with fade

    pause 2.0

    return
