label w05d04_s08:

    call theme_macy from _call_theme_macy_22

    "Some time later."

    scene backdrop car nighttime
    show macy_pd car nighttime neutral:
        subpixel True
        xalign 0.7 yalign 0.07 zoom 1.0
        ease 34.0 zoom 1.2
    with fade
    macy "Hey."

    if not (denise_locked_out or macy_locked_out):
        if macy_love >= 8:
            show macy_pd car nighttime hug
            with dissolve
            pause 0.3

            show macy_pd car nighttime peck
            with dissolve
            pause 0.3

            show macy_pd car nighttime hug
            with dissolve

            macy "Mwah."

    pc "How was work?"

    show macy_pd car nighttime thoughtful
    with dissolve
    macy "[dan_name] was finally back today."
    menu:
        "[abgreen]Ask about him.":
            pc "Really? That's good news, right?"

            show macy_pd car nighttime sad
            with dissolve
            macy "He's never been away this long."
            pc "How was he doing?"

            show macy_pd car nighttime eyeroll
            with dissolve
            macy "Didn't let on a damn thing, but I know he was hurting."

            show macy_pd car nighttime thoughtful
            with dissolve
            macy "[ethel_name] kept looking at him sideways, but she didn't say anything about it."
            pc "I'm sorry to hear that."

            show macy_pd car nighttime thoughtful eyesclosed
            with dissolve
            macy "Yeah. I feel bad for them."

            show macy_pd car nighttime neutral
            with dissolve
            macy "But let's talk about something else."
            pc "Sure."
        "Don't.":

            pc "That's nice."

            show macy_pd car nighttime sad
            with dissolve
            macy "Yeah."

            show macy_pd car nighttime thoughtful
            with dissolve
            macy "..."

    if not (denise_locked_out or macy_locked_out):
        show macy_pd car nighttime smile
        with dissolve
        macy "So, did you get 'the talk'?"

        menu:
            "'The talk?'":
                pc "The talk?"

                show macy_pd car nighttime neutral
                with dissolve
                macy "From [denise_name]."

                show macy_pd car nighttime eyeroll
                with dissolve
                macy "About being on your best behavior and all this weekend?"

                if denise_locked_out or macy_locked_out:
                    pc "No, I didn't."
                    show macy_pd car nighttime shock
                    with dissolve
                    macy "Well, I got an earfull about having to be on my best behavior this weekend."
                else:
                    pc "Oh that. Yeah, something like that."

            "[abgreen]'Yeah.'" if not(denise_locked_out or macy_locked_out):
                pc "Yeah, I did."

            "'No.'" if denise_locked_out or macy_locked_out:
                pc "No, I didn't."
                show macy_pd car nighttime shock
                with dissolve
                macy "Well, I got an earfull about having to be on my best behavior this weekend."

        show macy_pd car nighttime neutral
        with dissolve
        macy "Tell you what, I'll make you a deal."

        show macy_pd car nighttime smile
        with dissolve
        macy "I won't be a dick if you aren't either."

        default w05d04_s08_tried_pinkyswear = False
        default w05d04_s08_did_pinky_swear = False
        menu:
            "'Deal!'":
                $ w05d04_s08_tried_pinkyswear = False
                $ w05d04_s08_did_pinky_swear = False
                pc "That's a deal, princess."

                show macy_pd car nighttime secretsmile:
                    0.5
                    ease 18.1 zoom 1.0
                with dissolve
                macy "Good."

            "[abgreen]'Pinky-swear?'" if not (denise_locked_out or macy_locked_out):
                $ w05d04_s08_tried_pinkyswear = True
                pc "How about we pinky-swear on it?"

                if macy_love >=7:
                    $ w05d04_s08_did_pinky_swear = True

                    show macy_pd car nighttime shock:
                        0.5
                        ease 32.1 zoom 1.0
                    with dissolve
                    macy "Are you kidding me?"
                    pc "No. Let's pinky-swear, like in the old days."

                    show macy_pd car nighttime eyeroll
                    with dissolve
                    macy "You're really serious, aren't you?"
                    pc "Yeah."

                    show macy_pd car nighttime neutral
                    with dissolve
                    macy "..."

                    show macy_pd car nighttime pinkyswear_neutral
                    with dissolve
                    macy "Alright, hold out your hand."

                    show macy_pd car nighttime pinkyswear_neutral_mc_hand
                    with dissolve
                    "You lock pinkies with your eldest [macy_rel_to_pc]."

                    show macy_pd car nighttime pinkyswear_smile_mc_hand
                    with dissolve
                    macy "I hereby pinky-swear I'll try not to be a dick this weekend."
                    pc "I swear it too."

                    show macy_pd car nighttime pinkyswear_neutral_mc_hand
                    with dissolve
                    macy "You have to say it, doofus."

                    default w05d04_s08_made_dad_joke = False
                    menu:
                        "[abgreen]'It, doofus.'":
                            $ w05d04_s08_made_dad_joke = True
                            pc "It, doofus."

                            show macy_pd car nighttime pinkyswear_neutral_mc_hand eyesclosed
                            with dissolve
                            macy "Last chance, or I'm pulling my pinky."
                            pc "Alright, I pinky-swear I won't be a dick this weekend."

                            show macy_pd car nighttime pinkyswear_smile_mc_hand
                            with dissolve
                            macy "Finally."

                            show macy_pd car nighttime shock
                            with dissolve
                            macy "Fuckin' hell, is there a rule that says you have to give up your sense of humor when you become a [pc_rel_to_macy]?"
                            pc "You used to love my jokes."

                            show macy_pd car nighttime eyeroll
                            with dissolve
                            macy "When I was a little kid maybe."

                            show macy_pd car nighttime smile
                            with dissolve
                            macy "Kids are dumb, they just automatically love everything their [pc_rel_to_macy] does."
                            pc "Maybe I sorta miss that."

                            show macy_pd car nighttime neutral
                            with dissolve
                            macy "Miss what?"
                            pc "You automatically liking everything I do."
                            pc "I liked that feeling."

                            show macy_pd car nighttime secretsmile
                            with dissolve
                            macy "Huh..."
                        "'I pinky-swear...'":

                            $ w05d04_s08_made_dad_joke = False
                            pc "I pinky-swear I won't be a dick this weekend."

                            show macy_pd car nighttime pinkyswear_smile_mc_hand
                            with dissolve
                            macy "Good."

                            show macy_pd car nighttime neutral
                            with dissolve
                            macy "Fuck that was dumb."
                            pc "I thought it was cute."

                            show macy_pd car nighttime secretsmile
                            with dissolve
                            macy "..."
                else:

                    $ w05d04_s08_did_pinky_swear = False

                    show macy_pd car nighttime shock:
                        0.5
                        ease 18.1 zoom 1.0
                    with dissolve
                    macy "Sheesh, you must have gotten me mixed up with your other [denise_rel_to_pc]."

                    show macy_pd car nighttime eyeroll
                    with dissolve
                    macy "I'm the one that isn't living in a magical fairytale world, remember?"
                    pc "Right, sorry."

                    show macy_pd car nighttime frown
                    with dissolve
                    macy "Just... don't be a dick, alright?"
                    pc "Alright."

                    show macy_pd car nighttime neutral
                    with dissolve
                    macy "..."

    call music_fade_slow from _call_music_fade_slow_527

    scene black
    with fade

    "Soon after, you arrive home."

    pause 2.0

    call theme_household from _call_theme_household_53

    scene kitchen_bg lookatsink nighttime:
        subpixel True
        xalign 0.5 yalign 0.3
        0.5
        ease 22.6 zoom 1.05
    show macy_pd kitchen night workwear neutral:
        subpixel True
        xanchor 0.0 xpos 1.0 yalign 0.3
        1.2
        parallel:
            easein 2.3 xalign 0.75
            ease (22.6 -2.3) xalign 0.8
        parallel:
            ease 22.6 zoom 1.1
    show denise_pd kitchen night puggies neutral:
        subpixel True
        xanchor 1.0 xpos 0.0 yalign 0.3
        0.5
        parallel:
            easein 2.2 xalign 0.25
            ease (22.6 -2.2) xalign 0.2
        parallel:
            ease 22.6 zoom 1.1
    with fade
    pause 1.0
    "When you go inside, [denise_name] is waiting for you."

    show kitchen_bg lookatsink nighttime
    show denise_pd kitchen night puggies happy
    show macy_pd kitchen night workwear neutral
    with dissolve
    deni "Right you two, no watching movies tonight!"

    show kitchen_bg lookatsink nighttime
    show denise_pd kitchen night puggies happy
    show macy_pd kitchen night workwear shocked
    with dissolve
    macy "What?!"

    show kitchen_bg lookatsink nighttime
    show denise_pd kitchen night puggies angry
    show macy_pd kitchen night workwear shocked
    with dissolve
    deni "You heard me. It's going to be a long and tiresome drive tomorrow."

    show kitchen_bg lookatsink nighttime
    show denise_pd kitchen night puggies smile
    show macy_pd kitchen night workwear shocked
    with dissolve
    deni "[denise_adr_pc_as_cap] needs a good night's rest."

    show kitchen_bg lookatsink nighttime
    show denise_pd kitchen night puggies smile
    show macy_pd kitchen night workwear frown
    with dissolve
    macy "Fine. We didn't have anything planned anyways."

    show kitchen_bg lookatsink nighttime
    show denise_pd kitchen night puggies neutral
    show macy_pd kitchen night workwear frown
    with dissolve
    deni "Then go and get changed and come to bed!"

    show kitchen_bg lookatsink nighttime
    show denise_pd kitchen night puggies neutral
    show macy_pd kitchen night workwear eyeroll
    with dissolve
    macy "Yes, [macy_adr_charlotte_as]."

    show kitchen_bg lookatsink nighttime
    show denise_pd kitchen night puggies angry
    show macy_pd kitchen night workwear eyeroll
    with dissolve
    deni "Hmpf."

    show kitchen_bg lookatsink nighttime
    show denise_pd kitchen night puggies smile:
        0.5
        ease 2.3 xalign 0.55
        ease 1.1 xalign 0.5
    show macy_pd kitchen night workwear eyeroll:
        0.5
        1.2
        ease 1.9 xalign 1.0
    with dissolve
    deni "Goodnight [denise_adr_pc_as]."

    show kitchen_bg lookatsink nighttime
    show denise_pd kitchen night puggies smile
    show macy_pd kitchen night workwear neutral
    with dissolve
    macy "Yeah, goodnight."

    call music_fade_slow from _call_music_fade_slow_528

    play audio [ "<silence 3.7>", "sounds/doorslam.ogg" ]
    show kitchen_bg lookatsink nighttime
    show denise_pd kitchen night puggies smile:
        0.5
        0.9
        easeout 2.1 xpos 1.0 xanchor 0.0
    show macy_pd kitchen night workwear neutral:
        0.5
        easeout 1.9 xpos 1.0 xanchor 0.0
    with dissolve
    pc "Goodnight girls."

    scene black
    with fade

    pause 2.0

    return
