label w02d01_s02:

    "It's a beautiful morning as you drive to work."
    "The guy on the FM promises clear skies and high temperatures for the rest of the week."
    "You arrive to find all the parking spots that have shade in the afternoon already filled up."

    scene setpiece office midday desk
    with fade
    "In the air-conditioned, fluorescent gloom of your floor, it's just another Monday at the office."
    "You settle in and get to work."

    call theme_brooke from _call_theme_brooke_6

    scene office_bg midday:
        subpixel True
        xalign 0.5 yalign 0.0 zoom 1.1
        0.5
        ease 19 zoom 1.0
    show brooke_pd office midday cubicle smile:
        subpixel True
        xalign 0.5 yalign 0.0 zoom 1.2
        0.5
        ease 19 zoom 1.0
    with fade

    "Later that morning, [brooke_name] drops by."

    show brooke_pd office midday cubicle talk
    with dissolve
    broo "Hey you, how was your weekend?"

    default w02d01_s02_told_about_weekend = True
    menu:
        "[abgreen]Tell her.":

            $ w02d01_s02_told_about_weekend = True
            pc "Pretty good. I took my youngest [denise_rel_to_pc] to the museum."

            show brooke_pd office midday cubicle smile
            with dissolve
            broo "Oh, the renaissance art thing? It was in the news the other day."

            show brooke_pd office midday cubicle happy
            with dissolve
            broo "Wasn't there a bit of a scandal because of the subject matter?"
            pc "Really?"

            show brooke_pd office midday cubicle concern
            with dissolve
            broo "Yeah. Something about it not being suitable for younger visitors and tour groups with kids."

            default w02d01_s02_understood_fuss = False
            menu:
                "'Understandable.'":
                    $ w02d01_s02_understood_fuss = True
                    pc "I can understand why."
                    pc "There was classic art depicting biblical scenes."
                    pc "But some of the paintings dealt rather explicitly with a very inappropriate relationship between family members."

                    show brooke_pd office midday cubicle talk
                    with dissolve
                    broo "I don't see why people make such a fuss."

                    show brooke_pd office midday cubicle happy
                    with dissolve
                    broo "If scenes from the bible are so inappropriate, why do people who worry about such things keep trying to force all of us to live by it?"

                    show brooke_pd office midday cubicle serious
                    with dissolve
                    broo "Some people will complain about anything I guess."
                "[abgreen]'Don't see why.'":

                    $ w02d01_s02_understood_fuss = False
                    pc "I don't really understand why that would be."
                    pc "There was classic art depicting biblical scenes."
                    pc "Sure, some of it can get pretty intense."
                    pc "But it comes from the same book that they use to teach those young kids in Sunday school, right?"
                    show brooke_pd office midday cubicle serious
                    with dissolve
                    broo "Some people will complain about anything I guess."

            pc "No matter, I had a great time with my [denise_rel_to_pc]."

            show brooke_pd office midday cubicle smile
            with dissolve
            broo "That's nice."
        "Don't.":

            $ w02d01_s02_told_about_weekend = False
            pc "Yeah, pretty good. Nothing special."
            pc "You?"
            show brooke_pd office midday cubicle smile
            with dissolve
            broo "Same."

    show brooke_pd office midday cubicle talk
    with dissolve
    broo "Anyway."

    show brooke_pd office midday cubicle concern
    with dissolve
    broo "I..."

    show brooke_pd office midday cubicle serious
    with dissolve
    broo "I need your help."

    show brooke_pd office midday cubicle worried
    with dissolve
    broo "More specifically, I need a partner in crime."

    show brooke_pd office midday cubicle serious
    with dissolve
    broo "I have a feeling I can trust you."

    if w01d04_s03_told_brooke_about_emergency and w01d05_s04_told_about_incident and w02d01_s02_told_about_weekend:
        show brooke_pd office midday cubicle flirt
        with dissolve
        broo "You've always been honest with me."
    elif w01d04_s03_told_brooke_about_emergency or w01d05_s04_told_about_incident or w02d01_s02_told_about_weekend:
        show brooke_pd office midday cubicle talk
        with dissolve
        broo "You know when to share, and when to keep things to yourself."
    else:
        show brooke_pd office midday cubicle concern
        with dissolve
        broo "You know how to keep a secret."

    show brooke_pd office midday cubicle serious
    with dissolve
    broo "Now, before I say anything more, I have to be honest."

    show brooke_pd office midday cubicle concern
    with dissolve
    broo "It could get {i}you{/i} fired."

    show brooke_pd office midday cubicle worried
    with dissolve
    broo "It could definitely get {i}me{/i} fired."

    show brooke_pd office midday cubicle flirt
    with dissolve
    broo "And it's irresponsible, immature and dumb."

    show brooke_pd office midday cubicle smile
    with dissolve
    broo "Are you in?"

    pc_thought "I better think hard about this. If I decline, it could have repercussions for the future."

    default w02d01_s02_agree = True
    default w02d01_s02_hesitated = False
    menu:
        "[abgreen]'Yes!'":
            $ w02d01_s02_agree = True
            pc "You had me at getting fired."
            call w02d01_s02_agree_text from _call_w02d01_s02_agree_text
        "'No!'":

            $ w02d01_s02_agree = False
            pc "No way!"
            call w02d01_s02_disagree_text from _call_w02d01_s02_disagree_text
        "'Need more info.'":

            $ w02d01_s02_hesitated = True
            pc "You're not really selling it."
            pc "If the risks are that big, I need more info before I can agree to anything."

            show brooke_pd office midday cubicle talk
            with dissolve
            broo "Sorry, that's all I can say now."

            show brooke_pd office midday cubicle serious
            with dissolve
            broo "I need to know you're on board before I can risk telling you more."

            show brooke_pd office midday cubicle concern
            with dissolve
            broo "So, are you in, or are you out?"

            menu:
                "[abgreen]'In...?'":
                    $ w02d01_s02_agree = True
                    pc "I'm... in... I guess."
                    call w02d01_s02_agree_text from _call_w02d01_s02_agree_text_1
                "'Out...?'":

                    $ w02d01_s02_agree = False
                    pc "I'm going to have to pass."
                    call w02d01_s02_disagree_text from _call_w02d01_s02_disagree_text_1

    pause 2.0
    return

label w02d01_s02_agree_text:
    show brooke_pd office midday cubicle talk
    with dissolve
    broo "Good!"

    show brooke_pd office midday cubicle flirt
    with dissolve
    broo "Meet me at the copier in fifteen minutes."

    scene black
    with fade

    "She walks off, glancing left and right as she goes as if to make sure no one is watching."
    return

label w02d01_s02_disagree_text:
    pc "It's not much, but I need this job to provide for my [group_adr_as]."

    show brooke_pd office midday cubicle serious
    with dissolve
    broo "I understand."

    show brooke_pd office midday cubicle flirt
    with dissolve
    broo "Never mind, it was a stupid idea anyway."

    show brooke_pd office midday cubicle talk
    with dissolve
    broo "I'll talk to you later."

    call music_fade_slow from _call_music_fade_slow_124
    scene black
    with fade
    "With that, she goes about her business, and so do you."

    "Soon enough, it's time to go home."

    return
