label w02d02_s01:

    call theme_denise from _call_theme_denise_25
    scene setpiece hallway morning bathroomdoor:
        subpixel True
        xalign 0.0 yalign 1.0 zoom 1.2
        ease 27 zoom 1.0
    with fade

    show text "{size=+18}{font=fonts/typeo___.ttf}Tuesday...{/font}{/size}" at truecenter
    with dissolve
    $ renpy.pause(2.0, hard='True')

    hide text
    with dissolve

    $ renpy.pause(1.0, hard='True')

    show text "{size=+18}{font=fonts/typeo___.ttf}Early morning...{/font}{/size}" at truecenter
    with dissolve
    $ renpy.pause(2.0, hard='True')

    hide text
    with dissolve

    menu:
        "[abgreen]Knock.":
            "You knock on the door."
        "Just enter.":

            call sound_doorrattle from _call_sound_doorrattle_1
            "You try to open the door."
            "It's locked."

    deni "That you, [denise_adr_pc_as]?"
    pc "Yeah, are you nearly done?"
    deni "Almost. Give me a second to dry off."

    scene black
    with fade

    "You grab your phone from the living room and check your e-mail to pass the time."

    scene setpiece hallway morning bathroomdoor
    with fade
    "After a minute, the door unlatches."
    deni "I'm done. You can come in."

    scene bathroom_bg morning:
        subpixel True
        xalign 0.5 yalign 0.5 zoom 1.1
        0.5
        ease 18 zoom 1.0
    show denise_pd bathroom morning towel smiling:
        subpixel True
        xalign 0.5 yalign 0.5 zoom 1.2
        0.5
        ease 18 zoom 1.0
    with fade

    deni "Good morning, [denise_adr_pc_as]."

    show denise_pd bathroom morning towel happy
    with dissolve
    deni "I was just about to come get you."

    pc "I woke up a bit early."

    show denise_pd bathroom morning towel neutral
    with dissolve
    deni "Did you sleep well?"


    menu:
        "[abgreen]'Yes.'":
            pc "Yeah, I slept fine, angel."
            show denise_pd bathroom morning towel unhappy
            with dissolve
            deni "Are you sure?"
        "'No.'":

            pc "Not really, angel."
            show denise_pd bathroom morning towel unhappy
            with dissolve
            deni "I'm sorry."

    show denise_pd bathroom morning towel neutral
    with dissolve
    deni "I really wish you could sleep in a real bed sometimes."
    pc "We won't be in this situation forever, angel."
    pc "It'll be fine until then."

    pc "Did you sleep well?"

    show denise_pd bathroom morning towel smiling
    with dissolve
    deni "Like a baby, [denise_adr_pc_as]."

    show denise_pd bathroom morning towel happy
    with dissolve
    deni "I cuddled up to [macy_name] all night long."
    pc "That's nice."

    show denise_pd bathroom morning towel neutral
    with dissolve
    deni "Yeah."
    pc "So?"

    show denise_pd bathroom morning towel happy
    with dissolve
    deni "Massage?"

    show denise_pd bathroom morning towel smiling
    with dissolve
    deni "Yes please!"

    scene black
    with fade
    scene bathroom_bg morning applylotion:
        subpixel True
        zoom 1.15 xalign 0.0 yalign 0.0
        0.5
        ease 45.0 zoom 1.0
    show denise_pd bathroom applylotion norash neck eyesclosed:
        subpixel True
        zoom 1.3 xalign 0.0 yalign 0.0
        0.5
        ease 45.0 zoom 1.0
    with fade
    "You go through what has become a steady morning ritual."

    show denise_pd bathroom applylotion norash neck
    with dissolve
    "You're not entirely sure how it ended up becoming a ritual."

    show denise_pd bathroom applylotion norash neck eyesclosed
    with dissolve
    if w02d01_s01_pc_feels == "uncomfortable":
        "Although you're not comfortable with it, you're happy your [denise_rel_to_pc] is happy."
    elif w02d01_s01_pc_feels == "indifferent":
        "You're just doing it because it makes your [denise_rel_to_pc] happy."
    elif w02d01_s01_pc_feels == "good":
        if w02d01_s01_pc_feels_good_because == "denifeelsgood":
            "But it makes your [denise_rel_to_pc] happy, and that makes you happy."
        elif w02d01_s01_pc_feels_good_because == "feelclosetodeni":
            "But you enjoy spending this time bonding with your [denise_rel_to_pc]."
        elif w02d01_s01_pc_feels_good_because == "pclikestouch":
            "But you enjoy the feel of her soft skin as your fingers slide over her body."
    else:
        "But you hope it'll help build a better relationship with your [denise_rel_to_pc]."

    show denise_pd bathroom applylotion norash neck
    with dissolve
    deni "[denise_adr_pc_as_cap]...?"

    show denise_pd bathroom applylotion norash neck eyesclosed
    with dissolve
    deni "What are you thinking about?"

    pc "Nothing much, angel."

    show denise_pd bathroom applylotion norash shoulder eyesclosed
    with dissolve
    deni "[denise_adr_pc_as_cap]..."

    show denise_pd bathroom applylotion norash shoulder
    with dissolve
    deni "I wish I could do something for you, too."

    show denise_pd bathroom applylotion norash neck
    with dissolve
    deni "Your back must be sore from sleeping on the couch."
    show denise_pd bathroom applylotion norash neck eyesclosed
    with dissolve
    deni "Maybe I can give a massage to you for a change, sometime?"

    default w02d02_s01_pc_likes_massage = False
    menu:
        "[abgreen]'Sure.'":
            $ w02d02_s01_pc_likes_massage = True
            pc "Sure, angel, I'd like that."

            show denise_pd bathroom applylotion norash shoulder eyesclosed
            with dissolve
            deni "I'll make sure you'll get a happy end, too."
            with hpunch
            pc "You'll what?!"
        "'No need.'":

            $ w02d02_s01_pc_likes_massage = False
            pc "No need, angel. I'm fine."

            show denise_pd bathroom applylotion norash shoulder
            with dissolve
            deni "But I want to do something nice for you, too."

            show denise_pd bathroom applylotion norash flanks eyesclosed
            with dissolve
            deni "I want to make you feel good. Give you a happy end."
            with hpunch
            pc "Give me what?!"

    show denise_pd bathroom applylotion norash flanks eyesclosed
    with dissolve
    deni "A happy end..."

    show denise_pd bathroom applylotion norash flanks
    with dissolve
    deni "That's what they call it when someone feels good after they had a massage, right?"

    show denise_pd bathroom applylotion norash flanks eyesclosed
    with dissolve
    deni "Like you, giving me massages with a happy end all the time."

    default w02d02_s01_pc_corrected_her = False
    menu:
        "[abgreen]Correct her.":
            $ w02d02_s01_pc_corrected_her = True
            pc "That's... not what a happy end means, angel."

            show denise_pd bathroom applylotion belly
            with dissolve
            deni "It doesn't?"
            pc "No..."
            pc "Or rather, it does mean the person getting the massage feels happy at the end."
            pc "But that's because they got a... ah... a sexy massage."

            show denise_pd bathroom applylotion belly eyesclosed
            with dissolve
            deni "Oh..."
            show denise_pd bathroom applylotion belly
            with dissolve
            deni "Ow!"
            show denise_pd bathroom applylotion belly eyesclosed
            with dissolve
            deni "I didn't know that."

            show denise_pd bathroom applylotion underboob
            with dissolve
            deni "That wouldn't be appropriate, for a [denise_rel_to_pc] to give her [pc_rel_to_denise] a massage like that, now would it?"

            show denise_pd bathroom applylotion underboob eyesclosed
            with dissolve
            deni "Not unless they were like that [group_adr_as] from the paintings."
            pc "Right..."
        "Say nothing.":

            $ w02d02_s01_pc_corrected_her = False
            pc "Er... right..."
            show denise_pd bathroom applylotion belly
            with dissolve
            deni "You'll see, I'll give you a very happy end!"
            pc "{size=-8}Oh dear.{/size}"
            show denise_pd bathroom applylotion underboob
            with dissolve
            "You massage her for a few minutes in silence."

    scene black
    with closeeyestrans

    "She adjusts her towel, and you kneel down in front of her."

    scene bathroom_bg morning applylotion thighs:
        subpixel True
        xalign 0.9 yalign 0.1
        0.5
        ease 34 zoom 1.2
    show denise pd bathroom applylotion thighs:
        subpixel True
        xalign 0.9 yalign 0.1
        0.5
        ease 34 zoom 1.4
    with openeyestrans

    deni "I like it when we can talk like this, [denise_adr_pc_as]."

    show denise pd bathroom applylotion thighs eyesclosed
    with dissolve
    deni "Not like a [pc_rel_to_denise] and [denise_rel_to_pc], but like... like friends, maybe."

    show denise pd bathroom applylotion thighs2
    with dissolve
    "She reaches out with her hand, and starts to softly stroke your cheek with the tuft of hair at the end of her braid."
    "The gesture catches you completely off guard, and sends a shiver of electricity down your back."
    show denise pd bathroom applylotion thighs2 eyesclosed
    with dissolve
    "As you stroke her thigh, she reciprocates the gesture by stroking your face."
    with hpunch
    "For the third time in a short period, your body responds to the touch of your [denise_rel_to_pc]."

    $ persistent.unlock_d_massage = True

    show denise pd bathroom applylotion thighs2 handsstill
    with dissolve
    pc "Ehm..."
    pc "That's... that's it, angel."

    deni "Thanks, [denise_adr_pc_as]!"

    scene black
    with fade
    scene bathroom_bg morning:
        zoom 1.3 yalign 1.0
    show denise_pd bathroom morning closeup embrace
    with fade

    "As before, she puts her arms around you where you sit, kneeling in front of her."
    "Her leg brushes against your groin as she hugs you."

    pc_thought "Oh please, don't let her feel that."

    scene bathroom_bg morning:
        zoom 1.3 yalign 1.0
    show denise_pd bathroom morning closeup peck
    with dissolve
    deni "Mwah!"

    show denise_pd bathroom morning closeup embrace
    with dissolve
    deni "[denise_adr_pc_as_cap]..."
    deni "Are you okay?"

    scene bathroom_bg morning:
        subpixel True
        xalign 0.5 yalign 1.0 zoom 1.2
        0.5
        ease 2.3 zoom 1.1
    show denise_pd bathroom morning towel smiling:
        subpixel True
        xalign 0.5 yalign 1.0 zoom 1.4
        0.5
        ease 2.3 zoom 1.2
    with dissolve
    pc "Yes!"
    pc "Never better."

    pc_thought "I can't stand up now."
    pc_thought "Not like this."

    menu:
        "Think fast!":
            pc "Angel, do you think maybe you could get dressed in your room?"
            pc "I ah... I really need to pee."

    show denise_pd bathroom morning towel neutral
    with dissolve
    deni "Eh... sure."

    show denise_pd bathroom morning towel unhappy
    with dissolve
    deni "Let me just get my stuff."

    play audio [ "<silence 4.7>", "sounds/doorslam.ogg" ]
    show denise_pd bathroom morning towel neutral:
        subpixel True
        0.5
        ease 1.2 xanchor 0.5 xpos 1.0
        0.4
        ease 2.1 xanchor 1.0 xpos 0.0
    with dissolve

    "You're still kneeling and pretending to rub at a stain on the floor as she leaves the bathroom."

    show bathroom_bg morning:
        ease 1.3 zoom 1.0

    default w02d02_s01_take_care_of_it = True
    menu:
        "[abgreen]Take care of it.":
            $ w02d02_s01_take_care_of_it = True
            pc_thought "I really need to take care of this once and for all."
            pc_thought "It's a stroke of luck that I have my phone with me."

            show pc_pd bathroom morning phone searchporn:
                subpixel True
                ypos 1.0 yanchor 0.0
                ease 2.8 yalign 0.5
            with dissolve

            call w01d06_s04_select_actress from _call_w01d06_s04_select_actress_2

            call music_fade_slow from _call_music_fade_slow_122
            scene black
            with fade
            "The video starts loading..."
        "Wait it out.":

            $ w02d02_s01_take_care_of_it = False
            call music_fade_slow from _call_music_fade_slow_123
            scene black
            with fade
            "You decide to wait it out."


    pause 2.0

    return
