label w02d07_s03:

    scene backdrop car daytime:
        subpixel True
        ypos -0.25 yanchor 0.0 zoom 1.25
        ease 14.0 zoom 1
    show denise_pd car afternoon pleated sad:
        subpixel True
        xalign 0.75 yalign 0.45 zoom 1.5
        ease 14.0 zoom 1 yalign 0.15
    with fade

    pause 3.0

    pc "Do you need anything else while we're at the store?"

    show denise_pd car afternoon pleated brittlesmile
    with dissolve
    deni "I'll see when we're there."

    show denise_pd car afternoon pleated talk
    with dissolve
    deni "For now, just some rolls."

    default w02d07_s03_asked_about_macy = False
    menu:
        "[abgreen]Ask about [macy_name].":
            $ w02d07_s03_asked_about_macy = True
            pc "Did your [macy_rel_to_denise] get out of bed at all, today?"

            show denise_pd car afternoon pleated sad
            with dissolve
            deni "I think she just went to pee and then dove back into bed."

            show denise_pd car afternoon pleated talk
            with dissolve
            deni "She mumbled something about a hangover."
            pc "Is that so?"

            show denise_pd car afternoon pleated unhappy
            with dissolve
            deni_thought "I won't say she looked like she was just making excuses..."

            show denise_pd car afternoon pleated brittlesmile
            with dissolve
            deni_thought "I don't want to make him feel worse."
        "Don't.":

            $ w02d07_s03_asked_about_macy = False
            pc "..."

    show denise_pd car afternoon pleated sad
    with dissolve
    deni "..."

    show denise_pd car afternoon pleated unhappy
    with dissolve
    if w02d07_s01_confessed:
        deni_thought "I need to find out more about yesterday..."
    else:
        deni_thought "I need to find out what happened yesterday..."

    show denise_pd car afternoon pleated brittlesmile
    with dissolve
    deni "..."

    if not w02d07_s01_confessed:
        show denise_pd car afternoon pleated unhappy:
            ease 45.0 zoom 1.2 xalign 0.7 yalign 0.35
        with dissolve
        deni "[denise_adr_pc_as_cap], won't you tell me what happened with you and [macy_name] yesterday?"

        menu:
            "[abgreen]Confess.":
                $ w02d07_s01_confessed = True
                pc "I kissed her."
                pc "Inappropriately."

                show denise_pd car afternoon pleated sad
                with dissolve
                deni "Oh."

                show denise_pd car afternoon pleated talk
                with dissolve
                deni "What made it inappropriate?"

                menu:
                    "[abgreen]'I forced myself on her.'":
                        $ w02d07_s01_forced_her = True
                        pc "I forced myself upon her."

                        if w02d07_s01_she_overreacted:
                            pc "I couldn't help it, I wasn't thinking straight."
                        else:
                            pc "I wasn't thinking straight, but that is no excuse."

                        show denise_pd car afternoon pleated unhappy
                        with dissolve
                        deni "What do you mean by not thinking straight?"
                        pc "For a while, I... wasn't sure what was real and what was not."

                        show denise_pd car afternoon pleated talk
                        with dissolve
                        deni "Then, how do you know?"

                        show denise_pd car afternoon pleated unhappy
                        with dissolve
                        deni "It looked to me like you were both... having fun."
                        pc "What do you mean, 'it looked like'?"

                        show denise_pd car afternoon pleated sad
                        with dissolve
                        deni "Eh... I mean you said you had fun and you were dancing earlier."

                        show denise_pd car afternoon pleated talk
                        with dissolve
                        deni "And you agreed that for that night, you would be friends instead of [pc_rel_to_macy] and [macy_rel_to_pc]."

                        show denise_pd car afternoon pleated unhappy
                        with dissolve
                        deni "What if she wanted to kiss you?"
                        pc "..."
                        pc "A [pc_rel_to_macy] shouldn't kiss his [macy_rel_to_pc] like that, angel."
                    "'A [macy_rel_to_pc] shouldn't be kissed like that.'":

                        $ w02d07_s01_forced_her = False

                        pc "A [macy_rel_to_pc] shouldn't be kissed by her [pc_rel_to_macy] like {i}that{/i}, angel."
                        deni "..."

                show denise_pd car afternoon pleated brittlesmile
                with dissolve
                deni "Why not?"

                show denise_pd car afternoon pleated talk
                with dissolve
                deni "If the [macy_rel_to_pc] likes it, too?"

                pc "I..."
                pc "I don't think that's what happened, angel."
                pc "After all, [macy_name] did get very upset with me after it happened."
                pc "..."
            "Don't.":

                pc "I..."
                pc "No, I'd rather not."

                show denise_pd car afternoon pleated brittlesmile
                with dissolve
                deni "Oh..."

        show denise_pd car afternoon pleated sad
        with dissolve
        deni "But... you did have fun last night, right?"
    else:

        show denise_pd car afternoon pleated unhappy:
            ease 15.0 zoom 1.2 xalign 0.7 yalign 0.35
        with dissolve
        deni "[denise_adr_pc_as_cap]...?"

        show denise_pd car afternoon pleated talk
        with dissolve
        deni "When you and [macy_name] went out last night."

        show denise_pd car afternoon pleated sad
        with dissolve
        deni "You did have fun, right?"

    show denise_pd car afternoon pleated brittlesmile
    with dissolve
    deni "Before... you know... she punched you in the face."
    pc "Yeah, we did have fun before."

    show denise_pd car afternoon pleated talk
    with dissolve
    deni "So... that's a good thing, right?"

    show denise_pd car afternoon pleated sad:
        ease 35.0 zoom 1.0
    with dissolve
    deni "If you can make up for what happened at the end, that is."

    menu:
        "'Not sure I can.'":
            pc "I'm not sure I can do that, angel."
            pc "What I did was pretty bad."
        "[abgreen]'I'll try.'":

            pc "I'll do my best."
            pc "But what I did was pretty bad."

    show denise_pd car afternoon pleated unhappy
    with dissolve
    deni "But you have to try, [denise_adr_pc_as]!"

    show denise_pd car afternoon pleated brittlesmile
    with dissolve
    deni "Promise me you will."

    default w02d07_s03_promised = False
    menu:
        "[abgreen]Promise.":
            $ w02d07_s03_promised = True
            pc "I promise, angel."

            show denise_pd car afternoon pleated happy
            with dissolve
            deni "Thank you, [denise_adr_pc_as]!"
        "Don't.":

            $ w02d07_s03_promised = False
            pc "..."

            show denise_pd car afternoon pleated unhappy
            with dissolve
            deni "[denise_adr_pc_as_cap]...?"

            show denise_pd car afternoon pleated brittlesmile
            with dissolve
            deni "..."
            call denise_add_angst from _call_denise_add_angst_6

    scene black
    with fade

    pause 2.0

    return
