label w02d03_s02:

    "On your way to work, you turn up the stereo in the hope it'll bring you some energy."

    scene setpiece office midday desk
    with fade
    "You have a slow start, looking at a particularly elusive issue."
    "It doesn't help you did not sleep well last night."

    call theme_brooke from _call_theme_brooke_5

    if not w02d01_s02_agree:

        scene office_bg midday:
            subpixel True
            xalign 0.5 yalign 0.0 zoom 1.0
            0.5
            ease 19 zoom 1.1
        show brooke_pd office midday cubicle smile:
            subpixel True
            xalign 0.5 yalign 0.0 zoom 1.0
            0.5
            ease 19 zoom 1.2
        with fade

        "After a few fruitless hours, [brooke_name] drops by your desk."

        show brooke_pd office midday cubicle talk
        with dissolve
        "You banter about nothing much for a bit."
        menu:
            "[abgreen]Ask about yesterday.":
                pc "You were pretty busy yesterday, weren't you?"

                show brooke_pd office midday cubicle happy
                with dissolve
                broo "Eh... yeah."

                show brooke_pd office midday cubicle serious
                with dissolve
                broo "Marketing laid out their wishes for the roadmap next quarter."

                show brooke_pd office midday cubicle happy
                with dissolve
                broo "I'll be happy if we manage to implement one fifth of their lofty plans."
                pc "That bad eh?"

                show brooke_pd office midday cubicle worried
                with dissolve
                broo "They have no idea."
            "Don't.":

                pc "..."

        show brooke_pd office midday cubicle smile
        with dissolve
        broo "I'll be off, I have a lot to do."

        show brooke_pd office midday cubicle happy
        with dissolve
        broo "By the way, did you hear about that video that's circulating?"

        show brooke_pd office midday cubicle serious
        with dissolve
        broo "About the incident at the presentation of the quarterly figures?"

        pc "No?"
        pc "I saw some people huddled around a phone yesterday, and some more this morning."
        pc "They might know more about it."

        show brooke_pd office midday cubicle flirt
        with dissolve
        broo "Interesting."

        call music_fade_slow from _call_music_fade_slow_103

        show brooke_pd office midday cubicle smile
        with dissolve
        broo "Never mind, I'll see you later."

        scene black
        with fade
        pc "Bye."

        scene setpiece office midday desk
        with fade

        "By the end of the afternoon, there is some commotion on your floor."
        "Groups of people are clustered around phones and monitors all around you, and little work gets done as everyone discusses some video embarrassing the company CEO."
        "Except for you, as you're still trying to solve the issue you were working on, without making much headway."

        scene black
        with fade

        "As the day comes to a close, you pack your laptop and leave."
        "Driving home, you keep going over the problem your are working on in your mind, almost making you miss your turnoff."

        pause 2.0

        return
    else:

        scene office_bg midday:
            subpixel True
            xalign 0.5 yalign 0.0 zoom 1.0
            0.5
            ease 19 zoom 1.1
        show brooke_pd office midday cubicle concern:
            subpixel True
            xalign 0.5 yalign 0.0 zoom 1.0
            0.5
            ease 19 zoom 1.2
        with fade

        "After a few fruitless hours, [brooke_name] drops by your desk."

        show brooke_pd office midday cubicle flirt
        with dissolve
        "She stays just long enough to say 'Hi!' and casually drop a crumpled note on your desk."

        scene black
        with fade
        scene setpiece office midday desk
        with fade

        "It reads:"
        "{font=fonts/ArchitectsDaughter-Regular.ttf}'Meet in 15 mins @ usual spot.'{/font}"
        "{font=fonts/ArchitectsDaughter-Regular.ttf}'P.s.: eat this note.'{/font}"

        default w02d03_s02_ate_note = False
        menu:
            "Eat the note.":
                $ w02d03_s02_ate_note = True
                "You look at the note."
                "With some reservations, you stuff it in your mouth."
                "As a culinary experience, it's several kinds of horrible."
                "The more you chew, the worse it gets."
                "In desperation, you wash it down with the cold dregs remaining at the bottom of the mug on your desk."
                pc "Gaah!"
            "[abgreen]No way.":

                $ w02d03_s02_ate_note = False
                pc_thought "No way I'm eating this."
                "You crumple it back up, and drop it in the dust bin."

        call music_fade_slow from _call_music_fade_slow_104

        scene black
        with fade

        "You casually stand up, and gravitate towards the elevator."

    pause 2.0

    return
