label w03d06_s02:

    scene mall_bg clothestore_interior:
        subpixel True
        xalign 0.5 yalign 0.3 zoom 1.05
        ease 9.3 zoom 1.0
    show denise_pd mall_clothesstore smile:
        subpixel True
        xalign 0.5 yalign 0.3 zoom 1.1
        ease 9.3 zoom 1.0
    with fade

    deni "Alright then."

    show mall_bg clothestore_interior
    show denise_pd mall_clothesstore happy
    with dissolve
    deni "Just wait here, [denise_adr_pc_as]."

    show mall_bg clothestore_interior
    show denise_pd mall_clothesstore smile
    with dissolve
    deni "I'll go and find what I need. I won't be long."

    call music_fade_slow from _call_music_fade_slow_364

    show mall_bg clothestore_interior
    show denise_pd mall_clothesstore smile:
        0.5
        easeout 4.1 xpos 0.0 xanchor 1.0
    with dissolve
    "As your [denise_rel_to_pc] moves off, you sigh and look around the store."

    "After a minute or so, the click-click-click sound of six inch stilettos jabbing at the tile floor draws your attention to the tall woman approaching you."

    call theme_shop_assistant from _call_theme_shop_assistant
    scene mall_bg clothestore_interior vickyvignette:
        subpixel True
        zoom 1.025 xalign 0.4 yalign 1.0
        ease 14.4 zoom 1.0 yalign 0.0
    show vicky_pd mall_clothesstore vignette:
        subpixel True
        zoom 1.1 xalign 0.4 yalign 1.0
        ease 14.4 zoom 1.0 yalign 0.0
    with fade

    pause 12.1
    "She waves at someone, mouthing the words 'I'll be right with you', but you're unsure who it's directed at as you and your [denise_rel_to_pc] are the only customers currently in the store."

    scene mall_bg clothestore_interior:
        subpixel True
        xalign 0.5 yalign 0.1
        ease 24.6 zoom 1.1
    show vicky_pd mall_clothesstore smile:
        subpixel True
        xalign 0.5 yalign 0.1
        ease 24.6 zoom 1.2
    with fade
    vick "Why, heeelloooo!"

    show mall_bg clothestore_interior
    show vicky_pd mall_clothesstore laugh
    with dissolve
    vick "Sooo nice to see a new face around here."

    pc "Eh..."

    show mall_bg clothestore_interior
    show vicky_pd mall_clothesstore concered
    with dissolve
    vick "I'm the manager of this store."

    $ vicky_name = "Vicky"

    show mall_bg clothestore_interior
    show vicky_pd mall_clothesstore introduce
    with dissolve
    vick "My name is {i}miss{/i} Vosem, but {i}you{/i} may call me [vicky_name]."
    "The well practiced words roll smoothly out of her mouth as she sticks a limp hand in your direction."

    default w03d06_s02_friendly = False
    menu:
        "Be polite.":
            $ w03d06_s02_friendly = False
            pc "Eh, yes. Nice to meet you."
        "[abgreen]Be friendly.":

            $ w03d06_s02_friendly = True
            pc "Nice to meet you, [vicky_name]. I'm [player_name]."

    show mall_bg clothestore_interior
    show vicky_pd mall_clothesstore introduce eyesclosed
    with dissolve
    "You reach for her hand and give it a tepid shake."
    "It feels a bit like grabbing a dead fish."

    show mall_bg clothestore_interior
    show vicky_pd mall_clothesstore introduce
    with dissolve
    vick "A pleasure, I'm sure."

    show mall_bg clothestore_interior
    show vicky_pd mall_clothesstore thinking
    with dissolve

    default w03d06_s02_look_familiar = False
    menu:
        "[abgreen]'You look familiar.'":
            $ w03d06_s02_look_familiar = True
            pc "I hope you don't mind me saying, you look terribly familiar."

            show mall_bg clothestore_interior:
                ease 27.9 zoom 1.0
            show vicky_pd mall_clothesstore smile:
                ease 27.9 zoom 1.0
            with dissolve
            vick "Why, thank you. I get that a lot."

            show mall_bg clothestore_interior
            show vicky_pd mall_clothesstore concered
            with dissolve
            vick "I've done quite a bit of modelling, so I wouldn't be surprised if you've seen my likeness in {i}any{/i} number of visual novels."

            default w03d06_s02_knew_avns = False
            menu:
                "[abgreen]'I play those a lot.'":
                    $ w03d06_s02_knew_avns = True
                    pc "I've played quite a few of those, I might have seen you there."
                "'Visual novels?'":
                    $ w03d06_s02_knew_avns = False
                    pc "Visual novels?"

            show mall_bg clothestore_interior
            show vicky_pd mall_clothesstore laugh
            with dissolve
            vick "Oh yes. And as you may have noticed, striking a natural and alluring pose is almost second nature to me."

            show mall_bg clothestore_interior
            show vicky_pd mall_clothesstore pose
            with dissolve
            vick "Ahahaha! See what I mean?"
            pc "Eh... yes?"

            show mall_bg clothestore_interior
            show vicky_pd mall_clothesstore laugh
            with dissolve
            vick "But that's quite enough about me."

            show mall_bg clothestore_interior
            show vicky_pd mall_clothesstore concered
            with dissolve
        "Say nothing.":

            $ w03d06_s02_look_familiar = False
            pc "..."

            show mall_bg clothestore_interior:
                ease 32.1 zoom 1.0
            show vicky_pd mall_clothesstore concered:
                ease 32.1 zoom 1.0
            with dissolve

    vick "So tell me, are you shopping for yourself today, or...?"
    pc "I'm here with my [denise_rel_to_pc], actually."

    show mall_bg clothestore_interior
    show vicky_pd mall_clothesstore laugh
    with dissolve
    vick "Oh how nice! We do get a lot of [pc_rel_to_denise]s coming in with their [denise_rel_to_pc]s."
    pc "You do?"

    show mall_bg clothestore_interior
    show vicky_pd mall_clothesstore thinking
    with dissolve
    if w03d06_s02_knew_avns:
        vick "Oh yes, you'd be surprised. Or maybe not, ahaha."
    else:
        vick "Oh yes, you'd be surprised."

    show mall_bg clothestore_interior
    show vicky_pd mall_clothesstore smile
    with dissolve
    vick "I'm really glad that so many people are still upholding [group_adr_as] values."
    pc "[group_adr_as_cap] values?"

    show mall_bg clothestore_interior
    show vicky_pd mall_clothesstore concered
    with dissolve
    vick "Absolutely!"

    show mall_bg clothestore_interior
    show vicky_pd mall_clothesstore laugh
    with dissolve
    vick "We also get a great deal of fine young men accompanying their [charlotte_rel_to_denise]s."
    pc "Really?"

    show mall_bg clothestore_interior
    show vicky_pd mall_clothesstore smile
    with dissolve
    vick "Yeah, mostly they come to help their [charlotte_rel_to_denise] buy some nice lingerie for a hot date together. So thoughtful."
    pc "Eh... what?"

    show mall_bg clothestore_interior
    show vicky_pd mall_clothesstore laugh
    with dissolve
    vick "Oh yes! But we get all sorts."

    show mall_bg clothestore_interior:
        ease 42.1 zoom 1.1
    show vicky_pd mall_clothesstore smile:
        ease 42.1 zoom 1.2
    with dissolve
    vick "Just the other day, we had a boy come in with his [denise_rel_to_macy], to buy her some swimwear."

    show mall_bg clothestore_interior
    show vicky_pd mall_clothesstore thinking
    with dissolve
    vick "Why, I could have sworn I've seen him do the exact same thing for his [macy_rel_to_denise] some weeks earlier."

    show mall_bg clothestore_interior
    show vicky_pd mall_clothesstore laugh
    with dissolve
    vick "They even had a little competition with her friend, to see who could pull off the skimpiest outfit."

    show mall_bg clothestore_interior
    show vicky_pd mall_clothesstore smile
    with dissolve
    vick "Such a nice young man."

    show mall_bg clothestore_interior
    show vicky_pd mall_clothesstore thinking
    with dissolve
    vick "And of course, we get the occasional fine gentlemen such as yourself..."

    show mall_bg clothestore_interior
    show vicky_pd mall_clothesstore smile
    with dissolve
    vick "...coming in to dazzle their [denise_rel_to_pc] with a beautiful, form-fitting dress for a wild night on the town together."

    show mall_bg clothestore_interior
    show vicky_pd mall_clothesstore concered
    with dissolve
    vick "And of course picking up the bill."

    show mall_bg clothestore_interior
    show vicky_pd mall_clothesstore laugh
    with dissolve
    vick "Because nothing drops a pair of panties quicker than paying for them, I always say. Ahahaha!"
    pc "Er..."

    show mall_bg clothestore_interior
    show vicky_pd mall_clothesstore smile
    with dissolve
    vick "Am I right?"
    pc "Actually..."

    show mall_bg clothestore_interior:
        ease 18.1 zoom 1.0
    show vicky_pd mall_clothesstore thinking:
        ease 18.1 zoom 1.0
    with dissolve
    vick "Say, has your [denise_rel_to_pc] already gone into the dressing rooms by chance?"

    show mall_bg clothestore_interior
    show vicky_pd mall_clothesstore concered
    with dissolve
    vick "If you want to go have a peek, that's no problem. At. All."

    pc "Wait, what?!"

    show mall_bg clothestore_interior
    show vicky_pd mall_clothesstore laugh
    with dissolve
    vick "Oh yes! I encourage it!"

    show mall_bg clothestore_interior
    show vicky_pd mall_clothesstore smile
    with dissolve
    vick "A little unbidden peek now and then does wonders for the relationship between [group_adr_as] members, don't you think?"

    default w03d06_s02_inappropriate = False
    menu:
        "[abgreen]'You think I should?'" if not denise_locked_out:
            $ w03d06_s02_inappropriate = False
            pc "Do you really think I should?"

            show mall_bg clothestore_interior
            show vicky_pd mall_clothesstore thinking
            with dissolve
            vick "Oh, but I insist. Just follow me right this..."

            show mall_bg clothestore_interior:
                0.5
                parallel:
                    ease 2.1 yalign 0.3
            show vicky_pd mall_clothesstore thinking:
                0.5
                parallel:
                    ease 2.1 yalign 0.3
                parallel:
                    0.8
                    ease 1.9 xalign 0.85
                    ease (22.1-0.8-1.9) xalign 0.95
            show denise_pd mall_clothesstore happy:
                subpixel True
                yalign 0.1 xpos 0.0 xanchor 1.0
                0.5
                parallel:
                    ease 2.1 yalign 0.3
                parallel:
                    easein 2.1 xalign 0.15
                    ease (22.1-2.1) xalign 0.05
            with dissolve
        "'Are you crazy?'":

            $ w03d06_s02_inappropriate = True
            pc "Are you crazy? I hardly think that's..."

            show mall_bg clothestore_interior:
                0.5
                parallel:
                    ease 9.1 yalign 0.3
                parallel:
                    1.1
                    ease 22.1 zoom 1.1
            show vicky_pd mall_clothesstore smile:
                0.5
                parallel:
                    ease 9.1 yalign 0.3
                parallel:
                    0.8
                    ease 1.9 xalign 0.85
                    ease (22.1-0.8-1.9) xalign 0.95
                parallel:
                    1.1
                    ease 22.1 zoom 1.2
            show denise_pd mall_clothesstore happy:
                subpixel True
                yalign 0.1 xpos 0.0 xanchor 1.0
                0.5
                parallel:
                    ease 9.1 yalign 0.3
                parallel:
                    easein 2.1 xalign 0.15
                    ease (22.1-2.1) xalign 0.05
                parallel:
                    1.1
                    ease 22.1 zoom 1.2
            with dissolve

    deni "Hi [denise_adr_pc_as_cap]! What's going on?"

    pc "Eh... nothing, angel."

    show mall_bg clothestore_interior
    show vicky_pd mall_clothesstore laugh
    show denise_pd mall_clothesstore happy
    with dissolve
    vick "So this is your [denise_rel_to_pc]? Such a lovely young girl!"

    show mall_bg clothestore_interior
    show vicky_pd mall_clothesstore laugh
    show denise_pd mall_clothesstore neutral
    with dissolve
    deni "Uh... thank you?"

    show mall_bg clothestore_interior
    show vicky_pd mall_clothesstore laugh
    show denise_pd mall_clothesstore smile
    with dissolve
    deni "[denise_adr_pc_as_cap]? I'm all done here."

    show mall_bg clothestore_interior
    show vicky_pd mall_clothesstore thinking
    show denise_pd mall_clothesstore smile
    with dissolve

    if denise_locked_out:
        vick "Oh well, maybe next time?"
    else:
        vick "Remember, nothing drops them faster..."

    show mall_bg clothestore_interior
    show vicky_pd mall_clothesstore thinking
    show denise_pd mall_clothesstore unhappy
    with dissolve
    deni "Huh?"

    if denise_locked_out:
        jump w03d06_s02_paid_already

    default w03d06_s02_offer_to_pay = False
    menu:
        "[abgreen]Offer to pay.":
            $ w03d06_s02_offer_to_pay = True
            pc "Let me pay that for you, angel."

            show mall_bg clothestore_interior
            show vicky_pd mall_clothesstore thinking
            show denise_pd mall_clothesstore neutral
            with dissolve
            deni "That's okay, [macy_name] gave me a bit of cash and I already paid with the girl at the counter."

            show mall_bg clothestore_interior
            show vicky_pd mall_clothesstore thinking
            show denise_pd mall_clothesstore happy
            with dissolve
            deni "Besides, everything was on sale, so it didn't cost much."
        "Say nothing.":

            label w03d06_s02_paid_already:
            $ w03d06_s02_offer_to_pay = False

            pc "..."

            show mall_bg clothestore_interior
            show vicky_pd mall_clothesstore thinking
            show denise_pd mall_clothesstore happy
            with dissolve
            deni "I've paid already with the girl at the counter."

    show mall_bg clothestore_interior:
        0.5
        ease 19.1 zoom 1.0
    show vicky_pd mall_clothesstore thinking:
        0.5
        ease 19.1 zoom 1.0 xalign 0.85
    show denise_pd mall_clothesstore smile:
        0.5
        ease 19.1 zoom 1.0 xalign 0.15
    with dissolve
    deni "Shall we go?"

    show mall_bg clothestore_interior
    show vicky_pd mall_clothesstore smile
    show denise_pd mall_clothesstore smile
    with dissolve
    vick "Oh, please do come again!"

    show mall_bg clothestore_interior
    show vicky_pd mall_clothesstore laugh
    show denise_pd mall_clothesstore smile
    with dissolve
    vick "I have a shipment of sexy school uniforms coming next week, and I'm sure your [denise_adr_pc_as] would love to see you try those on!"

    show mall_bg clothestore_interior
    show vicky_pd mall_clothesstore laugh
    show denise_pd mall_clothesstore unhappy
    with dissolve
    deni "Eh... Please, can we go [denise_adr_pc_as]?"
    if w03d06_s02_inappropriate:
        pc "I think we should, angel."
    else:
        pc "Ah... of course, angel."

    show mall_bg clothestore_interior
    show vicky_pd mall_clothesstore laugh
    show denise_pd mall_clothesstore neutral
    with dissolve
    deni "Carry the bag for me? It's on the counter."

    show mall_bg clothestore_interior
    show vicky_pd mall_clothesstore laugh
    show denise_pd mall_clothesstore neutral:
        0.5
        easeout 2.1 xanchor 1.0 xpos 0.0
    with dissolve
    pc "Yeah."
    "You pick up the bag and follow your [denise_rel_to_pc] out."

    show mall_bg clothestore_interior:
        0.5
        parallel:
            ease 12.3 zoom 1.1
        parallel:
            ease 4.1 yalign 0.1
    show vicky_pd mall_clothesstore smile:
        0.5
        parallel:
            0.3
            ease 7.1 xalign 0.5
        parallel:
            ease 12.3 zoom 1.2
        parallel:
            ease 7.1 yalign 0.1
    with dissolve
    vick "Thank you for shopping at Thigh GAP! Have a nice day now!"

    call music_fade_slow from _call_music_fade_slow_365

    show mall_bg clothestore_interior
    show vicky_pd mall_clothesstore thinking
    with dissolve
    vick_thought "Such a nice [group_adr_as]."

    scene black
    with fade
    pause 2.0

    return
