label w04d03_s03:

    if not(denise_locked_out or macy_locked_out):
        call theme_pc from _call_theme_pc_17

    scene setpiece office midday desk:
        subpixel True
        xalign 0.5 yalign 0.6 zoom 1.05
        ease 12.7 zoom 1.00
    with fade

    if denise_locked_out or macy_locked_out:
        "You arrive at the office, and settle in at your desk."
    else:
        default w04d03_s03_picked_up_decaf_final = False
        if w04d02_s03_picked_up_decaf or w04d02_s02_liked_decaf:
            $ w04d03_s03_picked_up_decaf_final = True
            "You arrive at the office, and pick up an uncaffeinated dairy-free drink of choice before settling in at your desk."
        else:
            menu:
                "Pick up herbal tea." if pc_coffee == "tea":
                    $ w04d03_s03_picked_up_decaf_final = True
                    "You pick up some herbal tea like your [denise_rel_to_pc] asked you to, before settling in at your desk."

                "Pick up decaf." if pc_coffee != "tea":
                    $ w04d03_s03_picked_up_decaf_final = True
                    "You pick up some decaf like your [denise_rel_to_pc] asked you to, before settling in at your desk."
                "[abgreen]Pick up juice.":

                    $ w04d03_s03_picked_up_decaf_final = True
                    "You pull some non-dairy fruit drink from a vending machine like your [denise_rel_to_pc] asked you to, before settling in at your desk."

                "Pick up the caffeinated stuff." if not w04d02_s02_liked_decaf:
                    $ w04d03_s03_picked_up_decaf_final = False
                    "You pick up some regular, caffeinated [pc_coffee] in spite of what your [denise_rel_to_pc] asked you to do twice now, before settling in at your desk."

    if w04d02_s05_agreed_to_tcl_sara:
        "By that afternoon, you are completely engrossed in work, until a direct message over the company messaging service startles you back to the land of the living."

        if w03d04_s03_up_for_sierra:
            call sound_message from _call_sound_message
            if sierra_calls_you_by_first_name:
                sier "{font=fonts/Inconsolata-Regular.ttf}yo [player_name] u their?{/font}"
            else:
                sier "{font=fonts/Inconsolata-Regular.ttf}yo [sierra_adr_pc_as] u their?{/font}"
            call sound_message from _call_sound_message_1
            sier "{font=fonts/Inconsolata-Regular.ttf}Meat @ copir plz. bring ur :eggplant:{/font}"
            call sound_message from _call_sound_message_2
            sier "{font=fonts/Inconsolata-Regular.ttf}wtf!!! they blocked eggplant emoji lame.{/font}"
        else:

            call sound_message from _call_sound_message_3
            if w04d01_s05_agree_to_caper:
                zara "{font=fonts/Inconsolata-Regular.ttf}[player_name], I hope you haven't forgotten your side of our little bargain?{/font}"
            else:
                zara "{font=fonts/Inconsolata-Regular.ttf}[player_name], I hope you're still up for that favor your promised us?{/font}"

            call sound_message from _call_sound_message_4
            zara "{font=fonts/Inconsolata-Regular.ttf}Please meet us at the copier in 10 mins.{/font}"

        "You key in your reply."

        call music_fade_slow from _call_music_fade_slow_296
        pc "{font=fonts/Inconsolata-Regular.ttf}I'll be there.{/font}"
    else:

        call music_fade_slow from _call_music_fade_slow_297
        "You spend the day working on your assigned tasks, and getting annoyed by the erratic behavior of your mouse."


    scene black
    with fade

    pause 2.0

    return
