label w03d04_s06:

    scene setpiece_diner night macy standoutfront neutral:
        subpixel True
        xalign 0.3 yalign 0.2 zoom 1.0
        ease 9.1 zoom 1.3
    with fade

    call theme_macy_relaxed from _call_theme_macy_relaxed_1

    "You arrive just in time to pick your eldest [macy_rel_to_pc] up from work."

    scene backdrop car nighttime
    show macy_pd car nighttime thoughtful:
        subpixel True
        xalign 0.7 yalign 0.05 zoom 1.2
        ease 19.0 zoom 1.0
    with fade

    menu:
        "[abgreen]Ask about work.":
            pc "How was work today?"

            show macy_pd car nighttime neutral
            with dissolve
            macy "Eh..."

            show macy_pd car nighttime eyeroll
            with dissolve
            macy "Running my butt off."

            show macy_pd car nighttime shock
            with dissolve
            macy "Forcing a smile onto my face for assholes and creeps."

            show macy_pd car nighttime frown
            with dissolve
            macy "Get stuffed on the tip."

            show macy_pd car nighttime thoughtful
            with dissolve
            macy "The usual."
        "Don't.":

            pc "..."

    if denise_locked_out or macy_locked_out:
        jump w03d04_s06_scene_ends

    show macy_pd car nighttime neutral
    with dissolve
    macy "How was your evening?"
    pc "It was good. Your [denise_rel_to_macy] and me had a nice talk."

    show macy_pd car nighttime thoughtful
    with dissolve
    macy "That's good."

    menu:
        "[abgreen]Ask her about talking girl stuff.":
            pc "It must have been hard for you."
            pc "I mean, getting through high school without an older woman around to talk to."

            show macy_pd car nighttime sad:
                ease 44.7 zoom 1.2
            with dissolve
            macy "Talk to about what?"
            pc "Like, boys and... things."
            pc "Girl stuff."

            show macy_pd car nighttime neutral
            with dissolve
            macy "Oh, that."

            show macy_pd car nighttime thoughtful
            with dissolve
            macy "Meh. That's okay."

            show macy_pd car nighttime neutral
            with dissolve
            macy "I sorta figured it out as I went along."

            show macy_pd car nighttime eyeroll
            with dissolve
            macy "And in the process I also figured out that this high school boyfriend-girlfriend thing isn't for me."

            pc "Really?"
            pc "You never had a boyfriend?"
            pc "Or girlfriend? I'm not judging."

            show macy_pd car nighttime smile
            with dissolve
            macy "Hehehe. Now there's a thought..."

            show macy_pd car nighttime thoughtful
            with dissolve
            macy "But no. Not really."

            show macy_pd car nighttime shock
            with dissolve
            macy "There briefly was this one guy. Urgh!"
            pc "Not Mr. Right, I take it?"

            show macy_pd car nighttime smile
            with dissolve
            macy "Please."

            if macy_love >= 5:

                show macy_pd car nighttime neutral
                with dissolve
                macy "I'll tell you one thing."

                show macy_pd car nighttime thoughtful
                with dissolve
                macy "You're ten times the kisser he ever was."

                with hpunch
                pc "!"

                show macy_pd car nighttime smile
                with dissolve
                macy "Ohmygod! Are you blushing right now? You totally are! You're blushing. Hehehe."

            pc "..."

            show macy_pd car nighttime neutral
            with dissolve
            macy "..."
            "You get the feeling there's more she wants to say, but she changes the subject before you can ask."
        "Don't.":

            pc "..."

    label w03d04_s06_scene_ends:

    show macy_pd car nighttime smile:
        ease 12.3 zoom 1.0
    with dissolve
    macy "So how about those Tardigrades, eh? If they keep this up, they could be the next champions."

    default w03d04_s06_not_into_sports = False
    menu:
        "[abgreen]'You think so?'":
            $ w03d04_s06_not_into_sports = False
            pc "Do you really think so?"
            pc "The Rotifers still have a shot, if they win the next match."

            show macy_pd car nighttime eyeroll
            with dissolve
            macy "Eh, Rotifers shmotifers. The Tardigrades will tear them apart."
            pc "We'll see."

            show macy_pd car nighttime smile
            with dissolve
            "You spend the rest of the drive home discussing the goings-on in the current sports season with your [macy_rel_to_pc]."
        "'Not really into sports.'":

            $ w03d04_s06_not_into_sports = True
            pc "I'm not really into sports."

            show macy_pd car nighttime neutral
            with dissolve
            macy "Now's a good time to start. This season's been super exciting."

            show macy_pd car nighttime smile
            with dissolve
            macy "You see, if the Rotifers win their next match, it's still open, but if they don't..."
            "You spend the rest of the drive home listening to your [macy_rel_to_pc] harping on about the goings-on in the current sports season."

    call music_fade_slow from _call_music_fade_slow_263

    scene black
    with fade
    "Soon, you arrive home."

    pause 2.0

    return
