


label w01d03_s10:

    call theme_macy from _call_theme_macy_4

    scene backdrop hallway_blurredstreetlights
    show setpiece hallway night macy comehome
    with fade

    "At that moment, [macy_name] arrives home from work."

    if w01d03_s09_tried_to_kiss_mouth:
        scene black
        with fade
        "Still feeling the shame burning on your cheeks, you enter the kitchen."
    else:
        scene black
        with fade
        "You motion her to be quiet and go into the kitchen."

    scene kitchen_bg lookatsink nighttime
    show macy_pd kitchen night workwear neutral:
        xpos 1.0 xanchor 0.0
        0.5
        ease 2.1 xalign 0.5
    with fade
    "She follows you in."

    show macy_pd kitchen night workwear sad
    with dissolve
    macy "How is she doing?"

    show macy_pd kitchen night workwear neutral
    with dissolve
    menu:
        "[abgreen]'Good.'":
            pc "Good, I think, all things considering."
            pc "She came out halfway through the evening, and we talked a bit."
            show macy_pd kitchen night workwear secretsmile
            with dissolve
            pc "Then, she had some of the ice cream you had me buy, and that lifted her mood."
        "'Bad.'":

            pc "Not so well, I think."
            show macy_pd kitchen night workwear thoughtful
            with dissolve
            pc "She came out halfway through the evening, and we talked a bit."
            pc "She's pretty shook up and confused."
            show macy_pd kitchen night workwear secretsmile
            with dissolve
            pc "It's a good thing you had me get some ice cream, that seemed to lift her mood."
        "'Not sure.'":

            pc "Hard to say..."
            pc "She came out halfway through the evening, and we talked a bit."
            show macy_pd kitchen night workwear secretsmile
            with dissolve
            pc "She seemed pretty upset at first, but after she had some ice cream she seemed a whole lot better."

    show macy_pd kitchen night workwear smile
    with dissolve
    macy "See?"
    macy "No need to thank me."

    if w01d03_s05_understanding:
        show macy_pd kitchen night workwear thoughtful
        with dissolve
        macy "It's a good thing she's staying at home for a bit."

        if w01d03_s08_understanding_home_evening:
            pc "Yes it is."
            call w01d03_s10_macy_agree from _call_w01d03_s10_macy_agree
        else:

            pc "About that..."
            show macy_pd kitchen night workwear shocked
            with dissolve
            macy "Don't tell me you changed your mind!"
            call w01d03_s10_macy_disagree from _call_w01d03_s10_macy_disagree
    else:

        show macy_pd kitchen night workwear frown
        with dissolve
        macy "Now did she talk to you about your crazy notion to send her back to that school right away?"

        if w01d03_s08_understanding_home_evening:
            pc "Yeah, we did."
            show macy_pd kitchen night workwear neutral
            with dissolve
            pc "Listen, I thought about it and I guess it's not in her best interest."

            call w01d03_s10_macy_agree from _call_w01d03_s10_macy_agree_1
        else:

            pc "She brought it up, yes..."
            show macy_pd kitchen night workwear shocked
            with dissolve
            pc "But I think it's better if she gets back in the saddle as soon as she can."

            call w01d03_s10_macy_disagree from _call_w01d03_s10_macy_disagree_1

    return

label w01d03_s10_macy_agree:
    pc "She needs some time to calm down."
    pc "I don't want to distress her more than she already is."

    show macy_pd kitchen night workwear secretsmile
    with dissolve
    macy "Good, [player_name]..."

    show macy_pd kitchen night workwear smile
    with dissolve
    macy "You're doing the right thing. Thank you."

    show macy_pd kitchen night workwear secretsmile
    with dissolve
    macy "I'm going to clean up and go to bed."
    macy "Goodnight, [player_name]."

    menu:
        "'Goodnight, [macy_name].'":
            call music_fade_slow from _call_music_fade_slow_41

            show macy_pd kitchen night workwear thoughtful
            with dissolve
            pc "Goodnight, [macy_name]."

            show macy_pd kitchen night workwear thoughtful:
                ease 2.2 xpos 1.0 xanchor 0.0
        "[abgreen]'Goodnight, princess.'":

            pc "Goodnight, princess."

            show macy_pd kitchen night workwear frown
            with dissolve
            macy "Ack..."
            macy "I'm..."

            call music_fade_slow from _call_music_fade_slow_42
            show macy_pd kitchen night workwear secretsmile
            with dissolve
            macy "...too tired to complain. Goodnight."

            show macy_pd kitchen night workwear secretsmile:
                ease 2.2 xpos 1.0 xanchor 0.0

    "She leaves the room, closing the door behind her."

    scene black
    with fade
    return

label w01d03_s10_macy_disagree:
    show macy_pd kitchen night workwear frown
    with dissolve
    macy "Are you crazy?!"
    show macy_pd kitchen night workwear shocked
    with dissolve
    macy "If you push her like that, she might break down completely!"

    pc "It's for her own good."

    show macy_pd kitchen night workwear frown
    with dissolve
    macy "We'll see about that..."

    call music_fade_slow from _call_music_fade_slow_43

    show macy_pd kitchen night workwear eyeroll
    with dissolve
    macy "You're a real dickhead, [player_name]! You know that right?"
    call macy_remove_love from _call_macy_remove_love

    menu:
        "'You can't talk to me like that!'":
            play audio [ "<silence 1.6>", "sounds/doorslam.ogg" ]
            show macy_pd kitchen night workwear eyeroll:
                ease 1.6 xpos 1.0 xanchor 0.0
            pc "You can't talk to me like that, young lady!"
            with hpunch
            "But she's already out the door, slamming it behind her."
        "[abgreen]Say nothing.":
            play audio [ "<silence 1.6>", "sounds/doorslam.ogg" ]
            show macy_pd kitchen night workwear eyeroll:
                ease 1.6 xpos 1.0 xanchor 0.0
            "She leaves the room and slams the door behind her."
            with hpunch
            pc "..."

    scene black
    with fade
    pause 2.0
    return
