label w02d03_s06:
    scene outside_bg city night:
        subpixel True
        zoom 1.0 xalign 0.5 yalign 0.2
        0.5
        ease 12.0 zoom 1.05
    show outside_bg_ovl city night drunkblur:
        alpha 0.0
        subpixel True
        zoom 1.0 xalign 0.5 yalign 0.2
        0.5
        ease 12.0 zoom 1.05
    show macy_pd outside night mug walk1:
        subpixel True
        zoom 1.0 xalign 0.5 yalign 0.2
        0.5
        ease 12.0 zoom 1.1
    with fade

    show text "{size=+18}{font=fonts/typeo___.ttf}Earlier that night...{/font}{/size}" at truecenter
    with dissolve
    $ renpy.pause(2.0, hard='True')

    hide text
    with dissolve

    $ renpy.pause(2.0, hard='True')

    "[macy_name] walks home after work."
    macy_thought "Busy night."
    macy_thought "[dan_name] didn't look so hot today."
    macy_thought "Maybe it's the new pain killers he's on."

    show outside_bg city night:
        subpixel True
        0.5
        ease 12.0 zoom 1.1
    show outside_bg_ovl city night drunkblur:
        subpixel True
        0.5
        ease 12.0 zoom 1.1
    show macy_pd outside night mug walk2:
        subpixel True
        0.5
        ease 12.0 zoom 1.2
    with fade

    macy_thought "Fuck, he can be a cranky jerk sometimes..."
    macy_thought "But it's hard to blame him."
    macy_thought "It's got to be tough to bear for..."
    macy_thought "Footsteps?"
    macy_thought "It better not be that frat creep that wrote his phone number down instead of tipping..."

    show outside_bg city night:
        subpixel True
        0.5
        ease 0.7 zoom 1.2
    show outside_bg_ovl city night drunkblur:
        subpixel True
        0.5
        ease 0.7 zoom 1.2 alpha 0.75
    show macy_pd outside night mug shock:
        subpixel True
        0.5
        ease 0.7 zoom 1.4
    with fade
    with hpunch
    macy "{size=+10}Hey, what the...?!{/size}"

    show outside_bg city night:
        subpixel True
    show outside_bg_ovl city night drunkblur:
        subpixel True
        ease 1.4 alpha 0.0
    show macy_pd outside night mug shock:
        subpixel True
        ease 0.7 ypos 1.0 yanchor 0.0

    macy "{size=+10}Ooof...!{/size}"

    call music_fade_slow from _call_music_fade_slow_117

    show outside_bg city night:
        subpixel True
        ease 7.0 zoom 1.0
    show outside_bg_ovl city night drunkblur:
        subpixel True
        ease 7.0 zoom 1.0

    macy "{size=+10}Motherfucker! Get away from me, you...!{/size}"

    scene black
    with fade

    $ renpy.pause(0.5, hard='True')
    call sound_punch from _call_sound_punch_2
    with hpunch

    $ renpy.pause(0.6, hard='True')
    call sound_punch from _call_sound_punch_3
    with hpunch

    $ renpy.pause(2.0, hard='True')

    show text "{size=+18}{font=fonts/typeo___.ttf}Present time...{/font}{/size}" at truecenter
    with dissolve
    $ renpy.pause(2.0, hard='True')

    hide text
    with dissolve

    $ renpy.pause(2.0, hard='True')

    call theme_macy_sad from _call_theme_macy_sad_5
    scene policestation_bg interior:
        subpixel True
        xalign 0.0 yalign 0.5
        0.5
        ease 12 zoom 1.05
    show macy_pd policestation interior night thoughtfull lookaway:
        subpixel True
        xalign 0.0 yalign 0.5
        0.5
        ease 12 zoom 1.1
    with fade

    "Another week, another [macy_rel_to_pc] in distress to pick up."
    show policestation_bg interior:
        subpixel True
        0.5
        ease 8 xalign 0.5
    show macy_pd policestation interior night thoughtfull lookaway:
        subpixel True
        0.5
        ease 8 xalign 0.5

    "You find [macy_name] in the reception area inside the police station."

    show macy_pd policestation interior night sad
    with dissolve
    show macy_pd policestation interior night thoughtfull
    with dissolve
    "As she sees you, you see a flash of relief in her eyes, followed by a second flash of hesitation."

    default w02d03_s06_hugged_macy = False
    menu:
        "[abgreen]Hug her.":
            $ w02d03_s06_hugged_macy = True

            show policestation_bg interior:
                subpixel True
                0.5
                ease 4.2 zoom 1.2 yalign 0.0
            show macy_pd policestation interior night sad:
                subpixel True
                0.5
                ease 4.2 zoom 1.2 yalign 0.0
            with dissolve
            "You walk up to her with resolute steps..."

            show policestation_bg interior:
                subpixel True
                0.5
                ease 45.0 zoom 1.0
            show macy_pd policestation interior night hug lookup:
                subpixel True
                zoom 1.0
            with dissolve
            "...and put your arms around her..."
            show macy_pd policestation interior night hug lookup closedeyes
            with dissolve
            "... as she responds in kind."

            show macy_pd policestation interior night hug
            with dissolve
            "She presses herself against you."

            show macy_pd policestation interior night hug closedeyes
            with dissolve
            "You can feel the tension ebbing from her body."

            default w02d03_s06_reassured_macy = False
            menu:
                "[abgreen]Reassure her.":
                    $ w02d03_s06_reassured_macy = True
                    pc "Don't worry, your [macy_adr_pc_as]'s here."
                    pc "You're safe now. I'm not going to let anything else happen to you."

                    show macy_pd policestation interior night hug
                    with dissolve
                    show macy_pd policestation interior night hug closedeyes
                    with dissolve
                    "She inhales sharply, and tightens her grip around you even more."

                    show macy_pd policestation interior night hug
                    with dissolve
                    window hide
                    pause 2.0
                    call macy_add_love from _call_macy_add_love_2
                "Don't.":

                    $ w02d03_s06_reassured_macy = True
                    show macy_pd policestation interior night hug
                    with dissolve
                    window hide
                    pause 2.0
                    "You hug her in silence for a few seconds."
        "Don't.":

            $ w02d03_s06_hugged_macy = False
            show macy_pd policestation interior night sad
            with dissolve
            "You look at each other for a few seconds."

            show macy_pd policestation interior night thoughtfull
            with dissolve
            "[macy_name] gives you a conflicted look, but doesn't say anything."

            show macy_pd policestation interior night thoughtfull lookaway
            with dissolve
            call macy_remove_love from _call_macy_remove_love_2

    scene black
    with fade
    "You learn your [macy_rel_to_pc] was mugged in the street while walking home."
    "The duty officer informs you they have all they need from [macy_name]..."
    "...including a reasonably accurate description of the attacker's build, and what he took, which is the best that they could hope for in this case."


    if macy_love >= 4:
        "You put your hand on your [macy_rel_to_pc]'s shoulder as you walk her out of the police station and bring her to the car."
    else:
        "[macy_name] walks alongside you as you return to the car."

    pause 2.0

    return
