label w03d01_s07:
    call theme_macy_sad from _call_theme_macy_sad_12

    show setpiece_diner night macy standoutfront angry:
        subpixel True
        xalign 0.3 yalign 0.2
        ease 18.1 zoom 1.3
    with fade

    "[macy_name] is already standing in the doorway when you arrive."
    "She glowers at the car as you pull up, waiting a few moments before sullenly walking over to get in."

    scene black
    with fade

    pause 2.0

    scene backdrop car nighttime
    show macy_pd car nighttime thoughtful:
        subpixel True
        xalign 0.7 yalign 0.05 zoom 1.0
        ease 25.0 zoom 1.2
    with fade
    "The drive is even more awkward than dinner, cooped up as you are in the small compartment..."

    show macy_pd car nighttime frown
    with dissolve
    "...without your youngest [denise_rel_to_pc] to temper the emotions that lie thick and heavy in the air between you and your eldest [macy_rel_to_pc]."

    if w02d07_s04_picked_up_candy:
        default w03d01_s07_offered_candy = False
        menu:
            "Offer the candy.":
                $ w03d01_s07_offered_candy = True
                pc "There's..."
                pc "There's some candy in the glove box."
                pc "It's the good stuff."

                show macy_pd car nighttime candy_angry:
                    ease 15.3 zoom 1.0
                with dissolve
                "She takes the box from the glove compartment and scowls at it."

                show macy_pd car nighttime candy_angry eyesclosed
                with dissolve
                macy "I love these."

                show macy_pd car nighttime thoughtful
                with fade
                "Without saying another word, she opens up the window and drops the box out of the car."
                pc "..."

                show macy_pd car nighttime frown
                with dissolve
                macy "..."
                if macy_love >= 6:
                    call macy_remove_love from _call_macy_remove_love_4
            "[abgreen]Don't.":

                $ w03d01_s07_offered_candy = False
                pause 0.0


    show macy_pd car nighttime thoughtful eyesclosed
    with dissolve
    "You manage to endure the leaden silence for long enough to make it home."

    scene black
    with fade

    pause 2.0

    return
