label w02d06_s07:

    "You are waiting in the living room when [denise_name] enters."

    play audio [ "<silence 1.1>", "sounds/doorslam.ogg" ]

    scene kitchen_bg lookatsink nighttime:
        subpixel True
        xalign 0.5 yalign 0.2 zoom 1.1
        0.5
        ease 12.3 zoom 1.0
    show denise_pd kitchen_lookatsink evening camisole smile:
        subpixel True
        xanchor 0.0 xpos 1.0 yalign 0.2 zoom 1.2
        0.5
        parallel:
            easein 1.2 xalign 0.5
        parallel:
            ease 12.3 zoom 1.0
    with fade

    deni "She'll be out in a minute."

    show denise_pd kitchen_lookatsink evening camisole unhappy
    with dissolve
    deni "Be nice to her, please?"

    default w02d06_s07_pc_didnt_promised_to_be_nice = False
    menu:
        "[abgreen]'I will.'":
            $ w02d06_s07_pc_didnt_promised_to_be_nice = False
            pc "I'll be nice to her."
            pc "Aren't I always?"

            show denise_pd kitchen_lookatsink evening camisole smile
            with dissolve
            deni "Hmmm..."
        "'Depends on her.'":

            $ w02d06_s07_pc_didnt_promised_to_be_nice = True
            pc "I'll do my best, but it also depends on her."

            show denise_pd kitchen_lookatsink evening camisole neutral
            with dissolve
            deni "Just promise me you'll try and you won't lose your temper?"
            pc "I will."

            show denise_pd kitchen_lookatsink evening camisole smile
            with dissolve
            deni "Good."

    show denise_pd kitchen_lookatsink evening camisole neutral
    with dissolve
    deni "Just..."

    show denise_pd kitchen_lookatsink evening camisole happy
    with dissolve
    deni "Just try to have a fun night out."

    show denise_pd kitchen_lookatsink evening camisole angry
    with dissolve
    deni "No fighting."

    pc "I'll do my best, angel."

    call music_fade_slow from _call_music_fade_slow_237

    show denise_pd kitchen_lookatsink evening camisole neutral
    with dissolve
    deni "I want you two to be close again."

    show denise_pd kitchen_lookatsink evening camisole unhappy
    with dissolve
    deni "{size=-9}Maybe even more close than you ever were.{/size}"

    pc "What's that, angel?"

    call theme_macy from _call_theme_macy_18

    scene black
    with fade
    "Just at that moment, [macy_name] walks in."

    scene setpiece kitchen evening macy goingout vignette:
        subpixel True
        yalign 1.0
        ease 12.0 yalign 0.0
    with fade
    pause

    play audio [ "<silence 1.1>", "sounds/doorslam.ogg" ]
    scene kitchen_bg lookatsink nighttime:
        subpixel True
        xalign 0.5 yalign 0.2 zoom 1.0
        0.5
        ease 12.3 zoom 1.05
    show denise_pd kitchen_lookatsink evening camisole smile:
        subpixel True
        xalign 0.5 yalign 0.2 zoom 1.0
        0.5
        parallel:
            0.4
            ease 2.6 xalign 0.25
        parallel:
            ease 12.3 zoom 1.1
    show macy_pd kitchen_lookatsink outwear evening neutral:
        subpixel True
        xanchor 0.001 xpos 1.0 yalign 0.2 zoom 1.0
        0.5
        parallel:
            easein 1.2 xalign 0.75
        parallel:
            ease 12.3 zoom 1.1
    with fade
    deni "Wow..."

    show macy_pd kitchen_lookatsink outwear evening frown
    with dissolve
    macy "Don't start."

    show denise_pd kitchen_lookatsink evening camisole happy
    with dissolve
    deni "I think you look hot."

    show denise_pd kitchen_lookatsink evening camisole neutral
    with dissolve
    deni "What about you, [denise_adr_pc_as]?"

    default w02d06_s07_just_nice = False
    menu:
        "'You look nice.'":
            $ w02d06_s07_just_nice = True

            pc "You look nice, princess."
            show macy_pd kitchen_lookatsink outwear evening rolleyes
            with dissolve
            macy "Yeah, that's the look I was going for, [macy_adr_pc_as_nice]."

            show kitchen_bg lookatsink nighttime:
                0.5
                ease 12.3 zoom 1.0
            show denise_pd kitchen_lookatsink evening camisole neutral:
                0.5
                ease 12.3 zoom 1.0
            show macy_pd kitchen_lookatsink outwear evening neutral:
                0.5
                ease 12.3 zoom 1.0
            with dissolve
            macy "Nice."
        "[abgreen]'You look hot.'":

            $ w02d06_s07_just_nice = False

            pc "You look hot, princess."

            if macy_love >= 5:
                show macy_pd kitchen_lookatsink outwear evening neutral
                with dissolve
            else:
                show macy_pd kitchen_lookatsink outwear evening shocked
                with dissolve

            macy "Is that how you talk to your [macy_rel_to_pc], [macy_adr_pc_as_nice]?"

            default w02d06_s07_back_down = False
            menu:
                "Back down.":
                    $ w02d06_s07_back_down = True
                    pc "Sorry, I meant to say you look nice."

                    show macy_pd kitchen_lookatsink outwear evening rolleyes
                    with dissolve
                    macy "Nice..."

                    show kitchen_bg lookatsink nighttime:
                        0.5
                        ease 12.3 zoom 1.0
                    show denise_pd kitchen_lookatsink evening camisole neutral:
                        0.5
                        ease 12.3 zoom 1.0
                    show macy_pd kitchen_lookatsink outwear evening neutral:
                        0.5
                        ease 12.3 zoom 1.0
                    with dissolve
                    macy "..."
                "[abgreen]Double down.":

                    $ w02d06_s07_back_down = False
                    pc "Hey, I thought that tonight we were supposed to forget about being [pc_rel_to_macy] and [macy_rel_to_pc]."

                    show denise_pd kitchen_lookatsink evening camisole happy
                    with dissolve
                    deni "He's right you know."

                    show denise_pd kitchen_lookatsink evening camisole smile
                    with dissolve
                    deni "He can totally call you hot!"
                    pc "Good, because she looks hot."

                    show denise_pd kitchen_lookatsink evening camisole happy
                    with dissolve
                    deni "Yeah."

                    show kitchen_bg lookatsink nighttime:
                        0.5
                        ease 12.3 zoom 1.0
                    show denise_pd kitchen_lookatsink evening camisole happy:
                        0.5
                        ease 12.3 zoom 1.0
                    show macy_pd kitchen_lookatsink outwear evening secretsmile:
                        0.5
                        ease 12.3 zoom 1.0
                    with dissolve
                    macy "..."

    show denise_pd kitchen_lookatsink evening camisole smile
    with dissolve
    deni "Time to go, you two!"

    show kitchen_bg lookatsink nighttime:
        0.5
        ease 9.2 zoom 1.2 xalign 0.0
    show denise_pd kitchen_lookatsink evening camisole smile:
        0.5
        parallel:
            ease 3.2 xalign 0.5
        parallel:
            ease 9.2 zoom 1.3
    show macy_pd kitchen_lookatsink outwear evening smile:
        0.5
        parallel:
            0.7
            ease 2.2 xpos 1.0 xanchor 0.0
        parallel:
            ease 9.2 zoom 1.3
    macy "Right."

    pc "Are you sure you'll be alright by yourself, angel?"

    show denise_pd kitchen_lookatsink evening camisole happy
    with dissolve
    deni "Don't worry about me, [denise_adr_pc_as]! It's just one night."

    show denise_pd kitchen_lookatsink evening camisole smile
    with dissolve
    deni "Go out, have a drink, enjoy yourselves."

    show denise_pd kitchen_lookatsink evening camisole angry
    with dissolve
    deni "And the car stays home!"
    pc "Alright, alright."

    show denise_pd kitchen_lookatsink evening camisole happy
    with dissolve
    deni "Have fun."

    "You turn your attention to your eldest [macy_rel_to_pc]."

    show kitchen_bg lookatsink nighttime:
        0.5
        ease 3.3 zoom 1.2 xalign 1.0
    show denise_pd kitchen_lookatsink evening camisole happy:
        0.5
        ease 3.3 zoom 1.3 xalign 0.2
    with dissolve
    pc "Ready to go, princess?"

    scene setpiece kitchen evening macy goingout backside vignette:
        subpixel True
        yalign 1.0
        ease 12.0 yalign 0.0
    with fade

    pause 7.2
    macy "Yeah, I'm ready, [macy_adr_pc_as_nice]."

    call music_fade_slow from _call_music_fade_slow_238

    show setpiece kitchen evening macy goingout backside vignette:
        subpixel True
        0.5
        ease 2.0 xalign 0.5 yalign 0.6 zoom 1.3
    with dissolve
    pause 1.5

    $ persistent.unlock_m_leather_pants = True

    scene black
    with fade

    pause 0.5

    call theme_macy_fate from _call_theme_macy_fate_1

    scene outside_bg citystreet dusk:
        subpixel True
        xalign 0.85 yalign 0.1 zoom 1.0
        0.5
        ease 21.8 zoom 1.15
    show macy_pd outside evening eveningwear walkwithpc 1:
        subpixel True
        xalign 0.85 yalign 0.1 zoom 1.0
        0.5
        ease 21.8 zoom 1.3
    with dissolve

    "You go outside and enter the cool evening air."
    "It's a twenty minute walk to the center of town."

    if macy_love >= 5:
        show macy_pd outside evening eveningwear walkwithpc 2
        with dissolve
        macy "It's nice out..."
        pc "Yeah. It might be a cold night though."

        if macy_love >= 6:
            macy "..."
            show macy_pd outside evening eveningwear walkwithpc leanin
            with dissolve
            "She leans into you, and you instinctively put your hand on her shoulder."
            "The last light of the day warms your skin, balancing out the cooling air."
        else:
            show macy_pd outside evening eveningwear walkwithpc 1
            with dissolve
            "You walk on as the last light of the day warms your skin, balancing out the cooling air."
    else:
        show macy_pd outside evening eveningwear walkwithpc 2
        with dissolve
        "You walk together, enjoying the fleeting warmth of the last rays of daylight on your skin."

    scene black
    with fade

    pause 2.0

    return
