label w01d05_s03:
    if denise_have_coffee_ritual:

        scene kitchen_bg morning
        show denise_pd kitchen morning nightwear potter neutral:
            subpixel True
            xpos 1.0 xanchor 0.4
            ease 0.5 xanchor 0.5
        with fade
        pause 0.5

        show denise_pd kitchen morning nightwear holdcoffee:
            xpos 1.0 xanchor 0.5
            0.5
            subpixel True
            0.5
            ease 2.5 xpos 0.5 xanchor 0.5
        with dissolve
        "Before leaving for work, you stop by the kitchen."

        show denise_pd kitchen morning nightwear givecoffee
        with dissolve
        deni "Here [denise_adr_pc_as], your [pc_coffee]."
        pc "Thank you, angel."

        if denise_love >= 7:

            show denise_pd kitchen morning nightwear neutral
            with dissolve
            deni "Can I...?"

            show denise_pd kitchen morning nightwear happy
            with dissolve
            deni "Can I give you a hug?"
            pc "Sure, angel."

            show denise_pd kitchen morning nightwear unhappy
            with dissolve
            deni "Won't it hurt?"
            pc "Don't be silly. Come here!"

            show denise_pd kitchen morning nightwear hug
            with dissolve
            "She gingerly puts her arms around you, and you hug her back with your free arm."

            show denise_pd kitchen morning nightwear peck
            with dissolve
            pause 0.3
            show denise_pd kitchen morning nightwear hug
            with dissolve

            deni "Be safe, please..."
            menu:
                "[abgreen]'Don't worry.'":
                    pc "Don't worry about it."
                    show denise_pd kitchen morning nightwear unhappy
                    with dissolve
                    deni "I can't help it, it's what I do."
                    pc "I'll be careful."
                "'I always do.'":

                    pc "You know I always drive extra slow, just for you."
                    show denise_pd kitchen morning nightwear unhappy
                    with dissolve
                    deni "Statistically speaking, driving too slow is just as dangerous as driving too fast, you know."
                    pc "I'm kidding, angel. I'll be safe, I promise."

            show denise_pd kitchen morning nightwear smile
            with dissolve
            deni "Get out of here, [denise_adr_pc_as]. You'll be late!"
            pc "Right, see you later."

            call music_fade_slow from _call_music_fade_slow_92

            show denise_pd kitchen morning nightwear happy
            with dissolve
            deni "Love you."
            pc "Love you too, angel."

        scene black
        with fade
        "You quickly finish the [pc_coffee] and leave for work."
    else:

        call music_fade_slow from _call_music_fade_slow_93
        "You leave for work."

    pause 2.0
    return
