label w02d03_s03:
    if not w02d01_s02_agree:
        return

    scene office_bg midday copier:
        subpixel True
        xalign 0.5 yalign 0.5 zoom 1.0
        0.5
        ease 7.0 zoom 1.05 xalign 0.6 yalign 0.2
    show brooke_pd office midday copier neutral:
        subpixel True
        xalign 0.5 yalign 0.5 zoom 1.0
        0.5
        ease 7.0 zoom 1.1 xalign 0.6 yalign 0.2
    with fade
    "When you arrive at the copier, [brooke_name] is already there."

    broo "Good, you're here."
    pc "Yeah, I got your note."

    call theme_brooke_abomb from _call_theme_brooke_abomb_2

    show brooke_pd office midday copier serious
    with dissolve
    broo "Did you eat it, like I instructed?"

    default w02d03_s03_lied_about_eating_note = False
    menu:
        "'Yes.'" if not w02d03_s02_ate_note:
            $ w02d03_s03_lied_about_eating_note = True
            pc "Yeah, I did."

            show brooke_pd office midday copier smile
            with dissolve
            broo "No, you didn't!"

            show brooke_pd office midday copier neutral
            with dissolve
            broo "Did you?"

            show brooke_pd office midday copier thoughtful
            with dissolve
            broo "I just included it as a joke."

            pc "Nah, I didn't."
            pc "I'm not stupid."

            show brooke_pd office midday copier happy
            with dissolve
            broo "Phew."

            show brooke_pd office midday copier smile
            with dissolve
            broo "You had me worried there for a second."

        "'Yes.'" if w02d03_s02_ate_note:
            $ w02d03_s03_lied_about_eating_note = False
            pc "Yeah, I did."

            show brooke_pd office midday copier smile
            with dissolve
            broo "No, you didn't."

            show brooke_pd office midday copier neutral
            with dissolve
            broo "You did? Nah."

            show brooke_pd office midday copier serious
            with dissolve
            broo "I just included it as a joke."

            pc "Oh..."

            show brooke_pd office midday copier thoughtful
            with dissolve
            broo "..."
            pc "..."

            show brooke_pd office midday copier concerned
            with dissolve
            broo "Well, it's good to know that you're a literal person and you're not the squeamish type when it comes to using your mouth."

        "'No.'" if w02d03_s02_ate_note:
            $ w02d03_s03_lied_about_eating_note = True
            pc "I... ah..."

            show brooke_pd office midday copier thoughtful
            with dissolve
            broo "You didn't, did you?"
            pc "Eh... of course not!"

            show brooke_pd office midday copier happy
            with dissolve
            broo "Thank god, I only included that as a joke."
            pc "Yes, I got it. A joke. Ahahaha!"

            show brooke_pd office midday copier concerned
            with dissolve
            broo "Yeah... wasn't that funny."

        "[abgreen]'No.'" if not w02d03_s02_ate_note:
            $ w02d03_s03_lied_about_eating_note = False
            pc "No, I didn't."

            show brooke_pd office midday copier happy
            with dissolve
            broo "Good, I only included that as a joke."
            pc "I'm just happy you didn't send an email that wiped my hard drive."

            show brooke_pd office midday copier flirt
            with dissolve
            broo "Still working on that. Maybe next time."

    show brooke_pd office midday copier neutral
    with dissolve
    broo "Anyways..."

    show brooke_pd office midday copier happy
    with dissolve
    broo "You will be pleased to know... the plan succeeded!"

    pc "Nice!"

    show brooke_pd office midday copier thoughtful
    with dissolve
    broo "You know I couldn't be there myself."

    show brooke_pd office midday copier smile
    with dissolve
    broo "But from the way I've heard it told by someone who was, Johnson was taken completely by surprise."

    show brooke_pd office midday copier happy
    with dissolve
    broo "They said Johnson first turned as white as a sheet and then as red as a tomato."

    show brooke_pd office midday copier serious
    with dissolve
    if w02d01_s03_pc_copied_dick:
        broo "Then, he had everyone tear out the offending pages."
    else:
        broo "Then, he had everyone tear out the offending page."

    show brooke_pd office midday copier thoughtful
    with dissolve
    broo "After that, he ordered all phones confiscated to prevent any recording from coming out."
    show brooke_pd office midday copier happy
    with dissolve
    broo "However, it seems he didn't get them all, or maybe some videos already made it to the cloud."

    show brooke_pd office midday copier talk
    with dissolve
    broo "In any case, I've heard there's a video circulating among a slowly growing number of people."

    show brooke_pd office midday copier happy
    with dissolve
    if w02d01_s03_pc_copied_dick:
        broo "I haven't seen it yet, but apart from Johnson's rant, it is also supposed to have a pretty good shot of the images in there."
    else:
        broo "I haven't seen it yet, but apart from Johnson's rant, it is also supposed to have a pretty good shot of the image in there."

    show brooke_pd office midday copier smile
    with dissolve
    broo "It's only a matter of time before it goes viral."

    pc "That's great, you did it!"

    if not w02d01_s03_pc_copied_dick:
        show brooke_pd office midday copier happy
        with dissolve
        broo "Couldn't have done it without you!"
    else:
        show brooke_pd office midday copier happy
        with dissolve
        broo "No, {i}we{/i} did it."

    show brooke_pd office midday copier neutral
    with dissolve
    broo "God, this is exciting."

    show brooke_pd office midday copier flirt lookaway
    with dissolve
    broo "I'm so turned on right now."

    menu:
        "'Because you pulled it off?'":
            pc "Because your crazy scheme worked and you pulled it off?"
            show brooke_pd office midday copier thoughtful
            with dissolve
            broo "Yeah."

            show brooke_pd office midday copier concerned
            with dissolve
            broo "But if I'm totally honest..."

            show brooke_pd office midday copier flirt
            broo "Also because all those people saw me naked."
        "[abgreen]'Because all those people saw you naked?'":

            pc "Because all those people saw you naked?"
            pc "And more will when it goes viral?"

            show brooke_pd office midday copier happy
            with dissolve
            broo "God yes!"

            show brooke_pd office midday copier thoughtful
            with dissolve
            broo "I'm also happy that crazy scheme worked."

            show brooke_pd office midday copier flirt
            with dissolve
            broo "But, just think of it..."

    show brooke_pd office midday copier flirt lookaway
    with dissolve
    broo "When I walk around the office, and I see those people I know were there in the room..."

    show brooke_pd office midday copier concerned
    with dissolve
    broo "...all I can think is: 'You saw my butt hole, and now you're saying hi to me in passing and you don't even know it was me you saw!'"

    show brooke_pd office midday copier serious
    with dissolve
    broo "And then I wonder: 'Do you think it was me? Do you suspect it?'"

    show brooke_pd office midday copier smile
    with dissolve
    broo "'Are you picturing me naked right now, trying to figure out if that pussy could be mine?'"

    show brooke_pd office midday copier happy
    with dissolve
    broo "It makes me sooo horny."

    default w02d03_s03_agreed_its_hot = False
    menu:
        "[abgreen]Agree." if w02d01_s03_pc_copied_dick:
            $ w02d03_s03_agreed_its_hot = True
            pc "Now that you say it like that."
            pc "That is pretty hot."
            pc "I'm getting turned on now, too."

            show brooke_pd office midday copier flirt
            with dissolve
            broo "See?"

        "Don't." if w02d01_s03_pc_copied_dick:
            $ w02d03_s03_agreed_its_hot = False
            pc "O... kay."
            pc "I think we can officially add 'exhibitionism' to your list of fetishes?"

            show brooke_pd office midday copier smile
            with dissolve
            broo "Oh definitely!"

            show brooke_pd office midday copier flirt
            with dissolve
            broo "It doesn't do it for you?"
            pc "Nah... but I'm still happy I helped out."

        "Agree." if not w02d01_s03_pc_copied_dick:
            $ w02d03_s03_agreed_its_hot = True
            pc "Now that you say it like that."
            pc "That is pretty hot."
            pc "I almost regret not going through with it now."

            show brooke_pd office midday copier concerned
            with dissolve
            broo "I did warn you about feeling left out."
            pc "You did."

        "Don't." if not w02d01_s03_pc_copied_dick:
            $ w02d03_s03_agreed_its_hot = False
            pc "O... kay."
            pc "I think we can officially add 'exhibitionism' to your list of fetishes?"

            show brooke_pd office midday copier flirt
            with dissolve
            broo "Oh definitely!"

            show brooke_pd office midday copier concerned
            with dissolve
            broo "No regrets you chickened out?"
            pc "Nah..."

    if brooke_love < 6:
        call w02d03_s03_broo_bolt from _call_w02d03_s03_broo_bolt
    else:

        call music_fade_slow from _call_music_fade_slow_98

        show brooke_pd office midday copier neutral
        with dissolve
        broo "Say..."

        show brooke_pd office midday copier thoughtful
        with dissolve
        broo "Stop me if I'm going too far, but I..."

        show brooke_pd office midday copier flirt lookaway
        with dissolve
        broo "I think I could really use some release."
        pc "What are you saying?"

        call theme_brooke_blues from _call_theme_brooke_blues_2

        show brooke_pd office midday copier flirt
        with dissolve
        broo "I'm saying: how about, you, me and Marv here have ourselves a hot and steamy threesome?"

        default w02d03_s03_pc_said_yes = False
        menu:
            "'No thanks.'":
                $ w02d03_s03_pc_said_yes = False
                pc "Ahhh I think I have to pass on that."

                show brooke_pd office midday copier talk
                with dissolve
                broo "Really? Damn!"
                pc "Sorry."
                pc "Now..."
                call w02d03_s03_broo_bolt from _call_w02d03_s03_broo_bolt_1
            "[abgreen]'Yes please!'":

                $ w02d03_s03_pc_said_yes = True
                call w02d03_s03_broo_sexual_encounter from _call_w02d03_s03_broo_sexual_encounter

    call w02d03_s03_s3_encounter from _call_w02d03_s03_s3_encounter

    return
