label w01d04_s04:
    scene kitchen_bg dinnertable evening
    show denise_pd kitchen evening eating plateset
    show macy_pd kitchen evening eating plateset
    with fade

    "That evening, you sit down with your girls for dinner."

    if w01d03_s08_understanding_home_evening:
        call theme_denise from _call_theme_denise

        show denise_pd kitchen evening eating neutral
        show macy_pd kitchen evening eating lookdenise
        with dissolve

        pc "So, [denise_name], I called your school and told them you'll be staying at home for a bit longer."

        show denise_pd kitchen evening eating happy
        with dissolve
        deni "Thank you, [denise_adr_pc_as]."

        pc "Mrs. Farthingsworth sends her best by the way."

        show denise_pd kitchen evening eating neutraltalk
        with dissolve
        deni "She did? That's nice."

        show macy_pd kitchen evening eating unhappy
        with dissolve
        macy "I remember her. She's a hard one. She was always on my case."

        show denise_pd kitchen evening eating takebite
        with dissolve
        deni "She seems very strict, but she's always been nice to me."

        show macy_pd kitchen evening eating lookdeniseangry
        with dissolve
        macy "Perhaps that's because you're such a goody two-shoes."

        show denise_pd kitchen evening eating whipemouth
        with dissolve
        deni "Am not!"

        show macy_pd kitchen evening eating secretsmile
        with dissolve
        macy "Right. Tell us some of the mischief you've been up to then."

        show denise_pd kitchen evening eating unhappytalk
        with dissolve
        deni "I... eh..."

        show denise_pd kitchen evening eating neutraltalk
        with dissolve
        deni "I run through the hallways when there is no one around."

        show denise_pd kitchen evening eating happy
        with dissolve
        deni "I once snuck an apple out of the cafeteria and ate it in the locker room."

        show denise_pd kitchen evening eating takebite
        with dissolve
        deni "And after I've washed my hands in the restroom, I take more than one paper towel to dry them."

        show denise_pd kitchen evening eating lookmacy
        with dissolve
        deni "..."

        show macy_pd kitchen evening eating lookdenise
        with dissolve
        macy "..."

        show macy_pd kitchen evening eating lookdeniseangry
        with dissolve
        macy "That's... just pathetic."

        show denise_pd kitchen evening eating unhappytalk
        with dissolve
        deni "..."
    else:

        call theme_macy from _call_theme_macy

        show denise_pd kitchen evening eating neutral
        show macy_pd kitchen evening eating lookdenise
        with dissolve
        pc "So, I got a call from the school today."

        show macy_pd kitchen evening eating embarrassed
        with dissolve
        pc "Apparently, someone snuck inside and threatened some students."

        show denise_pd kitchen evening eating takebite
        with dissolve
        pc "Classmates of [denise_name]."

        show denise_pd kitchen evening eating lookmacy
        with dissolve
        pc "What the hell were you thinking, [macy_name]?!"

        show macy_pd kitchen evening eating angry
        with dissolve
        macy "Well, you were {i}sooo{/i} ready to just throw [denise_name] to the wolves."

        show macy_pd kitchen evening eating unhappy
        with dissolve
        macy "So I had to step up and make sure those twerps think twice about picking on my [denise_rel_to_macy] again!"

        show macy_pd kitchen evening eating neutraltalk
        with dissolve
        pc "Do you know what you've done?"

        show denise_pd kitchen evening eating unhappy
        with dissolve
        pc "You're lucky they don't bring charges against you."
        pc "But they made it quite clear [denise_name] isn't to show her face around school anytime soon."

        show macy_pd kitchen evening eating unhappy
        with dissolve
        macy "Good. That's what you should have agreed to in the first place."

        show denise_pd kitchen evening eating unhappytalk
        with dissolve
        deni "Please, stop arguing."

        show macy_pd kitchen evening eating lookdeniseangry
        with dissolve
        deni "[denise_adr_pc_as_cap], I'm sure [macy_name] only did what she thinks was best for me."

        show macy_pd kitchen evening eating lookdenise
        with dissolve
        deni "Please don't be angry at her."

        menu:
            "[abgreen]Agree.":
                show denise_pd kitchen evening eating happy
                with dissolve
                pc "You're right angel. What she did was wrong, but she did it for the right reason."

                call music_fade_slow from _call_music_fade_slow_9

                show macy_pd kitchen evening eating underbreath
                with dissolve
                "[macy_name] mutters under her breath."
                macy "Damned right I did."
            "Don't.":

                show denise_pd kitchen evening eating unhappy
                with dissolve
                pc "I'm sorry angel, but what she did was wrong, and I won't stand for it!"

                call music_fade_slow from _call_music_fade_slow_10

                show macy_pd kitchen evening eating underbreath
                with dissolve
                "[macy_name] mutters under her breath."
                macy "Too late now..."

        show macy_pd kitchen evening eating lookdenise
        with dissolve
        pc "..."

        call theme_denise from _call_theme_denise_1

    show denise_pd kitchen evening eating neutral
    show macy_pd kitchen evening eating neutraltalk
    with dissolve
    pc "Anyways..."
    pc "The school is going to send us a package with study materials for [denise_name]."
    pc "That way we can continue your lessons and prepare for your final exams."
    pc "So you're not off the hook yet."

    show denise_pd kitchen evening eating neutraltalk
    with dissolve
    deni "You're going to tutor me, [denise_adr_pc_as]?"

    if w01d04_s02_pc_did_not_want_to_tutor:
        pc "They didn't give me much of a choice, really."
    else:
        pc "Yes."

    show denise_pd kitchen evening eating happy
    with dissolve
    deni "Yay!"

    show macy_pd kitchen evening eating lookdenise
    with dissolve
    macy "I'll help you out too, but not tomorrow evening."
    show macy_pd kitchen evening eating neutraltalk
    with dissolve
    macy "I tried to get tomorrow evening off, but they told me they couldn't find a replacement and they really need me at the diner."

    if not w01d04_s03_rejected_brooke:
        pc_thought "Oh well, there goes the drink that [brooke_name] had planned for tomorrow..."

    show denise_pd kitchen evening eating unhappytalk
    with dissolve
    deni "That's okay, [macy_name]. I know what your grades were like. I'd rather [denise_adr_pc_as] does the tutoring if it's all the same to you."

    show macy_pd kitchen evening eating lookdeniseangry
    with dissolve
    macy "Hmph..."

    show macy_pd kitchen evening eating underbreath
    with dissolve
    if w01d03_s08_understanding_home_evening:
        macy "Goody two-shoes."
    else:
        macy "Twerp."

    show denise_pd kitchen evening eating whipemouth
    with dissolve
    deni "Hey!"

    call music_fade_slow from _call_music_fade_slow_11
    scene black
    with fade

    "After dinner finishes, you and [denise_name] clear up while [macy_name] sets off for work."

    return
