label w01d06_s04:

    call theme_pc from _call_theme_pc_3
    scene setpiece hallway morning bathroomdoor
    with fade

    "You hastily retreat into the hallway."
    pc_thought "Oh my god! That was pretty bad."

    default w01d06_s04_pc_tried_to_take_care = False
    menu:
        "Take care of your... situation.":
            $ w01d06_s04_pc_tried_to_take_care = True
            pc_thought "I've been walking around with a loaded gun."
            pc_thought "I need to take care of this before I embarrass my [denise_rel_to_pc]s any further."

            scene bathroom_bg morning applylotion
            with fade
            "You enter the bathroom."

            pc_thought "Only place I can have a semblance of privacy."

            show pc_pd bathroom morning phone searchporn:
                subpixel True
                ypos 1.0 yanchor 0.0
                ease 2.8 yalign 0.5
            with dissolve
            "You pull out your phone and browse to SmutCenter."

            call w01d06_s04_select_actress from _call_w01d06_s04_select_actress_1

            show pc_pd bathroom morning phone blank
            with dissolve

            "Without warning, your screen switches off."
            pc_thought "Oh no, that's no good, I'm almost out of battery charge..."

            show pc_pd bathroom morning phone blank:
                subpixel True
                ease 2.8 ypos 1.0 yanchor 0.0

            pc_thought "I'd better get my charger real quick. I think it's still in my laptop bag in the hallway."

            scene black
            with fade

            "You carefully step out of the bathroom, bent over slightly to hide your state, in case someone should see you there."
            "You walk up to your laptop bag, and start rummaging around for your phone adapter."

            play audio [ "<silence 0.5>", "sounds/doorslam.ogg", "<silence 0.3>", "sounds/doorslam.ogg" ]
            "Behind you, you hear someone come out of the bedroom and go into the bathroom."

            pc_thought "Oh..."

            scene setpiece hallway morning bathroomdoor
            with fade

            "You walk up to the bathroom door."

            menu:
                "Open the door.":
                    call sound_doorrattle from _call_sound_doorrattle
                    "You try and open the door. It's locked."
                "Knock.":
                    "You knock on the door."

            macy "I'm in here."
            macy "I'm washing my hair. I'll be some time."

            menu:
                "Say something.":
                    pc "I was in there first..."
                "Don't.":
                    pc "..."

            call music_fade_slow from _call_music_fade_slow_107

            "[macy_name] starts to sing, loudly and off key, drowning out anything you might have to say."
            macy "{font=DejaVuSans.ttf}♪{/font} La la lalala, that flows to her bones! {font=DejaVuSans.ttf}♪{/font}"
            macy "{font=DejaVuSans.ttf}♪{/font} And a comb in her pocket, lalala la laaa-agh! {font=DejaVuSans.ttf}♪{/font}"
        "[abgreen]Wait it out.":

            $ w01d06_s04_pc_tried_to_take_care = False
            call music_fade_slow from _call_music_fade_slow_108
            pc_thought "This shouldn't last long, I hope..."


    "You decide to wait for a bit in the hallway, until your... predicament... subsides."

    scene black
    with fade

    "After a minute, [denise_name] walks into the hallway and gives you a confused look."
    "You mumble something about waiting for your phone to charge, which only serves to deepen the creases on her brow."
    "She appears to listen to some inner monologue before nodding to you, as if in agreement, and carefully turning away."
    pc_thought "As if things weren't awkward enough."

    pause 2.0

    return

label w01d06_s04_select_actress:
    default w01d06_s04_searched_mia = False
    default w01d06_s04_searched_veronica = False
    default w01d06_s04_searched_sunny = False
    default w01d06_s04_searched_arabelle = False
    default w01d06_s04_searched_other = "Goblin cosplay."
    menu:
        "Search for 'Mia Khalifa'." if not w01d06_s04_searched_mia:
            $ w01d06_s04_searched_mia = True
            "You search for Mia Khalifa, one of your favorite Middle Eastern actresses."
        "Search for 'Veronica Rodriguez'." if not w01d06_s04_searched_veronica:
            $ w01d06_s04_searched_veronica = True
            "You search for Veronica Rodriguez, one of your favorite Latina actresses."
        "Search for 'Sunny Leone'." if not w01d06_s04_searched_sunny:
            $ w01d06_s04_searched_sunny = True
            "You search for Sunny Leone, one of your favorite Asian Indian actresses."
        "Search for 'Arabelle Raphael'." if not w01d06_s04_searched_arabelle:
            $ w01d06_s04_searched_arabelle = True
            "You search for Arabelle Raphael, one of your favorite, eh... {a=https://es.wikipedia.org/w/index.php?title=Arabelle_Raphael}French-Tunisian-Iranian-Jewish{/a} actresses?"
            "Oh what does it even matter; as long as she's hot."
        "Other.":
            $ inputstring = renpy.input("Who do you want to search for? (press enter for '[w01d06_s04_searched_other]')")
            $ inputstring = inputstring.strip().lower()
            if inputstring != "":
                $ w01d06_s04_searched_other = inputstring

            "You search for '[w01d06_s04_searched_other]', even though you know you'll feel dirty afterwards."
    return
