label w01d01_s04:
    scene livingroom_couch_bg night
    show denise_pd livingroom night couch empty
    with fade

    "You settle yourself in front of the TV, hoping to numb your mind until it is time to sleep."
    "It's not really working."
    "The drivel that the TV spews forth just makes you slightly angry."
    "Against all reason, the low key annoyance is just balanced out by the hope that someone will start to say something, anything insightful."
    "But you're not holding your breath."

    call theme_denise from _call_theme_denise_10

    show denise_pd livingroom night couch askjoin
    with dissolve
    "After some time, [denise_name] walks in."
    deni "Can I hang out with you for a bit, [denise_adr_pc_as]?"

    pc "Sure angel, come over here."

    show denise_pd livingroom night couch playphone
    with dissolve
    "[denise_name] nestles her back against you."

    pc "You're nice and warm, angel. Did you shower already?"
    show denise_pd livingroom night couch happy
    with dissolve
    deni "Yeah. I just wanted to hang out with you for a little before going to bed."

    show denise_pd livingroom night couch talk
    with dissolve
    deni "What are you watching?"
    pc "Honestly, angel, I'm not really sure. I thought it was some bad satire, but I have a growing suspicion they're actually serious."

    show denise_pd livingroom night couch thoughtfull
    with dissolve
    deni "That's why TV is for old people."
    deni "I just watch what I want on my phone."

    pc "What are you watching?"

    show denise_pd livingroom night couch happy
    with dissolve
    deni "A vlog about puppies."

    pc "..."
    pc "Well, can't argue with that, angel."

    show denise_pd livingroom night couch playphone
    with dissolve
    "You sit a bit in silence."

    menu:
        "[abgreen]Make conversation.":
            pc "Angel, how's school going? Really?"

            show denise_pd livingroom night couch talk
            with dissolve
            deni "I don't know. Fine, I guess."
            pc "Are you enjoying yourself?"

            show denise_pd livingroom night couch playphone
            with dissolve
            deni "Honestly? Not really."
            pc "Why?"

            show denise_pd livingroom night couch sad
            with dissolve
            deni "I don't know. It's too... busy."
            deni "You know, like too many people."

            show denise_pd livingroom night couch unhappy
            with dissolve
            deni "Learning new stuff is fine. I like that."

            show denise_pd livingroom night couch sad
            with dissolve
            deni "It's just, when I'm there, I just feel... anxious."

            show denise_pd livingroom night couch talk
            with dissolve
            deni "All I can think about is coming home, where you and [macy_name] will be."
        "Don't.":

            pc "..."
            deni "..."

            show denise_pd livingroom night couch talk
            with dissolve
            deni "[denise_adr_pc_as_cap]?"
            pc "Yes, angel?"

            show denise_pd livingroom night couch happy
            with dissolve
            deni "I like this. Hanging around with you and [macy_name], I mean."

            show denise_pd livingroom night couch talk
            with dissolve
            deni "Even if it's just sitting like this."
            pc "I like it too, angel."

    show denise_pd livingroom night couch thoughtfull
    with dissolve
    deni "I just wish you would get along better."
    pc "You mean [macy_name] and me?"

    show denise_pd livingroom night couch talk
    with dissolve
    deni "Yeah."

    menu:
        "[abgreen]'Me too.'":
            pc "Me too, angel."
            pc "It's not always easy though."

            show denise_pd livingroom night couch unhappy
            with dissolve
            deni "I know, [denise_adr_pc_as]."

            show denise_pd livingroom night couch thoughtfull
            with dissolve
            deni "I can see you're trying."
        "'Her fault.'":

            pc "She doesn't really make it easy, you know."

            show denise_pd livingroom night couch unhappy
            with dissolve
            deni "I know, [denise_adr_pc_as]. Just keep trying, please."

            show denise_pd livingroom night couch sad
            with dissolve
            deni "I {i}hate{/i} to see you fighting all the time."

            show denise_pd livingroom night couch unhappy
            with dissolve
            deni "It makes me worried."

    show denise_pd livingroom night couch talk
    with dissolve
    deni "Deep down, she really loves you, I'm sure of it."

    show denise_pd livingroom night couch sad
    with dissolve
    deni "She just has trouble showing it."

    menu:
        "[abgreen]Say something.":
            show denise_pd livingroom night couch talk
            with dissolve
            pc "Thanks, angel. That means a lot."
        "Say nothing.":

            pc "..."

    show denise_pd livingroom night couch playphone
    with dissolve
    deni "I just..."

    show denise_pd livingroom night couch unhappy
    with dissolve
    deni "I don't want to lose you two, too."

    show denise_pd livingroom night couch sad
    with dissolve
    deni "..."
    pc "Oh, sweetheart. You won't."

    show denise_pd livingroom night couch talk
    with dissolve
    deni "Promise?"

    menu:
        "[abgreen]Promise.":
            show denise_pd livingroom night couch happy
            with dissolve
            pc "I promise angel."
        "Don't.":
            show denise_pd livingroom night couch sad
            with dissolve
            pc "..."

    default w01d01_s04_denise_stroke_hair = False
    menu:
        "[abgreen]Stroke her hair.":
            $ w01d01_s04_denise_stroke_hair = True
            "You start to softly stroke her hair."
            show denise_pd livingroom night couch headrub happy
            with dissolve

            call denise_add_love from _call_denise_add_love_2
            tuto "Note, the love [denise_name] feels for you has just increased."

            call tuto_explain_loveadd from _call_tuto_explain_loveadd

            show denise_pd livingroom night couch headrub sad
            with dissolve
            deni "..."
            deni "Headscratchies."

            show denise_pd livingroom night couch headrub happy
            with dissolve
            deni "I love headscratchies..."

            show denise_pd livingroom night couch headrub sad
            with dissolve
            pause 1.0
            deni "They make me... {w=1.5}{nw}"

            show denise_pd livingroom night couch headrub sad eyesclosed
            with dissolve
            extend "sleepy..."
            deni "..."
            deni "Hmmm."
        "Don't.":

            $ w01d01_s04_denise_stroke_hair = False
            pc "..."
            tuto "Note, by choosing this option, you missed an opportunity to increase the love [denise_name] feels for you."
            call tuto_explain_loveadd from _call_tuto_explain_loveadd_1

    "You sit together for a while, taking comfort in each others presence."

    show denise_pd livingroom night couch askjoin
    with dissolve
    "Finally, [denise_name] gets up and wishes you goodnight."

    call music_fade_slow from _call_music_fade_slow_44

    show denise_pd livingroom night couch empty
    with dissolve
    "You sit for a few minutes longer before deciding to call it a night."

    scene black
    with fade

    pause 1.0

    return

label tuto_explain_loveadd:
    tuto "Throughout the game, certain actions will cause the love that key characters feel towards you to increase or decrease."
    tuto "High levels of love are usually a good thing."
    tuto "However, don't worry if you do something that will make them love you less."
    tuto "You will have plenty of opportunity to increase it, and sometimes it may lead to a better outcome."
    tuto "However, if you continually disappoint your loved ones, they may stop loving you altogether, and that may trigger one of the alternative endings."
    return
