label w02d04_s05:

    "You arrive home and freshen up, while your [denise_rel_to_pc]s set the table."

    scene kitchen_bg evening
    show denise_pd kitchen_lookatsink evening camisole happy:
        subpixel True
        xanchor 0.0 xpos 1.0
        0.5
        easein 2.3 xalign 0.25 yalign 1.0
    show macy_pd kitchen_lookatsink workwear evening neutral:
        subpixel True
        xanchor 0.0 xpos 1.0
        0.8
        easein 2.3 xalign 0.75 yalign 1.0
    with fade

    deni "You know [denise_adr_pc_as] is going to pick you up after work tonight, right?"

    show macy_pd kitchen_lookatsink workwear evening rolleyes
    with dissolve
    macy "You told me. Several times."

    show denise_pd kitchen_lookatsink evening camisole neutral
    with dissolve
    deni "I can tell [denise_adr_pc_as] to drop you off as well if you like."

    show macy_pd kitchen_lookatsink workwear evening smile
    with dissolve
    macy "Still don't need him to, just like last time you asked me."

    show denise_pd kitchen_lookatsink evening camisole unhappy
    with dissolve
    deni "Are you really sure?"
    show denise_pd kitchen_lookatsink evening camisole smile
    with dissolve
    deni "Maybe you're ashamed to ask, but I can do it for you."

    show macy_pd kitchen_lookatsink workwear evening shocked
    with dissolve
    macy "Urgh..."

    show macy_pd kitchen_lookatsink workwear evening rolleyes
    with dissolve
    macy "It's still going to be light out when I go to work, there's no need."

    show denise_pd kitchen_lookatsink evening camisole angry
    with dissolve
    deni "But what if there's a sudden eclipse?"

    show macy_pd kitchen_lookatsink workwear evening shocked
    with dissolve
    macy "A sudden eclipse?"

    show denise_pd kitchen_lookatsink evening camisole neutral
    deni "Well, one that you weren't expecting."

    show macy_pd kitchen_lookatsink workwear evening frown:
        subpixel True
        0.5
        easeout 2.2 xpos 0.0 xanchor 1.0
    show denise_pd kitchen_lookatsink evening camisole neutral:
        subpixel True
        2.8
        easeout 0.7 xpos 0.0 xanchor 1.0
    with dissolve
    macy "I'll make sure to consult an almanac before leaving for work."

    scene black
    with fade

    pause 2.0

    scene kitchen_bg dinnertable evening:
        subpixel True
        xalign 0.6 yalign 0.2 zoom 1.1
        0.5
        ease 25.0 zoom 1.0
    show denise_pd kitchen evening eating neutral:
        subpixel True
        xalign 0.8 yalign 0.0 zoom 1.2
        0.5
        ease 25.0 zoom 1.0
    show macy_pd kitchen evening eating embarrassed:
        subpixel True
        xalign 0.8 yalign 0.0 zoom 1.2
        0.5
        ease 25.0 zoom 1.0
    with fade
    "When the table is set, you join your girls for dinner."

    show denise_pd kitchen evening eating angryatmacy
    with dissolve
    deni "You're not going to be difficult and walk home by yourself anyway, are you?"

    show macy_pd kitchen evening eating underbreath
    with dissolve
    macy "No, I'm not. Just like the last time you asked me."

    show denise_pd kitchen evening eating unhappytalk
    with dissolve
    deni "And you're not waiting outside in a dark parking lot."
    show macy_pd kitchen evening eating lookdeniseangry
    with dissolve
    macy "What?"

    show denise_pd kitchen evening eating unhappy
    with dissolve
    deni "Just stay in the diner until [denise_adr_pc_as] pulls up in front."

    show denise_pd kitchen evening eating neutral
    with dissolve
    deni "Or better yet, stay inside until he walks up to the door so he can escort you back."

    show macy_pd kitchen evening eating laughoutloud
    with dissolve
    macy "What am I, the fucking president of the country?"

    show denise_pd kitchen evening eating angryatmacy
    with dissolve
    deni "I just want you to be safe."

    show macy_pd kitchen evening eating underbreath
    with dissolve
    macy "What you're doing is driving me crazy with all your questions and instructions!"

    default w02d04_s05_backed_denise = False
    menu:
        "Back [denise_name].":
            $ w02d04_s05_backed_denise = True
            pc "Now [macy_name], your [denise_rel_to_macy] is just worried because she was really scared by what happened yesterday."

            show macy_pd kitchen evening eating neutraltalk
            with dissolve
            macy "Huh?"

            pc "I understand her anxiety, and the important thing is that we reassure her that you'll be safe."

            show denise_pd kitchen evening eating happy
            with dissolve
            deni "Thank you, [denise_adr_pc_as]."

            show denise_pd kitchen evening eating whipemouth
            with dissolve
            deni "So, are you going to wait inside until he comes to collect you?"

            show macy_pd kitchen evening eating disbelief
            with dissolve
            macy "I don't fucking believe this!"

            show macy_pd kitchen evening eating lookdeniseangry
            with dissolve
            macy "Yes I will, okay?!"

            show denise_pd kitchen evening eating laugh
            with dissolve
            deni "Thank you."
        "[abgreen]Back [macy_name].":

            $ w02d04_s05_backed_denise = False
            pc "Your [macy_rel_to_denise] has a point, angel."

            show denise_pd kitchen evening eating neutraltalk
            with dissolve
            deni "But [denise_adr_pc_as]..."

            pc "I'm sure she's just as rattled as you are about what happened yesterday, but we should not overreact."
            pc "[macy_name] is not going to be walking home alone in the dark anymore, that's the important thing."

            show macy_pd kitchen evening eating lookdeniseangry
            with dissolve
            macy "There! Don't overreact!"

            show macy_pd kitchen evening eating lookdenise
            with dissolve
            macy "Now, let me eat in peace, will you?"

            show denise_pd kitchen evening eating upset
            deni "Awww..."

            show denise_pd kitchen evening eating angry
            with dissolve
            deni "[denise_adr_pc_as_cap], if she's not going to stay inside for you to come collect her, you have to pull up right in front of the door."

    call music_fade_slow from _call_music_fade_slow_132

    show denise_pd kitchen evening eating angryatmacy
    with dissolve
    deni "And something else..."

    show macy_pd kitchen evening eating underbreath
    with dissolve
    macy "Dear lord, give me strength..."

    scene black
    with fade

    pause 2.0

    return
