label w05d04_s02:

    call theme_pc from _call_theme_pc_24

    scene setpiece office midday desk:
        subpixel True
        xalign 0.5 yalign 0.6 zoom 1.0
        ease 12.7 zoom 1.05
    with fade
    if w05d04_s02_ask_call_back or w05d04_s02_mail_call_back:
        "Some time passes, and you still haven't heard back from the HR department."
        "You call them again."
    else:
        "After some time has passed, you decide to try your luck and call the HR department again."

    hr "Haytch-ar how can I help you?"

    "Although technically a question, the intonation makes the greeting sound like a statement."

    if w05d04_s02_mail_call_back and w05d04_s02_ask_call_back:
        "You explain your situation, adding that you left a message with their colleague and sent an e-mail."
        hr "No, I haven't seen either, but I'm very busy with important matters and can't be expected to respond to every little problem immediately."

    elif w05d04_s02_ask_call_back:
        "You explain your situation, adding that you called earlier and left a message."
        hr "No, I didn't see any note to call you back. But if it was so important, maybe you should have send an e-mail."

    elif w05d04_s02_mail_call_back:
        "You explain your situation, adding that you called earlier and send them an e-mail."
        hr "No, I haven't gotten round to my mail yet. But if it was so important, maybe you should have left a message with my intern?"
    else:

        "You explain your situation, adding that you called earlier."
        hr "If it was so important, maybe you should have considered leaving a message with my intern, or sending and e-mail?"

    pc "But..."

    hr "Never mind. If you haven't received confirmation, we probably didn't get the paperwork."
    hr "You people lose it in transit all the time, nothing we can do about that."

    default w05d04_s02_protest = False
    menu:
        "Protest.":
            $ w05d04_s02_protest = True
            pc "What do you mean, nothing you can do about it?"
        "[abgreen]Say nothing.":
            $ w05d04_s02_protest = False
            pc "..."

    hr "You can file it again and mark it as urgent, and if we deem the reason is valid we'll process it the next work day."

    pc "That's impossible. My leave is tomorrow."
    hr "You mean tomorrow's date is on the leave request you may or may not have filed correctly."
    pc "I..."
    "You hear some commotion on the other side of the line. Apparently, people are preparing to go to lunch and urging the person you're talking with to wrap things up."
    hr "Yes, ah, where were we?"
    hr "Oh yes. You could try and find the copy of the leave request you said you filed."
    hr "If it exists, it should have been archived by your manager."
    if w05d04_s02_protest:
        pc "What do you mean, if it exists?"
        hr "Please don't interrupt me."
    hr "Send me a copy of that and I might try to make an exception and process it today."
    pc "The copy archived by my manager?"
    hr "Yes, that's what I said. Now if you'll excuse me, I have more urgent matters to attend to. Goodbye."

    "The person on the other side of the line disconnects without waiting for your reply."
    pc_thought "Figures..."

    call music_fade_slow from _call_music_fade_slow_467

    "Asking around, you quickly learn that copies of leave requests are stored in the archive on the executive floor."

    scene black
    with fade
    "Determined to have this sorted as quickly as possible, you take the elevator up."

    pause 2.0

    if (w04d02_s05_agreed_to_tcl_sara and not w04d03_s04_still_in) or (s3_love <= 3):
        default w05d04_s02_cant_lewd_zarah = False
        $ w05d04_s02_cant_lewd_zarah = True

    if w05d04_s02_cant_lewd_zarah:
        call theme_s3_battle from _call_theme_s3_battle_6
    else:
        call theme_s3 from _call_theme_s3_12

    scene office_bg midday conferenceroom:
        subpixel True
        xalign 0.5 yalign 0.3 zoom 1.15
        ease 1.3 zoom 1.0
    show zarah_pd confroom shock:
        subpixel True
        xalign 0.5 yalign 0.3 zoom 1.3
        ease 1.3 zoom 1.0
    with fade
    zara "Whoop!"
    "Stepping out of the elevator, you almost bump into [zarah_name]."

    if w05d04_s02_cant_lewd_zarah:
        call w04d02_s05_zara_refuses from _call_w04d02_s05_zara_refuses
    else:
        call w04d02_s05_zara_helps from _call_w04d02_s05_zara_helps

    return

