label w02d01_s06:

    "You settle yourself on the couch and check out a series on Webfilms that everyone at the office seems to be raving about."

    call theme_denise from _call_theme_denise_20
    scene livingroom_couch_bg night:
        subpixel True
        xalign 0.6 yalign 0.0 zoom 1.1
        0.5
        ease 14 zoom 1.0
    show denise_pd livingroom night couch askjoin:
        subpixel True
        xalign 0.6 yalign 0.0 zoom 1.2
        0.5
        ease 14 zoom 1.0

    "After a little while, a freshly bathed [denise_name] joins you on the couch."

    show denise_pd livingroom night couch talk
    with dissolve
    deni "What are you watching?"

    show denise_pd livingroom night couch playphone
    with dissolve
    pc "Some new series that everyone was talking about."
    deni "Oh."

    pc "Aren't you looking at one of your vlogs?"

    show denise_pd livingroom night couch thoughtfull
    with dissolve
    deni "Nah. They're going to live stream the arrival of a new kitten later tonight."

    show denise_pd livingroom night couch talk
    with dissolve
    deni "I'll just watch what you're watching for now."

    "Out of the blue, the story erupts into a hefty sex scene."

    pc "What the...?"

    show denise_pd livingroom night couch happy
    with dissolve
    deni "That was unexpected."
    pc "Yeah, they do that a lot in first seasons, I noticed."
    pc "Hook viewers on explicit sex scenes in season one."
    pc "...and see if they can get them to stay for the story and characters in season two."

    "The scene becomes very explicit, indeed."
    show denise_pd livingroom night couch sad
    with dissolve
    deni "Eh... that's..."

    show denise_pd livingroom night couch talk
    with dissolve
    deni "That... works too if it's two girls?"
    pc "I guess so."
    pc "We can watch something else."

    show denise_pd livingroom night couch tummyrub talk
    with dissolve
    deni "That's okay, just rub my belly for a bit."

    show denise_pd livingroom night couch tummyrub talk movehand
    with dissolve
    "On screen, the sex scene in turn erupts into a violent bloodbath."

    pc "Eh..."

    show denise_pd livingroom night couch tummyrub neutral movehand
    with dissolve
    deni "How was your work?"

    show denise_pd livingroom night couch tummyrub talk movehand
    with dissolve
    deni "Did you see that lady again?"

    if w02d01_s02_agree:
        pc "[brooke_name]? Yeah, I spoke to her."
        default w02d01_s06_told_about_prank = False
        if w02d01_s02_agree:
            menu:
                "Tell her about the prank.":
                    $ w02d01_s06_told_about_prank = True
                    pc "We kinda pulled a naughty prank at the office today."

                    show denise_pd livingroom night couch talk
                    with dissolve
                    deni "You did?"

                    show denise_pd livingroom night couch thoughtfull
                    with dissolve
                    deni "What did you do?"

                    pc "Ehhh... maybe I'll tell you some other time."

                    show denise_pd livingroom night couch headrub sad
                    with dissolve
                    deni "Lame."

                    show denise_pd livingroom night couch tummyrub talk movehand
                    with dissolve
                    "She lies back down."
                "[abgreen]Don't.":

                    $ w02d01_s06_told_about_prank = False
                    pc "..."
    else:
        pc "Yeah, we chatted for a minute or so."

    show denise_pd livingroom night couch tummyrub neutral movehand
    with dissolve
    with hpunch
    "[denise_name] adjusts her position on your lap a bit, making contact with your groin."
    "Once more, your treacherous body responds to your [denise_rel_to_pc]s presence."
    pc_thought "Oh come on... Not again!"

    "You try to distract yourself by looking at the gory scene on screen."
    "Unfortunately, the bloodbath turns into another sex scene."

    show denise_pd livingroom night couch tummyrub talk movehand
    with dissolve
    deni "Is that how it usually goes?"

    pc "I..."
    pc "I have no idea angel. First time I saw this."

    "[denise_name] adjusts her position on your lap again..."

    show denise_pd livingroom night couch tummyrub neutral movehand
    with dissolve
    with hpunch
    "...and another brush with your groin ensures there's no stopping the inevitable."
    pc_thought "This is ridiculous!"
    pc_thought "I have to take care of this, now!"

    show denise_pd livingroom night couch headinlap neutral
    with dissolve
    pc "Excuse me, angel, I just want to go and have a quick shower."

    show denise_pd livingroom night couch talk
    with dissolve
    deni "Are you okay?"

    pc "Never better. Now if you'll excuse me for a minute..."
    scene livingroom_couch_bg night:
        subpixel True
        xalign 0.6 yalign 0.0
        0.5
        ease 13 zoom 1.1
    show denise_pd livingroom night couch solo looksurprised:
        subpixel True
        xalign 0.6 yalign 0.0
        0.5
        ease 13 zoom 1.2
    with dissolve
    play audio [ "<silence 2.2>", "sounds/doorslam.ogg" ]
    "Once more, you rush out of the room, body bent at an awkward angle to hide your predicament."

    deni_thought "What was that about?"
    deni_thought "I could have sworn he showered before dinner."

    deni_thought "It couldn't be another..."
    deni_thought "Could it?"

    scene black
    with fade

    "Once in the hallway, you take a second to gather your thoughts."
    pc_thought "This is really getting out of hand."

    default w02d01_s06_tried_to_take_care_of_it = True
    menu:
        "[abgreen]Take care of it.":
            $ w02d01_s06_tried_to_take_care_of_it = True
            scene bathroom_bg morning applylotion
            with fade
            "You enter the bathroom."

            show pc_pd bathroom morning phone searchporn:
                subpixel True
                ypos 1.0 yanchor 0.0
                ease 2.8 yalign 0.5
            with dissolve
            "You pull out your phone and browse to SmutCenter."

            call w01d06_s04_select_actress from _call_w01d06_s04_select_actress

            "This time, the site just refuses to load."
            "You try to refresh, but you can't connect to any website at all."

            show pc_pd bathroom morning phone searchporn:
                subpixel True
                ease 2.8 ypos 1.0 yanchor 0.0
            with dissolve
            pc_thought "Great, connection's down."

            "At that moment, there's a polite knock at the door."
            deni "[denise_adr_pc_as_cap]? I think the internet is broken."
            pc "Yeah, I noticed. I'll be out in a second."
            deni "Okay."

            scene black
            with fade

            "Your mind is thoroughly distracted by the prospect of having to fix the entire internet, and your erection soon subsides."
            "You return to your [denise_rel_to_pc] in the living room after a minute or two."

            scene kitchen_bg lookatsink nighttime:
                subpixel True
                xalign 0.5 yalign 0.5 zoom 1.15
                0.5
                ease 14 zoom 1.0
            show denise_pd kitchen night unhappy:
                subpixel True
                xalign 0.5 yalign 0.5 zoom 1.15
                0.5
                ease 14 zoom 1.0
            with fade
        "Don't.":

            $ w02d01_s06_tried_to_take_care_of_it = False
            pc_thought "I should just wait a few minute for it to subside."
            "You wait for a bit."
            "No sooner has your erection subsided, then [denise_name] walks into the hallway."
            "She looks up at you, startled."
            deni "What are you doing here in the dark?"

            pc "Nothing, let's go inside."

            "You follow your [denise_rel_to_pc] back into the living room."

            scene kitchen_bg lookatsink nighttime:
                subpixel True
                xalign 0.5 yalign 0.5 zoom 1.15
                0.5
                ease 14 zoom 1.0
            show denise_pd kitchen night unhappy:
                subpixel True
                xpos 1.0 xanchor 0.0 yalign 0.5 zoom 1.15
                0.5
                parallel:
                    ease 14 zoom 1.0
                parallel:
                    ease 1.9 xalign 0.5
            with fade

            deni "I think the internet is broken, [denise_adr_pc_as]."
            pc "It is?"

            show denise_pd kitchen night neutral
            with dissolve
            deni "Yeah. It's not loading any webpage and all the apps are giving error messages when they try to connect."

            show denise_pd kitchen night unhappy
            with dissolve

    deni "What's wrong with it, [denise_adr_pc_as]?"

    call music_fade_slow from _call_music_fade_slow_97

    show denise_pd kitchen night angry
    with dissolve
    deni "The live stream is about to start. I'm going to miss it!"

    pc "I'll look into it right now, angel."

    return
