label w01d02_s07:

    call theme_macy_sad from _call_theme_macy_sad_2
    scene backdrop hallway_blurredstreetlights
    show setpiece hallway night macy comehome
    with fade

    "You've already turned in for the night when [macy_name] comes home from work."

    scene black
    with fade
    "She pauses in the hall, and a second later you hear the living room door creak open."

    macy "[player_name]?"

    scene backdrop darkblue
    show setpiece livingroom night macy askawake
    with openeyestrans
    macy "[player_name]? Are you awake?"

    pc "Yeah..."
    pc "Yeah, I am. What's up, [macy_name]?"

    macy "You got a minute?"

    menu:
        "[abgreen]'Of course.'":
            pc "Of course. Let me get up."
        "'Can't it wait?'":

            pc "Can't it wait? It's late and I'm kinda tired."
            macy "Sure, never mind. Goodnight."

            call music_fade_slow from _call_music_fade_slow_7
            "She leaves, closing the door behind her."

            scene black
            with closeeyestrans
            pc_thought "She sounded disappointed."
            pc_thought "I wonder what was so important."

            return

    scene black
    with fade
    "She comes in and turns on the kitchen lights. You get up and join her."

    scene kitchen_bg lookatsink nighttime
    show macy_pd kitchen night workwear neutral
    with fade

    "She brings the faint smell of perspiration into the room."
    "It's not an unpleasant smell, and one you know very well."
    "But you associate it with meeting a happy [macy_rel_to_pc] coming of off a sports field after a game, or trying to wrestle her [pc_rel_to_macy] into submission in the yard on a sunny afternoon."
    "Now, she just looks tired."

    macy "..."

    pc "What is it, princess?"

    show macy_pd kitchen night workwear frown
    with dissolve
    macy "..."

    show macy_pd kitchen night workwear neutral
    with dissolve
    macy "<sigh>"
    macy "I just..."
    macy "..."

    show macy_pd kitchen night workwear secretsmile
    with dissolve
    macy "Thanks for bringing the candy."
    macy "You remembered I always liked the purple ones."
    call macy_add_love from _call_macy_add_love

    pc "You're welcome, [macy_name]."
    pc "I'm sorry, I seem to have misplaced it. I thought I left it on the kitchen counter but it's not there."

    show macy_pd kitchen night workwear neutral
    with dissolve
    macy "I already took them."
    show macy_pd kitchen night workwear secretsmile
    with dissolve
    macy "And ate them."

    pc "Good."

    show macy_pd kitchen night workwear neutral
    with dissolve
    macy "..."
    macy "I know you mean well."
    macy "..."
    show macy_pd kitchen night workwear thoughtful
    with dissolve
    macy "It's just... I can't..."
    macy "..."

    menu:
        "[abgreen]Say something.":
            pc "It's been a hard time for all of us."
            menu:
                "[abgreen]'It'll be okay.'":
                    pc "But it's going to be okay, princess."
                    show macy_pd kitchen night workwear sad
                    with dissolve
                    macy "No it's not, it really isn't."
                "'I understand.'":

                    pc "I understand what you're going through, princess."
                    show macy_pd kitchen night workwear sad
                    with dissolve
                    macy "No you don't... You couldn't."

            macy "I'm sorry."
        "Don't.":

            pc "..."
            show macy_pd kitchen night workwear sad
            with dissolve
            macy "I..."

    show macy_pd kitchen night workwear thoughtful
    with dissolve
    macy "I need to go to sleep. It's late."
    macy "..."
    macy "Goodnight, [player_name]."
    pc "Goodnight, [macy_name]."

    show macy_pd kitchen night workwear sad:
        0.5
        easeout 1.8 xpos 1.0 xanchor 0.0
    with dissolve
    call music_fade_slow from _call_music_fade_slow_8
    "She leaves and closes the door behind her."

    scene black
    with fade
    pause 2.0

    return
