label w02d04_s07:

    "You arrive early, and drive around the block a couple of times until a parking spot opens up right in front of the diner."

    if w02d04_s05_backed_denise:
        "As promised, you walk up to the door, and wait a few minutes for [macy_name] to leave with you."
    else:
        "After fifteen minutes, [macy_name] comes out and enters the car."

    call theme_macy from _call_theme_macy_11

    scene backdrop car nighttime
    show macy_pd car nighttime thoughtful:
        subpixel True
        xalign 0.7 yalign 0.05 zoom 1.2
        ease 25.0 zoom 1
    with fade

    show macy_pd car nighttime thoughtful eyesclosed
    with dissolve
    "She seems tense and tired."

    menu:
        "[abgreen]Ask about her day.":
            pc "How was work?"

            show macy_pd car nighttime neutral
            with dissolve
            macy "The usual."

            show macy_pd car nighttime thoughtful eyesclosed
            with dissolve
            macy "..."
        "Don't.":

            pc "..."

    "You can tell something's brooding."
    "After a few minutes, [macy_name] boils over."

    show macy_pd car nighttime frown
    with dissolve
    macy "How are things with that floozy at the office?"
    pc "Who, [brooke_name]?"

    show macy_pd car nighttime shock
    with dissolve
    macy "Yeah. You fuck her yet?"

    default w02d04_s07_pc_responded = False
    menu:
        "Respond.":
            $ w02d04_s07_pc_responded = True
            pc "Really, [macy_name]..."
            pc "What the hell is wrong with you?!"

            show macy_pd car nighttime eyeroll
            with dissolve
            macy "With me? What the hell is wrong with you?"

            show macy_pd car nighttime frown
            with dissolve
            macy "You have a responsibility to this family."

            show macy_pd car nighttime shock
            with dissolve
            macy "I can understand that you can't wait to move on and forget all about me, but [denise_name] needs you, us."

            default w02d04_s07_pc_responded_2 = False
            menu:
                "Respond.":
                    $ w02d04_s07_pc_responded_2 = True
                    pc "What?!"
                    pc "Why would you think I would want to forget about you?"
                    pc "I care about you. A lot."

                    show macy_pd car nighttime thoughtful
                    with dissolve
                    macy "Well, maybe I don't deserve that."
                    pc "Don't deserve it? You're not making sense."

                    show macy_pd car nighttime sad
                    with dissolve
                    macy "I don't want to make sense."

                    show macy_pd car nighttime frown
                    with dissolve
                    macy "This isn't about me. It's about your responsibility to this [group_adr_as]."

                    show macy_pd car nighttime eyeroll
                    with dissolve
                    macy "You know what? Fuck it! Forget I said anything."

                    default w02d04_s07_pc_responded_3 = False
                    menu:
                        "Respond.":
                            $ w02d04_s07_pc_responded_3 = True
                            pc "I don't want to!"

                            show macy_pd car nighttime frown
                            with dissolve
                            macy "Tough! Like I said this isn't about you or me."
                            pc "I... I don't know what to say."

                            show macy_pd car nighttime thoughtful eyesclosed
                            with dissolve
                            macy "Then do us both a favor and don't say anything."
                            pc "..."
                        "Say nothing.":

                            $ w02d04_s07_pc_responded_3 = False
                            pc "..."

                            show macy_pd car nighttime thoughtful eyesclosed
                            with dissolve
                            macy "..."
                "Say nothing.":

                    $ w02d04_s07_pc_responded_2 = False
                    pc "..."
        "[abgreen]Say nothing.":

            $ w02d04_s07_pc_responded = False
            pc "..."

    if not (w02d04_s07_pc_responded and w02d04_s07_pc_responded_2):
        show macy_pd car nighttime frown
        with dissolve
        macy "Fuck! I knew it."
        show macy_pd car nighttime thoughtful eyesclosed
        with dissolve
        macy "..."

    "The rest of the drive home passes in awkward silence."

    scene black
    with fade

    pause 2.0

    scene kitchen_bg lookatsink nighttime
    show denise_pd kitchen night neutral:
        subpixel True
        xanchor 1.0 xpos 0.0 yalign 1.0
        0.5
        easein 0.9 xalign 0.0
    show macy_pd kitchen night workwear frown:
        subpixel True
        xanchor 0.0 xpos 1.0 yalign 1.0
        1.2
        easein 1.9 xalign 1.0
    with fade

    "You arrive home where [denise_name] is waiting."

    play audio [ "<silence 3.3>", "sounds/doorslam.ogg" ]
    show macy_pd kitchen night workwear shocked:
        2.1
        easeout 0.7 xanchor 0.0 xpos 1.0
    show denise_pd kitchen night neutral:
        2.4
        ease 1.2 xalign 0.5
    with dissolve
    macy "I'm going straight to bed."

    show denise_pd kitchen night unhappy
    with dissolve
    deni "Oh..."

    show denise_pd kitchen night neutral
    with dissolve
    deni_thought "They had another argument, I can tell..."
    show denise_pd kitchen night unhappy
    with dissolve
    deni_thought "What {u}am{/u} I going to do to make it stop?"

    show denise_pd kitchen night neutral
    with dissolve
    deni "Hold up, I'm coming...!"

    show denise_pd kitchen night smile
    with dissolve
    deni "Goodnight, [denise_adr_pc_as]."

    play audio [ "<silence 3.5>", "sounds/doorslam.ogg" ]
    show denise_pd kitchen night smile:
        0.7
        easeout 2.3 xanchor 0.0 xpos 1.0
    pc "Goodnight, angel."

    call music_fade_slow from _call_music_fade_slow_118

    scene black
    with fade

    scene backdrop darkblue
    show setpiece livingroom night pc sleepcouch:
        subpixel True
        zoom 1.2 xalign 0.2 yalign 0.2
        0.5
        ease 29 zoom 1.0
    with fade
    "The house grows quiet as everyone goes to sleep."

    scene black
    with fade

    pause 2.0

    return
