label w01d05_s05:
    call theme_household from _call_theme_household_3

    "You arrive home and sit down for dinner."

    scene kitchen_bg dinnertable evening
    show denise_pd kitchen evening eating unhappy
    show macy_pd kitchen evening eating angry
    with fade

    macy "This crap again? Can't we have something other than [w01d01_s03_protein_choice] for a change?"

    show denise_pd kitchen evening eating unhappytalk
    with dissolve
    deni "I have to agree. I like corn as much as the next girl, but enough is enough."

    show macy_pd kitchen evening eating lookdenise
    with dissolve
    macy "Do you want to cook something together this weekend?"

    show denise_pd kitchen evening eating happy
    with dissolve
    deni "YES!"

    show macy_pd kitchen evening eating lookdeniseangry
    with dissolve
    macy "Good. You pick out a recipe, and I'll pick up the groceries tomorrow."

    default w01d05_s05_tried_to_be_funny = False
    menu:
        "Try to be funny.":
            $ w01d05_s05_tried_to_be_funny = True
            pc "Don't forget to pick up a bottle of Pepto..."

            show denise_pd kitchen evening eating lookmacy
            with dissolve
            pc "Ahahaha."

            show macy_pd kitchen evening eating lookdenise
            with dissolve
            pc "..."

            show macy_pd kitchen evening eating neutraltalk
            with dissolve
            macy "You done?"
            show denise_pd kitchen evening eating unhappytalk
            with dissolve
            deni "Yeah."

            show macy_pd kitchen evening eating lookdeniseangry
            with dissolve
            macy "Typical..."
            show denise_pd kitchen evening eating lookmacy
            with dissolve
            deni "Anyways..."

            show denise_pd kitchen evening eating neutral
            with dissolve
        "[abgreen]Try to be supportive.":

            $ w01d05_s05_tried_to_be_funny = False
            pc "Looking forward to it already."

            show denise_pd kitchen evening eating neutral
            with dissolve
            deni "We'll make something delicious, just wait and see."

            show macy_pd kitchen evening eating lookdenise
            with dissolve
            macy "It'll be fun."

            show denise_pd kitchen evening eating lookmacy
            with dissolve

    deni "That still leaves tomorrow."

    show macy_pd kitchen evening eating unhappy
    with dissolve
    macy "How about pizza and a movie?"

    pc "Sounds good to me."

    show denise_pd kitchen evening eating unhappytalk
    with dissolve
    deni "But you don't get to pick the movie, [denise_adr_pc_as]!"

    show macy_pd kitchen evening eating angry
    with dissolve
    macy "Yeah, the last time you picked one, it was awful."

    show denise_pd kitchen evening eating whipemouth
    with dissolve
    deni "And ancient. From like 2007 or something."
    pc "It was 2003."

    show denise_pd kitchen evening eating unhappy
    with dissolve
    deni "Even worse!"

    default w01d05_s05_pc_picked_movie = False
    menu:
        "Insist.":
            $ w01d05_s05_pc_picked_movie = True
            pc "But I have a very good one in mind. It picked up a lot of awards in its time."

            show macy_pd kitchen evening eating lookdeniseangry
            with dissolve
            macy "Can I still back out of this?"

            show denise_pd kitchen evening eating angryatmacy
            with dissolve
            deni "No way, I'm not watching whatever he's picking alone."

            if not w01d05_s02_pc_said_it_hurt:
                call music_fade_slow from _call_music_fade_slow_73

            show macy_pd kitchen evening eating underbreath
            with dissolve
            macy "Fine."
        "[abgreen]Let them pick.":

            $ w01d05_s05_pc_picked_movie = False
            pc "Right, angel, dazzle me with your best choice then."

            show macy_pd kitchen evening eating underbreath
            with dissolve
            macy "No movies where the main character is a dog, you hear!"

            if not w01d05_s02_pc_said_it_hurt:
                call music_fade_slow from _call_music_fade_slow_74

            show denise_pd kitchen evening eating angryatmacy
            with dissolve
            deni "Alright, alright! I'll pick something else."

    if w01d05_s02_pc_said_it_hurt:

        show denise_pd kitchen evening eating unhappytalk
        with dissolve
        deni "Ehm..., [denise_adr_pc_as]?"

        show macy_pd kitchen evening eating lookdenise
        with dissolve
        show denise_pd kitchen evening eating neutraltalk
        with dissolve
        deni "Are you...?"

        call music_fade_slow from _call_music_fade_slow_75

        show denise_pd kitchen evening eating unhappytalk
        with dissolve
        deni "Are you feeling okay now?"
        menu:
            "[abgreen]Answer.":
                show macy_pd kitchen evening eating lookdeniseangry
                with dissolve
                pc "I'm fine, angel..."

                call theme_macy from _call_theme_macy_6
                show macy_pd kitchen evening eating angry
                with dissolve
                macy "Wait, what happened?"
            "Pretend you didn't hear.":

                show macy_pd kitchen evening eating lookdeniseangry
                with dissolve
                pc "..."
                show denise_pd kitchen evening eating unhappy
                with dissolve
                deni "You know... from this morning, when I hit you?"

                call theme_macy from _call_theme_macy_7
                show macy_pd kitchen evening eating angry
                with dissolve
                macy "You did what?"

        show denise_pd kitchen evening eating unhappytalk
        with dissolve
        deni "I..."

        show denise_pd kitchen evening eating unhappy
        with dissolve
        deni "I hit [denise_adr_pc_as] by mistake."

        show denise_pd kitchen evening eating upset
        with dissolve
        deni "Twice... no, three times."

        show macy_pd kitchen evening eating lookdeniseangry
        with dissolve
        macy "By mistake?"

        show denise_pd kitchen evening eating unhappytalk
        with dissolve
        deni "Yes, and it really hurt him."

        show denise_pd kitchen evening eating upset
        with dissolve
        deni "Because it was in his..."
        pc "Ahem!"

        show macy_pd kitchen evening eating disbelief
        with dissolve
        macy "No way! You hit [player_name] in his... his..."
    else:

        show denise_pd kitchen evening eating takebite
        with dissolve
        deni "..."

        call theme_macy from _call_theme_macy_8
        show macy_pd kitchen evening eating neutraltalk
        with dissolve
        macy "So, [player_name]..."

        show macy_pd kitchen evening eating unhappy
        with dissolve
        macy "I hear we had an minor infestation of... rats... this morning?"

        show denise_pd kitchen evening eating unhappy
        with dissolve
        "[denise_name] looks away startled, then starts to whisper urgently."

        show denise_pd kitchen evening eating angryatmacy
        with dissolve
        deni "{size=-6}[macy_name]! You were supposed to keep it a secret!{/size}"

        show macy_pd kitchen evening eating disbelief
        with dissolve
        macy "I just can't believe that you hit him in the... in the..."

    show denise_pd kitchen evening eating angry
    with dissolve
    deni "In his [denise_penis_name]! I hit him in his [denise_penis_name]! Happy?!"

    show macy_pd kitchen evening eating laughoutloud
    with dissolve
    macy "Bwaaahaha!"

    show denise_pd kitchen evening eating unhappytalk
    show macy_pd kitchen evening eating laughoutloud eyesclosed
    with dissolve
    deni "It was a stupid mistake, alright?!"

    default w01d05_s05_pc_laughed = True
    menu:
        "[abgreen]Laugh.":
            $ w01d05_s05_pc_laughed = True
            pc "Hahaha!"

            show macy_pd kitchen evening eating laughoutloud
            with dissolve
            macy "Hahahahaha!"

            show denise_pd kitchen evening eating angry
            with dissolve
            deni "[denise_adr_pc_as_cap]! It's not funny!"

            pc "It is a little bit, angel."

            show denise_pd kitchen evening eating neutral
            with dissolve
            deni "..."

            show macy_pd kitchen evening eating laughoutloud eyesclosed
            with dissolve
            macy "Hehehehehehe!"

            show denise_pd kitchen evening eating laugh
            with dissolve
            deni "Maybe it is..."

            show macy_pd kitchen evening eating secretsmile
            with dissolve
            macy "Heeheehee... Phew..."
        "Stay silent.":

            $ w01d05_s05_pc_laughed = False
            show macy_pd kitchen evening eating laughoutloud
            with dissolve
            pc "..."

            show macy_pd kitchen evening eating laughoutloud eyesclosed
            with dissolve
            macy "Hahahahaha!"

            show denise_pd kitchen evening eating angryatmacy
            with dissolve
            deni "..."

            show macy_pd kitchen evening eating secretsmile
            with dissolve
            macy "Hehehe..."

            show macy_pd kitchen evening eating underbreath
            with dissolve
            macy "Tough crowd."

    show denise_pd kitchen evening eating takebite
    show macy_pd kitchen evening eating lookdenise
    with dissolve
    "You continue eating for a while."

    show macy_pd kitchen evening eating neutraltalk
    with dissolve
    macy "By the way, I think they delivered the study materials from school."

    show macy_pd kitchen evening eating lookdenise
    show denise_pd kitchen evening eating lookmacy
    with dissolve

    macy "It's in the hallway. The box is pretty heavy."
    pc "That's good news."

    call music_fade_slow from _call_music_fade_slow_76

    pc "Shall we have a look tomorrow, angel?"

    show denise_pd kitchen evening eating neutral
    with dissolve
    deni "Sure, [denise_adr_pc_as]."
    pc "Okay."

    pc "In other news, guess who got asked out on a date?"

    show denise_pd kitchen evening eating happy
    with dissolve
    deni "What? No way..."

    show macy_pd kitchen evening eating disbelief
    with dissolve
    macy "..."

    if w01d04_s03_rejected_brooke:
        pc "Way! There's this lady at the office."
    else:
        pc "Way! There's this nice lady at the office."

    call theme_macy_mad from _call_theme_macy_mad_2
    show macy_pd kitchen evening eating lookdeniseangry
    with dissolve
    macy "..."

    show denise_pd kitchen evening eating laugh
    with dissolve
    deni "So when are you going to go?"

    show macy_pd kitchen evening eating disbelief
    with dissolve
    menu:
        "Answer.":
            pc "Well..."

    show macy_pd kitchen evening eating angry
    show denise_pd kitchen evening eating lookmacy
    with dissolve
    "Before you can finish your sentence, [macy_name] bursts out in anger!"

    show macy_pd kitchen evening eating furious
    show denise_pd kitchen evening eating whipemouth
    with dissolve
    macy "Are you completely mad?!"
    call macy_add_anger from _call_macy_add_anger_1

    show macy_pd kitchen evening eating angry
    with dissolve
    macy "How can you even consider going out with some {i}bimbo{/i} from your office at a time like this?!"

    default w01d05_s05_lost_temper = False
    menu:
        "[abgreen]Stay calm.":
            $ w01d05_s05_lost_temper = False
            if w01d04_s03_rejected_brooke:
                pc "Well I didn't go. In fact I turned her down."
            else:
                pc "Well I didn't go. In fact I told her it is not a good time."

            show macy_pd kitchen evening eating furious
            with dissolve
            macy "Good! I..."

            show macy_pd kitchen evening eating unhappy
            with dissolve
            macy "[denise_name] needs you here, at home!"

            show denise_pd kitchen evening eating unhappy
            with dissolve
            deni "..."
        "Lose your temper.":

            $ w01d05_s05_lost_temper = True
            pc "You mind your own business, young lady!"

            show macy_pd kitchen evening eating furious
            with dissolve
            macy "I..."

            show macy_pd kitchen evening eating unhappy
            with dissolve
            macy "[denise_name] needs you here, at home!"

            show denise_pd kitchen evening eating unhappy
            with dissolve
            deni "..."

            pc "Well, I need to be able to take a break from all... this... and have some fun sometimes!"
            show macy_pd kitchen evening eating disbelief
            with dissolve
            macy "..."

            show macy_pd kitchen evening eating sad
            with dissolve
            call macy_remove_love from _call_macy_remove_love_1

            show macy_pd kitchen evening eating sad eyesclosed
            with dissolve

    call music_fade_slow from _call_music_fade_slow_77

    show denise_pd kitchen evening eating angry
    with dissolve
    deni "Please!"

    show macy_pd kitchen evening eating lookdeniseangry
    with dissolve
    macy "..."

    call theme_denise_sad from _call_theme_denise_sad_8

    show denise_pd kitchen evening eating upset
    with dissolve
    deni "Stop fighting!"

    show denise_pd kitchen evening eating unhappy
    with dissolve
    deni "I'm right here you know!"

    show macy_pd kitchen evening eating embarrassed
    with dissolve
    macy "Sorry..."

    default w01d05_s05_doubled_down = False
    menu:
        "[abgreen]Say sorry.":
            $ w01d05_s05_doubled_down = False
            pc "Sorry, angel."

            show macy_pd kitchen evening eating lookdeniseangry
            with dissolve
            macy "I... I have to go. I'm late!"

            play audio [ "<silence 1.8>", "sounds/doorslam.ogg" ]
            scene black
            with fade
            "[macy_name] stalks out of the room."
        "Double down.":

            $ w01d05_s05_doubled_down = True
            pc "As well you should be!"
            pc "I don't appreciate being spoken to like that!"

            show macy_pd kitchen evening eating furious
            with dissolve
            macy "Tough luck!"

            play audio [ "<silence 1.8>", "sounds/doorslam.ogg" ]
            scene black
            with fade
            "[macy_name] storms out of the room."

    "Neither you nor [denise_name] are very hungry after that."
    "You clear the table together in silence."

    pause 2.0

    return
