label w01d05_s06:

    scene livingroom_couch_bg night
    show denise_pd livingroom night couch empty
    with fade
    pause 0.5
    show denise_pd livingroom night couch askjoin
    with dissolve
    pause 0.5
    show denise_pd livingroom night couch sad
    with dissolve

    "Like clockwork, [denise_name] shows up freshly bathed, and cozies up to you."
    menu:
        "[abgreen]Say something about dinner.":
            pc "I'm sorry about what happened during dinner, angel."

            show denise_pd livingroom night couch talk
            with dissolve
            deni "I know, [denise_adr_pc_as]."

            show denise_pd livingroom night couch sad
            with dissolve
            if w01d05_s05_doubled_down:
                deni "I wish you both hadn't gotten so angry."

                show denise_pd livingroom night couch thoughtfull
                with dissolve
                deni "[macy_name]'s just very protective of me."
            else:
                deni "[macy_name] shouldn't have blown up like that."

                show denise_pd livingroom night couch thoughtfull
                with dissolve
                deni "She's just very protective of me."


            default w01d05_s06_agree_protective = True
            menu:
                "[abgreen]Agree.":
                    $ w01d05_s06_agree_protective = True
                    pc "Yes she is, angel."

                    show denise_pd livingroom night couch playphone
                    with dissolve
                    deni "She really loves me a lot you know, even if she calls me names sometimes."

                    pc "Yes she does, angel. Love you, that is."
                "Doubt.":

                    $ w01d05_s06_agree_protective = False
                    pc "Is that really it?"

                    show denise_pd livingroom night couch playphone
                    with dissolve
                    deni "Sure, [denise_adr_pc_as]. What else could it be?"
        "Don't.":

            show denise_pd livingroom night couch playphone
            with dissolve

    pc "..."

    show denise_pd livingroom night couch talk
    with dissolve
    deni "[denise_adr_pc_as_cap]...?"
    pc "Yes, angel?"

    show denise_pd livingroom night couch sad
    with dissolve
    deni "What if you and [macy_name] fight and it gets real bad and you can't stand to live together in this house anymore?"
    default w01d05_s06_reassure = True
    menu:
        "[abgreen]'It won't come to that.'":
            $ w01d05_s06_reassure = True
            pc "It won't come to that, angel."

            show denise_pd livingroom night couch headrub sad
            with dissolve
            pc "I'll make sure the situation won't get out of hand."
            pc "No matter how bad it is."

            show denise_pd livingroom night couch headrub happy
            with dissolve
            deni "Please do. I don't want to live here without either of you."
        "'I won't force her to stay.'":

            $ w01d05_s06_reassure = False
            pc "We're all adults in this house, angel."
            pc "If [macy_name] doesn't want to stay here anymore, she is free to make that choice."

            show denise_pd livingroom night couch unhappy
            with dissolve
            deni "But where would I go?"

            show denise_pd livingroom night couch sad
            with dissolve
            deni "I don't want to be without either of you!"
            call denise_add_angst from _call_denise_add_angst_3

            pc "I'm sure it'll be fine, angel."

            show denise_pd livingroom night couch unhappy
            with dissolve
            deni "If you say so, [denise_adr_pc_as]."

    call music_fade_slow from _call_music_fade_slow_88
    pc "..."

    show denise_pd livingroom night couch playphone
    with dissolve
    deni "..."

    show denise_pd livingroom night couch talk
    with dissolve
    deni "Ehm..."
    pc "Yes?"

    call theme_denise from _call_theme_denise_18

    show denise_pd livingroom night couch sad
    with dissolve
    deni "..."

    show denise_pd livingroom night couch unhappy
    with dissolve
    deni "I... eh..."

    show denise_pd livingroom night couch thoughtfull
    with dissolve
    deni "I wanted to ask you in private... about this morning, [denise_adr_pc_as]..."

    if w01d05_s02_pc_said_its_fine:
        pc "Really, don't worry about it."
    else:
        pc "We already talked about this."

    if w01d05_s02_pc_said_it_hurt:
        pc "I am fine now, really."
    else:
        pc "I'm sorry I embarrassed you."

    show denise_pd livingroom night couch thoughtfull
    with dissolve
    deni "It's not that..."

    show denise_pd livingroom night couch talk
    with dissolve
    deni "I'm sort of curious... about... something..."

    pc "Yeah...?"

    show denise_pd livingroom night couch thoughtfull
    with dissolve
    deni "Why... does it do... {i}that?{/i}"

    menu:
        "Be confused.":
            pc "Why does... what do what?"
            show denise_pd livingroom night couch angry
            with dissolve
        "[abgreen]Be surprised.":

            pc "You mean my ehm..."
            pc "Ah..."
            show denise_pd livingroom night couch talk
            with dissolve

    deni "Your [denise_penis_name], [denise_adr_pc_as]!"

    show denise_pd livingroom night couch thoughtfull
    with dissolve
    deni "Why does it get..."

    show denise_pd livingroom night couch unhappy
    with dissolve
    deni "You know..."

    default w01d05_s06_pc_said_swole = False
    menu:
        "[abgreen]'Big?'":
            $ w01d05_s06_pc_said_swole = False
            pc "You mean why does it get big?"
        "'Swole?'":

            $ w01d05_s06_pc_said_swole = True
            pc "You mean why does it get {i}swole{/i}?"

            show denise_pd livingroom night couch sad
            with dissolve
            deni "What?"
            show denise_pd livingroom night couch thoughtfull
            with dissolve
            deni "No, I mean why does it get big?"

            pc "I said that."

            show denise_pd livingroom night couch talk
            with dissolve
            deni "No you didn't, you said {i}swole{/i}."

            show denise_pd livingroom night couch angry
            with dissolve
            deni "That's not even an proper adjective."

            pc "You're right. I'm sorry."

            show denise_pd livingroom night couch unhappy
            with dissolve
            deni "It's just a weird word to use."
            pc "So... you want to... eh... know why it gets... big?"
        "'Erect?'":

            $ w01d05_s06_pc_said_swole = False
            pc "You mean why does it get erect?"

    show denise_pd livingroom night couch sad
    with dissolve
    deni "Uh-huh."

    pc "Well..."

    default w01d05_s06_embarassed = False
    menu:
        "Be embarrassed.":
            $ w01d05_s06_embarassed = True
            pc "Well, ehm..."
            pc "I think it's got to do with..."
            pc "You know..."
            pc "Blood flowing into..."
            pc "Ah..."
        "[abgreen]Be direct.":

            $ w01d05_s06_embarassed = False
            pc "Well, when a man is aroused, certain blood vessels widen."
            pc "When that happens, blood flows into special chambers which then inflate like balloons, and..."

    show denise_pd livingroom night couch talk
    with dissolve
    deni "Geez [denise_adr_pc_as], I know about the technical side!"

    show denise_pd livingroom night couch thoughtfull
    with dissolve
    deni "Biology class, remember?"

    show denise_pd livingroom night couch sad
    with dissolve
    deni "I mean, what causes it to happen?"


    pc "Ah..."

    $ w01d05_s06_told_about_MW = False
    $ w01d05_s06_told_about_Luv = False
    $ w01d05_s06_told_about_Stim = False
    $ w01d05_s06_told_about_dreams = False

    label w01d05_s06_start_erection_conversation:
        menu:
            "Explain about morning wood." if not w01d05_s06_told_about_MW:
                $ w01d05_s06_told_about_MW = True
                pc "Well, it sometimes happens in the morning."

                show denise_pd livingroom night couch talk
                with dissolve
                deni "Why?"
                pc "Not sure, really. It just does."
                pc "Maybe because it's nice and warm, or because I'm really relaxed."

                show denise_pd livingroom night couch sad
                with dissolve
                deni "Oh... kay..."
                jump w01d05_s06_start_erection_conversation

            "Explain about love and intimacy." if not w01d05_s06_told_about_Luv:
                $ w01d05_s06_told_about_Luv = True
                pc "It can happen when a man is close to someone he really loves and wants to be intimate with."

                show denise_pd livingroom night couch talk
                with dissolve
                deni "Awww..."

                pc "You're a bit of a romantic, aren't you?"
                show denise_pd livingroom night couch headrub happy
                with dissolve

                show denise_pd livingroom night couch headrub happy eyesclosed
                with dissolve
                deni "I guess."
                jump w01d05_s06_start_erection_conversation

            "Explain about stimuli." if not w01d05_s06_told_about_Stim:
                $ w01d05_s06_told_about_Stim = True
                pc "Sometimes it happens from outside stimuli."

                show denise_pd livingroom night couch thoughtfull
                with dissolve
                deni "Like what, [denise_adr_pc_as]?"

                pc "Well, visuals, like certain images or videos can make it happen."

                show denise_pd livingroom night couch sad
                with dissolve
                deni "Like... ah... porn?"

                pc "Not necessarily. It can also just be a sexy image. It depends."
                pc "Or, it can happen when someone talks about sexy things or situations."
                pc "Or when it gets touched."

                show denise_pd livingroom night couch headrub happy
                with dissolve
                deni "I see..."
                jump w01d05_s06_start_erection_conversation

            "Explain about dreams." if w01d05_s06_told_about_MW and w01d05_s06_told_about_Luv and w01d05_s06_told_about_Stim:
                pc "And sometimes, a very vivid dream can make it happen."

    show denise_pd livingroom night couch thoughtfull
    with dissolve
    deni "Is that what happened this morning?"
    pc "Eh... yeah."

    show denise_pd livingroom night couch talk
    with dissolve
    deni "Were you dreaming about [denise_adr_charlotte_as]?"

    default w01d05_s06_was_honest = True
    menu:
        "[abgreen]Be honest.":
            $ w01d05_s06_was_honest = True
            pc "Yes. I was."

            show denise_pd livingroom night couch sad
            with dissolve
            deni "I heard you talking while you were sleeping. Were you talking with her?"
            pc "Yes..."

            show denise_pd livingroom night couch talk
            with dissolve
            deni "Were you doing naughty things?"

            menu:
                "[abgreen]'Maybe...'":
                    pc "Maybe..."

                    show denise_pd livingroom night couch headrub happy
                    with dissolve
                    deni "Wheehee."
                "Distract her.":

                    show denise_pd livingroom night couch tickles2
                    with dissolve
                    pc "That's none of your business, young lady."

                    show denise_pd livingroom night couch tickles1
                    with dissolve
                    deni "Hahaha!"

                    show denise_pd livingroom night couch headrub happy
                    with dissolve

            pc "..."
            show denise_pd livingroom night couch headrub sad
            with dissolve
            deni "I sometimes talk to [denise_adr_charlotte_as] in my dreams."
        "Be evasive.":

            $ w01d05_s06_was_honest = False
            pc "I think I'd rather not tell..."

            show denise_pd livingroom night couch unhappy
            with dissolve
            deni "That's okay, I understand."

            show denise_pd livingroom night couch sad
            with dissolve
            deni "I sometimes dream about [denise_adr_charlotte_as]..."

            show denise_pd livingroom night couch headrub sad
            with dissolve
            deni "About talking with her."


    show denise_pd livingroom night couch headrub happy
    with dissolve
    deni "It makes me feel good, even if it's just a dream."

    menu:
        "[abgreen]Ask what they talk about.":
            pc "What do you talk about?"

            show denise_pd livingroom night couch headinlap happytalk
            with dissolve
            deni "Just... stuff."

            show denise_pd livingroom night couch headinlap neutral
            with dissolve
            deni "Like things we did together."

            show denise_pd livingroom night couch headinlap happytalk
            with dissolve
            deni "Or she gives me a bit of advice."

            show denise_pd livingroom night couch tummyrub neutral
            with dissolve
            deni "Most of the time, she'll tell me I should look after you and [macy_name], and make sure you're doing well."

            show denise_pd livingroom night couch tummyrub talk
            with dissolve
            deni "Usually I don't really remember what we talked about..."

            show denise_pd livingroom night couch tummyrub talk eyesclosed
            with dissolve
            deni "...I just remember we talked and it made me feel good."
        "Don't.":

            pc "..."

    pc "That's nice, angel."

    show denise_pd livingroom night couch headinlap neutral
    with dissolve
    deni "It is."

    show denise_pd livingroom night couch headinlap neutral eyesclosed
    with dissolve
    deni "I miss her a lot, but when I dream of her, I feel close to her for a little while."

    default w01d05_s06_was_observant_about_tshirt = False
    if denise_love >= 7:
        menu:
            "[abgreen]Be observant.":
                $ w01d05_s06_was_observant_about_tshirt = True
            "Don't.":
                $ w01d05_s06_was_observant_about_tshirt = False

    if w01d05_s06_was_observant_about_tshirt:
        pc "That's why you're wearing her old shirt to bed, isn't it?"
        pc "I noticed the other day it's the same shirt your [charlotte_rel_to_denise] wore in that photo I took on the beach."
        show denise_pd livingroom night couch tummyrub talk
        with dissolve
        deni "Yeah... it is."

        show denise_pd livingroom night couch tummyrub neutral
        with dissolve
        deni "I found it in one of the boxes with our old stuff."

        show denise_pd livingroom night couch tummyrub neutral
        with dissolve
        deni "It makes me feel... closer to her."

        show denise_pd livingroom night couch tummyrub talk
        with dissolve
        deni "I think that's also why you still wear your ring, right?"
        pc "It... it is, angel."
    else:
        pc "I understand, angel."

    deni "..."

    call music_fade_slow from _call_music_fade_slow_89

    show denise_pd livingroom night couch tummyrub neutral
    with dissolve
    "You stroke her hair a bit."

    show denise_pd livingroom night couch tummyrub neutral eyesclosed
    with dissolve
    "Her breathing slows, and she falls asleep in your lap."
    "It's been a long week, and you feel your eyelids getting heavier too."

    show denise_pd livingroom night couch bothsleep
    with dissolve
    "Soon, you also nod off."

    scene black
    with fade

    pause 2.0

    return
