label w02d05_s02:

    "After finishing up in the bathroom, you go to the kitchen."

    if denise_have_coffee_ritual:
        scene kitchen_bg morning
        show denise_pd kitchen morning nightwear holdcoffee
        with fade
        pause 0.5
        show denise_pd kitchen morning nightwear givecoffee
        with dissolve

        "[denise_name] hands you your daily [pc_coffee]."
        pc "Thank you, angel."

        show denise_pd kitchen morning nightwear happy
        with dissolve
        deni "..."
    else:
        scene kitchen_bg morning
        show denise_pd kitchen morning nightwear happy
        with dissolve
        deni "..."

    if denise_love >= 7:
        show denise_pd kitchen morning nightwear hug
        with dissolve

        "[denise_name] hugs you goodbye."
        deni "I love you, [denise_adr_pc_as]."
    else:

        show denise_pd kitchen morning nightwear smile
        with dissolve
        deni "See you tonight, [denise_adr_pc_as]."

    call music_fade_slow from _call_music_fade_slow_79

    show denise_pd kitchen morning nightwear happy
    with dissolve
    deni "Drive safely."

    play audio [ "<silence 1.7>", "sounds/doorslam.ogg" ]
    show denise_pd kitchen morning nightwear happy:
        subpixel True
        0.5
        easeout 1.2 xpos 1.0 xanchor 0.0
    with dissolve
    "She leaves the room."

    if denise_have_coffee_ritual:
        "You finish your [pc_coffee]."

    call theme_charlotte from _call_theme_charlotte_4

    scene setpiece kitchen morning pc charlottphoto
    with fade
    "On your way out, you stop by the living room door."

    menu:
        "[abgreen]Say hi to [charlotte_name].":

            show setpiece kitchen morning pc charlottphoto touchframe2:
                subpixel True
                xalign 0.5 yalign 0.5
                0.5
                ease 9.0 zoom 1.15
            with dissolve
            pc "Hi babe."

            show setpiece kitchen morning pc charlottphoto touchframe
            with dissolve
            pc "It's been a while..."

            show setpiece kitchen morning pc charlottphoto
            with dissolve
            pc "I'm sorry, I've been a little busy."

            default w02d05_s02_told_about_denise = False
            default w02d05_s02_told_about_incidents = False
            default w02d05_s02_told_about_macy = False
            default w02d05_s02_told_about_brooke = False

            label w02d05_s02_charlotte_conversation:
            menu:
                "[abgreen]'[denise_name]...'" if not w02d05_s02_told_about_denise:
                    $ w02d05_s02_told_about_denise = True

                    show setpiece kitchen morning pc charlottphoto focusfamily:
                        subpixel True
                        0.5
                        ease 7.0 xalign 1.0
                    with dissolve

                    pc "[denise_name] had another panic attack. Well, two actually."
                    pc "One was at school, and it was pretty bad I guess."
                    pc "With the other one, I was there, and..."
                    pc "...well, it helped her that I was."

                    if denise_love >= 7:
                        pc "She and I have really grown close in the last few weeks."
                    else:
                        pc "I've not done as well with her as I should have."
                        pc "I could've really used your help with that."

                    pc "She's studying at home for the time being, and doing really well."
                    pc "I'm supposed to tutor her, but so far she's figuring it all out by herself."

                    show setpiece kitchen morning pc charlottphoto:
                        subpixel True
                        0.5
                        ease 5.0 xalign 0.5
                    with dissolve

                    if not (w02d05_s02_told_about_denise and w02d05_s02_told_about_macy and w02d05_s02_told_about_brooke):
                        jump w02d05_s02_charlotte_conversation

                "[abgreen]'[macy_name]...'" if not w02d05_s02_told_about_macy:
                    $ w02d05_s02_told_about_macy = True

                    show setpiece kitchen morning pc charlottphoto focusfamily:
                        subpixel True
                        0.5
                        ease 7.0 xalign 1.0
                    with dissolve

                    pc "[macy_name] is being as obtrusive as ever."
                    pc "She... she got mugged."
                    pc "It rattled her, I think."
                    pc "But she's acting tough, doesn't let on a thing."

                    show setpiece kitchen morning pc charlottphoto:
                        subpixel True
                        0.5
                        ease 5.0 xalign 0.5
                    with dissolve
                    pc "Don't worry, from now on I'm making sure she gets home safe after dark."
                    pc "[denise_name] wouldn't have it any other way."

                    if not (w02d05_s02_told_about_denise and w02d05_s02_told_about_macy and w02d05_s02_told_about_brooke):
                        jump w02d05_s02_charlotte_conversation

                "[abgreen]'[brooke_name]...'" if not w02d05_s02_told_about_brooke:
                    $ w02d05_s02_told_about_brooke = True
                    pc "I..."
                    pc "I met someone at work."

                    if not w01d04_s03_rejected_brooke or w02d03_s03_pc_said_yes:
                        if w01d07_s08_pc_liked_brooke == 1:
                            pc "I think I like her."
                        else:
                            pc "I enjoy spending time with her."

                        show setpiece kitchen morning pc charlottphoto touchframe
                        with dissolve
                        if w01d07_s08_pc_liked_brooke == 1:
                            pc "I think you would have liked her, too."
                        else:
                            pc "I think you would have gotten along, too."

                        show setpiece kitchen morning pc charlottphoto
                        with dissolve

                        if w02d01_s02_agree:
                            pc "You couldn't tell it by looking at her, but she's pretty wild."

                        pc "[macy_name]'s having none of it though, and that's something I have to consider."
                    else:
                        pc "She's a nice person, and she might be a good friend."

                        show setpiece kitchen morning pc charlottphoto touchframe
                        with dissolve
                        pc "I think you would have liked her."

                        show setpiece kitchen morning pc charlottphoto
                        with dissolve

                    if not (w02d05_s02_told_about_denise and w02d05_s02_told_about_macy and w02d05_s02_told_about_brooke):
                        jump w02d05_s02_charlotte_conversation
                "Leave":

                    pc "..."

            call music_fade_slow from _call_music_fade_slow_80
            pc "I gotta go..."
        "Don't.":

            call music_fade_slow from _call_music_fade_slow_81
            pc "..."

    scene black
    with fade
    "You leave and go to work."

    scene black
    with fade

    scene setpiece office midday desk:
        subpixel True
        xalign 0.5 yalign 0.5
        0.5
        ease 45 zoom 1.2
    with fade

    "It's a hectic Friday at the office, with lots of last minute issues that need to be addressed."
    "Your mail box is already filled with requests for assistance and test results that require some action."
    "You get your head down and start ticking off the tasks one by one."

    scene black
    with fade

    pause 2.0

    return