label w04d02_s05_zara_refuses:
    show office_bg midday conferenceroom:
        0.5
        ease 34.3 zoom 1.15
    show zarah_pd confroom angry:
        0.5
        ease 34.3 zoom 1.3
    with dissolve
    zara "Mr. [player_last_name]..."

    show office_bg midday conferenceroom
    show zarah_pd confroom neutraldisdain
    with dissolve
    zara "You just keep turning up like a bad penny."
    pc "Ah... hello."

    show office_bg midday conferenceroom
    show zarah_pd confroom angry
    with dissolve
    zara "State your business please."
    pc "I... ah... I need to get a copy of some paperwork from the archives."

    show office_bg midday conferenceroom
    show zarah_pd confroom neutraldisdain
    with dissolve
    zara "I'm afraid that's impossible."

    show office_bg midday conferenceroom
    show zarah_pd confroom smile
    with dissolve
    zara "Those are off limits for unauthorized personnel."
    pc "Are, eh... are you authorized?"

    show office_bg midday conferenceroom
    show zarah_pd confroom neutraldisdain
    with dissolve
    zara "Yes I am."
    pc "Then maybe you could...?"

    show office_bg midday conferenceroom
    show zarah_pd confroom smile
    with dissolve
    zara "I really am sorry, Mr. [player_last_name], but I don't have time for this."

    show office_bg midday conferenceroom
    show zarah_pd confroom angry
    with dissolve
    zara "Now, if you have no other business here, perhaps you should return to your duties? That they pay you for?"
    pc "Is there anyone else here that could...?"

    show office_bg midday conferenceroom
    show zarah_pd confroom neutraldisdain
    with dissolve
    zara "I'm afraid not. Everyone else is busy actually doing their job."

    call music_fade_slow from _call_music_fade_slow_468

    show office_bg midday conferenceroom
    show zarah_pd confroom smile:
        0.5
        easeout 8.1 xpos 0.0 xanchor 1.0
    with dissolve
    zara "Goodbye. Elevator's right behind you."

    scene black
    with fade
    "Clearly you're not getting anywhere, so you return to the elevator."

    call w05d04_s05_run_in_to_brooke from _call_w05d04_s05_run_in_to_brooke_1

    return

label w04d02_s05_zara_helps:
    show office_bg midday conferenceroom:
        0.5
        ease 34.3 zoom 1.15
    show zarah_pd confroom smile:
        0.5
        ease 34.3 zoom 1.3
    with dissolve
    zara "Oh! Well hello there, [player_name]."
    pc "Hi, [zarah_name]. Sorry about that."

    show office_bg midday conferenceroom
    show zarah_pd confroom flirty
    with dissolve

    if w04d03_s04_still_in and w03d04_s03_up_for_sierra:
        if w03d05_s02_said_its_our_thing_now:
            zara "Have you come looking for [sara_name], or for your... precious?"
        else:
            zara "Have you come looking for [sara_name] or [sierra_name]?"
    elif w04d03_s04_still_in:
        zara "Have you come looking for [sara_name]?"
    elif w03d04_s03_up_for_sierra:
        if w03d05_s02_said_its_our_thing_now:
            zara "Have you come looking for your... precious?"
        else:
            zara "Have you come looking for [sierra_name]?"

    if w04d03_s04_still_in or w03d04_s03_up_for_sierra:
        show office_bg midday conferenceroom
        show zarah_pd confroom neutraldisdain
        with dissolve
        zara "I'm afraid they're both occupied. [sara_name] has [sierra_name] assisting her with... something."
        pc "Oh, that's okay."

        show office_bg midday conferenceroom
        show zarah_pd confroom flirty
        with dissolve
        zara "Is there any chance I could help you out?"
    else:
        zara "Is there anything I can do for you?"

    pc "There is, actually."
    pc "I've got a weekend away planned with my girls..."

    show office_bg midday conferenceroom
    show zarah_pd confroom smile
    with dissolve
    zara "Oh, that's nice."
    pc "Yeah. But it seems..."

    show office_bg midday conferenceroom
    show zarah_pd confroom sadnosepinch eyesclosed
    with dissolve
    zara "Don't tell me."

    show office_bg midday conferenceroom
    show zarah_pd confroom sadnosepinch
    with dissolve
    zara "They've lost the paperwork for your leave request, right?"
    pc "Yeah."

    show office_bg midday conferenceroom
    show zarah_pd confroom angry
    with dissolve
    zara "Happens every goddamn time."

    show office_bg midday conferenceroom
    show zarah_pd confroom neutraldisdain
    with dissolve
    zara "Don't worry. I'm sure we can work this out."

    if w04d03_s04_still_in or w03d04_s03_up_for_sierra:
        show office_bg midday conferenceroom
        show zarah_pd confroom flirty
        with dissolve
        if w04d03_s04_still_in:
            if w04d01_s05_agree_to_caper:
                zara "It wouldn't be the first time we've helped each other, after all."
            else:
                if w03d04_s03_up_for_sierra:
                    zara "You helped my sisters out too, after all."
                else:
                    zara "You helped one of my sisters out too, after all."
        elif w03d04_s03_up_for_sierra:
            zara "You helped one of my sisters out too, after all."

    show office_bg midday conferenceroom:
        0.5
        ease 12.1 xalign 0.0
    show zarah_pd confroom smile:
        0.5
        easeout 12.1 xpos 0.0 xanchor 1.0
    show black:
        alpha 0.0
        0.5
        choice w04d03_s04_offer_help and w03d04_s03_up_for_sierra:
            pass
        choice not (w04d03_s04_offer_help and w03d04_s03_up_for_sierra):
            easein 6.1 alpha 1.0
    with dissolve
    zara "Right this way..."

    if w04d03_s04_offer_help and w03d04_s03_up_for_sierra:
        pc "You said something about [sierra_name] assisting [sara_name]?"

        call music_fade_slow from _call_music_fade_slow_469

        show office_bg midday conferenceroom
        show zarah_pd confroom neutraldisdain
        show black:
            0.5
            easein 6.1 alpha 1.0
        with dissolve
        zara "Uh-huh."
        pc "Are they okay?"

    return
