label w04d02_s03:

    if not(denise_locked_out or macy_locked_out):
        call theme_pc from _call_theme_pc_18

    scene setpiece office midday desk:
        subpixel True
        xalign 0.5 yalign 0.6 zoom 1.05
        ease 12.7 zoom 1.00
    with fade

    "You arrive at the office, and get to work."
    "After a couple of hours, you receive a call from school."

    scene setpiece office midday photoondesk:
        subpixel True
        xalign 0.75 yalign 0.3
        ease 21.3 zoom 1.1
    with fade
    "They inform you that they're pleased with the work [denise_name] submitted and the progress she is making..."
    "...and they want to schedule an appointment with you and her, somewhere in the coming weeks."
    "You promise to talk it over with your [denise_rel_to_pc] and get back to them."

    if denise_locked_out or macy_locked_out:

        call music_fade_slow from _call_music_fade_slow_300

        scene black
        with fade

        pause 2.0

        return

    scene setpiece office midday building:
        subpixel True
        xalign 0.4 yalign 0.9 zoom 1.1
        0.5
        ease 22.3 zoom 1.0
    with fade
    "Lunchtime comes, and you discover your lunch consists of chunks of several types of citrusy fruits and a few sandwiches, none of which have any meat in them."
    "It's actually quite tasty."
    "You pick up a beverage on the way back to your desk."

    default w04d02_s03_picked_up_decaf = False
    default w04d02_s03_picked_up_juice = False
    menu:
        "Pick up herbal tea." if pc_coffee == "tea":
            $ w04d02_s03_picked_up_decaf = True
            call w04d02_s03_show_desk from _call_w04d02_s03_show_desk
            "You pick up some herbal tea like your [denise_rel_to_pc] asked you to, and get back to work."

        "[abgreen]Pick up decaf." if pc_coffee != "tea":
            $ w04d02_s03_picked_up_decaf = True
            call w04d02_s03_show_desk from _call_w04d02_s03_show_desk_1
            "You pick up some decaf like your [denise_rel_to_pc] asked you to, and get back to work."
        "Pick up juice.":

            $ w04d02_s03_picked_up_decaf = True
            $ w04d02_s03_picked_up_juice = True
            call w04d02_s03_show_desk from _call_w04d02_s03_show_desk_2
            "You pull some non-dairy fruit drink from a vending machine like your [denise_rel_to_pc] asked you to, and get back to work."

        "Pick up the caffeinated stuff." if not w04d02_s02_liked_decaf:
            $ w04d02_s03_picked_up_decaf = False
            call w04d02_s03_show_desk from _call_w04d02_s03_show_desk_3
            "You pick up some regular, caffeinated [pc_coffee] in spite of what your [denise_rel_to_pc] asked you to do, before getting back to work."

    return

label w04d02_s03_show_desk:
    scene setpiece office midday desk:
        subpixel True
        xalign 0.5 yalign 0.6 zoom 1.0
        ease 12.7 zoom 1.05
    with fade
    return
