label w02d02_s02:

    scene kitchen_bg morning:
        subpixel True
        xalign 0.5 yalign 0.5 zoom 1.1
        0.5
        ease 12.0 zoom 1.0
    show denise_pd kitchen morning nightwear smile:
        subpixel True
        xanchor 0.0 xpos 1.0 yalign 0.5 zoom 1.1
        0.5
        parallel:
            ease 12.0 zoom 1.0
        parallel:
            ease 1.7 xalign 0.5
    with fade

    "Meanwhile, [denise_name] has put on her clothes and enters the kitchen."

    show denise_pd kitchen morning nightwear unhappy
    with dissolve
    deni_thought "That was {u}really{/u} peculiar."

    show denise_pd kitchen morning nightwear neutral
    with dissolve
    deni_thought "Think he may have had another..."

    call theme_macy from _call_theme_macy_10
    show denise_pd kitchen morning nightwear smile:
        subpixel True
        0.5
        ease 1.2 xalign 0.25
    show macy_pd kitchen morning nightwear annoyed:
        subpixel True
        xanchor 0.0 xpos 1.0
        0.5
        easein 1.8 xalign 0.75
    with dissolve
    "At that moment, [macy_name] enters the room as well."

    show denise_pd kitchen morning nightwear unhappy
    with dissolve
    deni "You're up already? Did I wake you?"

    show macy_pd kitchen morning nightwear neutral
    with dissolve
    macy "Maybe. Don't worry about it."

    show macy_pd kitchen morning nightwear smile
    with dissolve
    macy "You sleep well?"

    show denise_pd kitchen morning nightwear happy
    with dissolve
    deni "Really good. You?"

    show macy_pd kitchen morning nightwear eyeroll
    with dissolve
    macy "Not particularly."

    show macy_pd kitchen morning nightwear annoyed
    with dissolve
    macy "Someone kept me up all night fumbling with my boobs."

    show denise_pd kitchen morning nightwear unhappy
    with dissolve
    deni "You told me I could!"

    show denise_pd kitchen morning nightwear angry
    with dissolve
    deni "Besides, you're lying."

    show denise_pd kitchen morning nightwear happy
    with dissolve
    deni "You were fast asleep in minutes."

    show macy_pd kitchen morning nightwear smile
    with dissolve
    macy "Yeah... yeah, I was."

    show macy_pd kitchen morning nightwear annoyed
    with dissolve
    macy "Is the bathroom still occupied? I really need to go."

    show denise_pd kitchen morning nightwear unhappy
    with dissolve
    deni "You too?"

    show denise_pd kitchen morning nightwear neutral
    with dissolve
    deni "[denise_adr_pc_as_cap] is still in there."

    show denise_pd kitchen morning nightwear smile
    with dissolve
    deni "I'm not sure if he's finished already."

    play audio [ "<silence 2.6>", "sounds/doorslam.ogg" ]
    show macy_pd kitchen morning nightwear shocked:
        subpixel True
        yalign 1.0
        0.5
        ease 0.15 zoom 1.01
        ease 0.15 zoom 1.0
        ease 0.15 zoom 1.01
        ease 0.15 zoom 1.0
        ease 0.15 zoom 1.01
        ease 0.15 zoom 1.0
        easeout 1.2 xanchor 0.0 xpos 1.0
    show denise_pd kitchen morning nightwear smile:
        subpixel True
        1.3
        ease 2.2 xalign 0.5
    with dissolve
    macy "Okay jinxed it by talking about it can't hold any longer now bye!"

    show denise_pd kitchen morning nightwear unhappy
    with dissolve
    deni "B-bye..."

    scene black
    with fade

    if w02d02_s01_take_care_of_it:
        scene bathroom_bg morning
        show pc_pd bathroom morning phone searchporn
        with fade
        "The video is just about ready to start when there's a single, urgent knock at the door."

        show pc_pd bathroom morning phone searchporn:
            subpixel True
            0.5
            ease 0.9 ypos 1.0 yanchor 0.0
        with dissolve
        "You quickly put away the phone lest someone hear something."
        hide pc_pd
    else:
        scene bathroom_bg morning
        with fade
        "You are busy doing mental exercises to distract yourself and bring down your level of arousal."
        "There's a single, urgent knock at the door."

    pc_thought "For the love of..."
    pc "Occupied!"

    "There's a series of knocks at the door, adding discomfort, annoyance and alarm to the urgency of the first one."

    macy "Open up! I need to use the bathroom!"

    menu:
        "'I'm in here.'":
            pc "I'm in here!"
            macy "I'm going to explode! Please open up right now!"
            macy "If you don't, I'm going to make an awful mess in the hallway. And I am not going to clean that up!"
            "You have little choice but to open the door."
            "But not until after you've grabbed a bunch of towels to hold in front of you and hide your state."
            pc_thought "Please don't let her notice."
            "You unlatch the door."
        "[abgreen]Open up.":

            "You grab a bunch of towels and hold them in front of you to hide your state."
            pc_thought "Please don't let her notice."
            "You unlatch the door."

    show macy_pd bathroom morning sleepwear frown:
        subpixel True
        xpos 0.0 xanchor 1.0 yalign 1.0
        0.5
        ease 0.9 xalign 0.6
        parallel:
            choice:
                1.2
            choice:
                3.2
            choice:
                5.0
            pass
            choice:
                ease 0.15 zoom 1.01
                ease 0.15 zoom 1.0
                ease 0.15 zoom 1.01
                ease 0.15 zoom 1.0
                ease 0.15 zoom 1.01
                ease 0.15 zoom 1.0
            choice:
                ease 0.15 zoom 1.01
                ease 0.15 zoom 1.0
                ease 0.15 zoom 1.01
                ease 0.15 zoom 1.0
            choice:
                ease 0.15 zoom 1.01
                ease 0.15 zoom 1.0
            choice:
                pass
            repeat
        parallel:
            choice:
                ease 1.2 xalign 0.45
                ease 1.2 xalign 0.55
            choice:
                ease 1.4 xalign 0.4
                ease 1.4 xalign 0.6
            choice:
                ease 1.9 xalign 0.35
                ease 1.9 xalign 0.65
            choice:
                ease 0.9 xalign 0.5
                3.1
                ease 0.9 xalign 0.6
            repeat

    with dissolve
    "[macy_name] shoulders her way past you."
    "You present her with what you hope is a smile, but objectively qualifies as a rictus, hoping she doesn't notice anything is off."

    show macy_pd bathroom morning sleepwear shocked
    with dissolve
    "She hops around the bathroom, her look of bewilderment and confusion matching yours."

    show macy_pd bathroom morning sleepwear frown
    with dissolve
    macy "What?!"

    pc "I'm... eh... taking these towels to be washed."

    show macy_pd bathroom morning sleepwear eyeroll
    with dissolve
    macy "Do I look like I care?"

    pc "I didn't want you to think..."

    show macy_pd bathroom morning sleepwear frown
    with dissolve
    macy "I swear to you, nothing could be further from my mind!"

    show macy_pd bathroom morning sleepwear gotogo
    with dissolve
    macy "I need to go."

    show macy_pd bathroom morning sleepwear shocked
    with dissolve
    macy "Really bad."

    pc "I need to grab my..."

    show macy_pd bathroom morning sleepwear gotogo
    with dissolve
    macy "Oh for the love of fuck!"

    default w02d02_s02_language = False
    menu:
        "'Language!'":
            $ w02d02_s02_language = True
            pc "Language!"
            show macy_pd bathroom morning sleepwear shocked
            with dissolve
            macy "Are you fucking kidding me right now?!"
        "[abgreen]Say nothing.":

            $ w02d02_s02_language = False
            pc "Alright I'm g..."

    show macy_pd bathroom morning sleepwear frown
    with dissolve
    with hpunch
    macy "OUT! NOW!"

    scene black
    with fade

    call music_fade_slow from _call_music_fade_slow_100
    call sound_doorslam from _call_sound_doorslam_7
    scene setpiece hallway morning bathroomdoor
    with hpunch
    pc_thought "This feels familiar."

    scene black
    with fade

    "[denise_name] comes to check what all the hubbub is about."
    "She takes one look at you, standing in the hallway holding a bundle of towels, raises her eyebrows, and returns to the living room without saying a word."
    pc_thought "Great."

    "After all this upheaval, your erection soon subsides."
    "You pretend to be busy in the hallway until [macy_name] vacates the bathroom..."
    "...allowing you just enough time to get ready and to make it to work in time, if you hurry."

    call theme_pc from _call_theme_pc_2
    if denise_have_coffee_ritual:
        scene kitchen_bg morning
        show denise_pd kitchen morning nightwear holdcoffee
        with fade
        pause 0.5
        show denise_pd kitchen morning nightwear givecoffee
        with dissolve

        "Before you set out for work, you stop by the kitchen for another ritual you established with your youngest [denise_rel_to_pc]."

        show denise_pd kitchen morning nightwear hug
        with dissolve
        pause 0.4
        show denise_pd kitchen morning nightwear peck
        with dissolve
        pause 0.9
        show denise_pd kitchen morning nightwear hug
        with dissolve

        "You quickly gulp down the hot liquid, and she kisses you goodbye before letting you leave."
        scene black
        with fade

    pause 2.0

    return
