label w03d02_s05:

    "After you pick up [macy_name], you drive back home."

    call theme_macy from _call_theme_macy_17

    scene backdrop car nighttime
    show macy_pd car nighttime thoughtful:
        subpixel True
        xalign 0.7 yalign 0.07 zoom 1.2
        ease 58.0 zoom 1.0
    with fade
    macy "So..."

    pc "So?"

    show macy_pd car nighttime neutral
    with dissolve
    macy "Listen."

    show macy_pd car nighttime thoughtful
    with dissolve
    macy "I..."

    show macy_pd car nighttime frown
    with dissolve
    macy "I'm still pissed at you."

    show macy_pd car nighttime thoughtful
    with dissolve
    macy "But I want to call a truce."

    show macy_pd car nighttime sad
    with dissolve
    macy "For [denise_name], you see."
    pc "Yeah, for [denise_name]."

    call macy_remove_anger from _call_macy_remove_anger_4

    show macy_pd car nighttime thoughtful
    with dissolve
    macy "She really doesn't like it when we're mad with each other."
    pc "No. No, she doesn't."

    show macy_pd car nighttime sad
    with dissolve
    macy "But she's really happy when we do get along."

    default w03d02_s05_me_too = False
    menu:
        "[abgreen]'Me too.'":
            $ w03d02_s05_me_too = True
            pc "I'm really happy when we do, too."

            show macy_pd car nighttime neutral
            with dissolve
            macy "We..."

            show macy_pd car nighttime smile
            with dissolve
            macy "We did have a pretty good time last Saturday, didn't we?"
            pc "Yeah, I really enjoyed that."
            pc "Right until..."

            show macy_pd car nighttime thoughtful
            with dissolve
            macy "Let's... not bring that up."
            pc "Probably shouldn't."

            show macy_pd car nighttime neutral
            with dissolve
            macy "Probably."
            call macy_remove_anger from _call_macy_remove_anger_5
        "Say nothing.":

            $ w03d02_s05_me_too = False
            pc "..."

    if w02d07_s04_picked_up_candy and not w03d01_s07_offered_candy:
        default w03d02_s05_offered_candy = False
        menu:
            "[abgreen]Offer the candy.":
                $ w03d02_s05_offered_candy = True
                pc "There's..."
                pc "There's some candy in the glove box."
                pc "It's the good stuff."

                if w03d02_s05_me_too:
                    show macy_pd car nighttime smile
                    with dissolve
                else:
                    show macy_pd car nighttime neutral
                    with dissolve
                macy "Really?"

                show macy_pd car nighttime candy_hold
                with dissolve
                "She grabs the box, tears it open, and pours some candy out into her hand."

                show macy_pd car nighttime candy_eat
                with dissolve
                macy "I love these."

                show macy_pd car nighttime candy_eat eyesclosed
                with dissolve
                macy "Mwank wou!"

                if macy_love < 6:
                    call macy_add_love from _call_macy_add_love_6

                pc "You're welcome."
                show macy_pd car nighttime candy_angry
                with dissolve
                macy "But don't you go thinking one lousy box of candy makes everything right!"

                show macy_pd car nighttime candy_hold
                with dissolve
                macy "Still mad at you."

                show macy_pd car nighttime candy_eat
                with dissolve
                macy "Om nom nom."

                pc "Fair 'nuf."
            "Don't.":

                $ w03d02_s05_offered_candy = False
                pause 0.0

    show macy_pd car nighttime thoughtful:
        ease 1.0 zoom 1.01
        parallel:
            choice:
                ease 0.1 xalign 0.0
            choice:
                ease 0.9 xalign 0.0
            choice:
                ease 4.1 xalign 0.0
            pass
            choice:
                ease 0.1 xalign 1.0
            choice:
                ease 0.9 xalign 1.0
            choice:
                ease 4.1 xalign 1.0
            repeat
        parallel:
            choice:
                ease 0.1 yalign 0.8
            choice:
                ease 0.9 yalign 0.8
            choice:
                ease 4.1 yalign 0.8
            pass
            choice:
                ease 0.1 yalign 0.6
            choice:
                ease 0.9 yalign 0.6
            choice:
                ease 4.1 yalign 0.6
            repeat
    with dissolve

    "Without much of a warning, the car starts sputtering."

    default w03d02_s05_curse = False
    menu:
        "[abgreen]Curse.":
            $ w03d02_s05_curse = True
            pc "Ah fuck!"

            show macy_pd car nighttime shock
            with dissolve
            macy "..."
        "Don't.":

            $ w03d02_s05_curse = False

            show macy_pd car nighttime shock
            with dissolve
            macy "Ah fuck!"

            default w03d02_s05_language = False
            menu:
                "'Language.'":
                    $ w03d02_s05_language = True
                    pc "Language, princess."

                    show macy_pd car nighttime eyeroll
                    with dissolve
                    macy "Urgh."
                "[abgreen]Say nothing.":

                    $ w03d02_s05_language = False
                    pc "..."

    show macy_pd car nighttime thoughtful
    with dissolve
    macy "What's wrong with it?"

    if w03d02_s05_curse:
        pc "Damned if I know. I'll just pull off here."
    else:
        pc "Darned if I know. I'll just pull off here."

    call music_fade_slow from _call_music_fade_slow_199

    scene black
    with fade

    pause 2.0

    return
