label w01d07_s05b:

    scene museum_bg gallery:
        subpixel True
        xalign 0.3 yalign 0.5 zoom 1.2
        ease 16 zoom 1.0 yalign 0.0
    show denise_pd museum afternoon exhibit2 talk:
        subpixel True
        xalign 0.3 yalign 0.5 zoom 1.4
        ease 16 zoom 1.0 yalign 0.0
    with fade
    deni "Wow!"

    show denise_pd museum afternoon exhibit2 happy
    with dissolve
    deni "This looks even more amazing in real life!"

    show denise_pd museum afternoon exhibit2 lookpainting
    with dissolve
    deni "You can see all the little blobs and smears of paint."

    pc "Indeed..."

    $ w01d07_s05_look_at_1st_painting = False
    $ w01d07_s05_look_at_2nd_painting = False
    $ w01d07_s05_look_at_3rd_painting = False
    $ w01d07_s05_look_at_4th_painting = False

    scene museum_bg paintings1:
        subpixel True
        xalign 0.0
        0.5
        parallel:
            ease 24.0 xalign 0.70
            ease 24.0 xalign 0.0
            repeat
    show denise_pd museum afternoon exhibit3 talk:
        subpixel True
        zoom (1080.0/1600.0) yalign 1.0 xalign 1.00
        0.5
        parallel:
            ease 24.0 xalign 0.0
            ease 24.0 xalign 1.0
            repeat
    with fade
    $ w01d07_s05_last_pose_lookpainting = "talk"

    label w01d07_s05_look_at_paintings:
    menu:
        "Look at the first painting." if not w01d07_s05_look_at_1st_painting:
            $ w01d07_s05_look_at_1st_painting = True
            show museum_bg paintings1:
                subpixel True
                0.5
                parallel:
                    ease 2.2 xalign 0.0 yalign 0.0
                parallel:
                    ease 5.1 zoom 1.4

            show denise_pd museum afternoon exhibit3 lastshown:
                subpixel True
                0.5
                parallel:
                    ease 5.1 zoom 1.2 xalign 0.9 yalign 1.0 yoffset 400

            pc "What do you think of the first painting?"
            if w01d07_s05_last_pose_lookpainting == 'happy':
                show denise_pd museum afternoon exhibit3 talk
                with dissolve
            else:
                show denise_pd museum afternoon exhibit3 happy
                with dissolve
            deni "The lighting and colors look real soft."

            show denise_pd museum afternoon exhibit3 touchhair
            with dissolve
            deni "The young girl to the right gives the man {i}such{/i} a longing look."

            show denise_pd museum afternoon exhibit3 shock
            with dissolve
            deni "And she's tugging at his clothes."
            pc "I think the man looks almost like an afterthought, sitting in the dark."
            pc "It's clear who the main attraction is."

            show denise_pd museum afternoon exhibit3 happy
            with dissolve
            deni "The girls, right?"

            show denise_pd museum afternoon exhibit3 talk
            with dissolve
            if w01d07_s05_look_at_3rd_painting:
                deni "These girls look very delicate and pretty, too."
            else:
                deni "They look very delicate and pretty."

            pc "They do, don't they?"

            show denise_pd museum afternoon exhibit3 happy
            with dissolve
            deni "Yeah..."

            if not(w01d07_s05_look_at_1st_painting and w01d07_s05_look_at_2nd_painting and w01d07_s05_look_at_3rd_painting and w01d07_s05_look_at_4th_painting):
                show museum_bg paintings1:
                    subpixel True
                    0.5
                    parallel:
                        ease 2.1 zoom 1.0
                    parallel:
                        ease 24.0 xalign 0.70
                        ease 24.0 xalign 0.0
                        repeat
                show denise_pd museum afternoon exhibit3 happy:
                    subpixel True
                    0.5
                    parallel:
                        ease 2.1 zoom (1080.0/1600.0) yalign 1.0 xalign 1.00 yoffset 0 xoffset 0
                    parallel:
                        ease 24.0 xalign 0.0
                        ease 24.0 xalign 1.0
                        repeat
                with dissolve

                $ w01d07_s05_last_pose_lookpainting = "happy"

                jump w01d07_s05_look_at_paintings

        "Look at the second painting." if not w01d07_s05_look_at_2nd_painting:
            $ w01d07_s05_look_at_2nd_painting = True
            show museum_bg paintings1:
                subpixel True
                0.5
                parallel:
                    ease 2.2 xalign 0.33 yalign 0.0
                parallel:
                    ease 5.1 zoom 1.4
            show denise_pd museum afternoon exhibit3 lastshown:
                subpixel True
                0.5
                parallel:
                    ease 5.1 zoom 1.2 xalign 1.0 yalign 1.0 yoffset 400

            pc "How about the second painting?"
            if w01d07_s05_last_pose_lookpainting == "talk":
                show denise_pd museum afternoon exhibit3 happy
                with dissolve
            else:
                show denise_pd museum afternoon exhibit3 talk
                with dissolve
            deni "It looks like a really cozy scene."

            show denise_pd museum afternoon exhibit3 touchhair
            with dissolve
            deni "They look very familiar and comfortable with each other. Like they're having a picnic."

            show denise_pd museum afternoon exhibit3 talk
            with dissolve
            if w01d07_s05_look_at_3rd_painting:
                deni "The girls look a lot alike as well. Do you think they're related, too?"
            else:
                deni "The girls look a lot alike. Do you think they're related?"

            pc "Could be."
            if w01d07_s05_look_at_4th_painting:
                pc "The undressed one sitting on the lap of that man is giving us another one of those smoldering looks."
            else:
                pc "The undressed one sitting on the lap of that man is giving us quite a smoldering look, isn't she?"

            show denise_pd museum afternoon exhibit3 shock
            with dissolve
            if w01d07_s05_look_at_3rd_painting or w01d07_s05_look_at_4th_painting:
                deni "She is."
                show denise_pd museum afternoon exhibit3 unhappy
                with dissolve
                deni "Is that another burning city in the background on the left?"
                show denise_pd museum afternoon exhibit3 touchhair
                with dissolve
                deni "Above those angels and that figure standing alone on the road. Like the one we saw on the other painting."
            else:
                deni "She is."
                show denise_pd museum afternoon exhibit3 unhappy
                with dissolve
                deni "Is that a burning city in the background on the left?"
                show denise_pd museum afternoon exhibit3 touchhair
                with dissolve
                deni "Above those angels and that figure standing alone on the road."
            pc "Yeah, I think so."

            if not(w01d07_s05_look_at_1st_painting and w01d07_s05_look_at_2nd_painting and w01d07_s05_look_at_3rd_painting and w01d07_s05_look_at_4th_painting):
                show museum_bg paintings1:
                    subpixel True
                    0.5
                    parallel:
                        ease 2.1 zoom 1.0
                    parallel:
                        ease 24.0 xalign 0.70
                        ease 24.0 xalign 0.0
                        repeat
                show denise_pd museum afternoon exhibit3 touchhair:
                    subpixel True
                    0.5
                    parallel:
                        ease 2.1 zoom (1080.0/1600.0) yalign 1.0 xalign 1.00 yoffset 0 xoffset 0
                    parallel:
                        ease 24.0 xalign 0.0
                        ease 24.0 xalign 1.0
                        repeat
                with dissolve

                $ w01d07_s05_last_pose_lookpainting = "touchhair"

                jump w01d07_s05_look_at_paintings

        "Look at the third painting." if not w01d07_s05_look_at_3rd_painting:
            $ w01d07_s05_look_at_3rd_painting = True
            show museum_bg paintings1:
                subpixel True
                0.5
                parallel:
                    ease 2.2 xalign 0.85 yalign 0.0
                parallel:
                    ease 5.1 zoom 1.4
            show denise_pd museum afternoon exhibit3 lastshown:
                subpixel True
                0.5
                parallel:
                    ease 5.1 zoom 1.2 xalign 0.85 yalign 1.0 yoffset 400

            deni "The third painting is really beautiful."

            if w01d07_s05_last_pose_lookpainting == "happy":
                show denise_pd museum afternoon exhibit3 talk
                with dissolve
            else:
                show denise_pd museum afternoon exhibit3 happy
                with dissolve

            deni "The colors are so vibrant."

            show denise_pd museum afternoon exhibit3 touchhair
            with dissolve
            if w01d07_s05_look_at_1st_painting:
                deni "And the girls look so soft and delicate in this one, too."
            else:
                deni "And the girls look so soft and delicate."

            show denise_pd museum afternoon exhibit3 talk
            with dissolve
            deni "They're not thin..."

            show denise_pd museum afternoon exhibit3 happy
            with dissolve
            deni "But they're young and beautiful..."

            default w01d07_s05_compliment_delicate = False
            menu:
                "[abgreen]'Just like you.'":
                    $ w01d07_s05_compliment_delicate = True
                    pc "Soft and delicate, young and beautiful."
                    pc "Just like my little angel right here."

                    show denise_pd museum afternoon exhibit3 unhappy
                    with dissolve
                    deni "Aww... you really think so?"
                    pc "Yeah."

                    show denise_pd museum afternoon exhibit3 happy
                    with dissolve
                    deni "That's so sweet. Thank you."
                    call denise_add_love from _call_denise_add_love_6
                "Say nothing.":

                    $ w01d07_s05_compliment_delicate = False
                    pc "..."

            if w01d07_s05_look_at_2nd_painting:
                pc "Again, the girls look quite similar. They could be sisters."
            else:
                pc "The girls look quite similar. They could be sisters."

            show denise_pd museum afternoon exhibit3 touchhair
            with dissolve
            deni "Yeah..."

            show denise_pd museum afternoon exhibit3 talk
            with dissolve
            deni "They have a particular expression."

            show denise_pd museum afternoon exhibit3 shock
            with dissolve
            deni "Almost as if they're secretly looking forward to doing something they've been planning together."

            menu:
                "[abgreen]'That's kinda specific.'":
                    pc "That's an oddly specific observation..."

                    show denise_pd museum afternoon exhibit3 happy
                    with dissolve
                    deni "I guess it takes having a sister-in-crime to recognize that look."
                "'I know that look well.'":

                    pc "Yeah. That's a look I'm all too familiar with..."

                    show denise_pd museum afternoon exhibit3 happy
                    with dissolve
                    deni "[denise_adr_pc_as_cap]!"


            show denise_pd museum afternoon exhibit3 shock
            with dissolve
            deni "The only thing is, the naked girl pouring wine has a really awkward position, don't you think?"
            pc "Yeah, now that you mention it."

            if w01d07_s05_look_at_2nd_painting or w01d07_s05_look_at_4th_painting:
                pc "I think it's to frame and bring attention to another one of those burning cities and lone figures."
            else:
                pc "I think it's to frame and bring attention to that burning city and lone figure."

            show denise_pd museum afternoon exhibit3 talk
            with dissolve
            deni "I think you're right."

            show denise_pd museum afternoon exhibit3 shock
            with dissolve
            deni "The figure looks like a statue don't you think?"

            if not(w01d07_s05_look_at_1st_painting and w01d07_s05_look_at_2nd_painting and w01d07_s05_look_at_3rd_painting and w01d07_s05_look_at_4th_painting):
                show museum_bg paintings1:
                    subpixel True
                    0.5
                    parallel:
                        ease 2.1 zoom 1.0
                    parallel:
                        ease 24.0 xalign 0.70
                        ease 24.0 xalign 0.0
                        repeat
                show denise_pd museum afternoon exhibit3 shock:
                    subpixel True
                    0.5
                    parallel:
                        ease 2.1 zoom (1080.0/1600.0) yalign 1.0 xalign 1.00 yoffset 0 xoffset 0
                    parallel:
                        ease 24.0 xalign 0.0
                        ease 24.0 xalign 1.0
                        repeat
                with dissolve

                $ w01d07_s05_last_pose_lookpainting = "shock"

                jump w01d07_s05_look_at_paintings

        "Look at the fourth painting." if not w01d07_s05_look_at_4th_painting:
            $ w01d07_s05_look_at_4th_painting = True
            show museum_bg paintings1:
                subpixel True
                0.5
                parallel:
                    ease 2.2 xalign 1.0 yalign 0.0
                parallel:
                    ease 5.1 zoom 1.8
            show denise_pd museum afternoon exhibit3 lastshown:
                subpixel True
                0.5
                parallel:
                    ease 5.1 zoom 1.2 xalign 1.00 xoffset 150 yalign 1.0 yoffset 400

            pc "What about that fourth painting, angel?"

            if w01d07_s05_last_pose_lookpainting == "touchhair":
                show denise_pd museum afternoon exhibit3 talk
                with dissolve
            else:
                show denise_pd museum afternoon exhibit3 touchhair
                with dissolve
            deni "It looks quite... fancy?"

            show denise_pd museum afternoon exhibit3 happy
            with dissolve
            deni "Beautiful fabrics and clothes, and expensive table wear."

            show denise_pd museum afternoon exhibit3 shock
            with dissolve
            deni "It looks a little out of place out in a... cave?"

            menu:
                "[abgreen]'Maybe it was commissioned?'":
                    pc "Maybe the painter was commissioned to depict some patron who wanted to show off his wealth?"

                    show denise_pd museum afternoon exhibit3 talk
                    with dissolve
                    deni "Maybe..."
                "'Maybe a self portait?'":

                    pc "Maybe it's a self portrait and the painter wants to look his best?"

                    show denise_pd museum afternoon exhibit3 talk
                    with dissolve
                    deni "Could be..."

            "You see some oysters prominently on display on the table."
            default w01d07_s05_commented_on_oysters = False
            menu:
                "Comment on the oysters.":
                    $ w01d07_s05_commented_on_oysters = True
                    pc "Looks like oysters are on the menu."
                    pc "It's not hard to guess what those people would have been doing later that night."

                    show denise_pd museum afternoon exhibit3 unhappy
                    with dissolve
                    deni "What's that, [denise_adr_pc_as]?"
                    pc "Well... the shape and texture of oysters is supposed to evoke the image of a certain part of the female anatomy."
                    pc_thought "Not to mention their briny flavour."

                    show denise_pd museum afternoon exhibit3 shock
                    with dissolve
                    deni "You mean..."

                    show denise_pd museum afternoon exhibit3 angry
                    with dissolve
                    deni "Really? Ew...!"
                "[abgreen]Don't.":

                    $ w01d07_s05_commented_on_oysters = False
                    pc "..."

            if w01d07_s05_look_at_2nd_painting:
                pc "That girl on the right is giving us another smoldering look."
            else:
                pc "That girl on the right is giving us a smoldering look."

            show denise_pd museum afternoon exhibit3 shock
            with dissolve
            deni "And the way they're both touching him is also quite..."
            pc "Suggestive?"

            show denise_pd museum afternoon exhibit3 touchhair
            with dissolve
            deni "Yeah."

            if w01d07_s05_look_at_2nd_painting or w01d07_s05_look_at_3rd_painting:
                pc "There's another lone statue or figure on the right, and I guess another burning city?"

                show denise_pd museum afternoon exhibit3 talk
                with dissolve
                deni "Yeah, I think you're right."
            else:
                pc "There's a peculiar statue on the right, and something's burning? Maybe some buildings or a city?"
                show denise_pd museum afternoon exhibit3 talk
                with dissolve
                deni "Yeah, could be. I can't quite make it out."

            if not(w01d07_s05_look_at_1st_painting and w01d07_s05_look_at_2nd_painting and w01d07_s05_look_at_3rd_painting and w01d07_s05_look_at_4th_painting):
                show museum_bg paintings1:
                    subpixel True
                    0.5
                    parallel:
                        ease 2.1 zoom 1.0
                    parallel:
                        ease 24.0 xalign 0.70
                        ease 24.0 xalign 0.0
                        repeat
                show denise_pd museum afternoon exhibit3 talk:
                    subpixel True
                    0.5
                    parallel:
                        ease 2.1 zoom (1080.0/1600.0) yalign 1.0 xalign 1.00 yoffset 0 xoffset 0
                    parallel:
                        ease 24.0 xalign 0.0
                        ease 24.0 xalign 1.0
                        repeat
                with dissolve

                $ w01d07_s05_last_pose_lookpainting = "talk"

                jump w01d07_s05_look_at_paintings

        "Move on." if w01d07_s05_look_at_1st_painting or w01d07_s05_look_at_2nd_painting or w01d07_s05_look_at_3rd_painting or w01d07_s05_look_at_4th_painting:
            pc_thought "I know I may be missing out on certain context if I rush this, but this is taking {b}forever{/b}..."
            pc "Let's talk about something else."

    return
