label w01d06_s06:
    "Half an hour later, the pizzas are delivered and you install yourselves in the living room for a movie."

    scene livingroom_couch_bg night eatpizza:
        subpixel True
        xalign 0.7 yalign 0.0 zoom 1.2
        ease 15.0 zoom 1.0 xalign 0.5
    show denise_macy_pd livingroom night pizza eat:
        subpixel True
        xalign 0.7 yalign 0.0 zoom 1.4
        ease 15.0 zoom 1.0 xalign 0.5
    with fade

    macy "Ugh. Keep that rank stuff away from me."
    deni "You don't know what you're missing."
    macy "It smells funky."
    deni "I know, but it tastes great."
    deni "[denise_adr_pc_as_cap] likes my flavour right? Even if it smells a bit funky?"

    default w01d06_s06_mc_chose_flavour = False
    $ w01d06_s06_mc_chose_flavour = True
    default w01d06_s06_mc_likes_flavour = False
    menu:
        "[abgreen]'Yes I do.'":
            $ w01d06_s06_mc_likes_flavour = True
            pc "Yes I do angel. I love your flavour, even if it smells a bit funky."
            show livingroom_couch_bg night eatpizza:
                ease 10.0 zoom 1.2 xalign 0.2
            show denise_macy_pd livingroom night pizza feed:
                ease 10.0 zoom 1.4 xalign 0.2
            with dissolve
            deni "See?"
            macy "Sheesh, if I'd just walked in, that line would have sounded sooo wrong."
            deni "You're just jealous [denise_adr_pc_as] didn't say he likes your flavour."
            macy "As if."
            deni "Here, [denise_adr_pc_as], have another taste."
        "'Not really.'":

            $ w01d06_s06_mc_likes_flavour = False
            pc "I'm not really a fan of those moldy flavours."
            macy "See?"
            deni "Hmpf."

    if w01d05_s05_pc_picked_movie:
        show livingroom_couch_bg night eatpizza:
            ease 15.0 zoom 1.0 xalign 0.5
        show denise_macy_pd livingroom night pizza eat:
            ease 15.0 zoom 1.0 xalign 0.5
        with dissolve
        "While you're eating, you propose three different movies."
        "With each synopsis, you see the interest in your girls eyes waning."

        pc "Alright, I give up."
        pc "Put on what you like."
        scene black
        with fade

        deni "Yay!"
    else:

        deni "Now, I get to choose the movie."
        scene black
        with fade

    "[denise_name] quickly flicks through the menu to select a movie she likes."

    scene livingroom_couch_bg night eatpizza
    show denise_macy_pd livingroom night pizza lookmovie
    show black:
        alpha 0.0
    with fade

    "It turns out to be a superhero movie about a young woman from an ancient warrior cult fighting her way through a contemporary war."

    show denise_macy_pd livingroom night pizza lookmovie3
    with dissolve
    "But it's not half bad, and the lead actress is quite easy on the eyes."

    show denise_macy_pd livingroom night pizza lookmovie
    with dissolve
    if not w01d06_s01_groped_denise:
        deni "Rub my tummy, [denise_adr_pc_as]?"

        show denise_macy_pd livingroom night pizza lookmovie bellyrub
        with dissolve
        pc "Sure, angel."
    else:
        "Your [denise_rel_to_pc]s seem to enjoy it too."

    show livingroom_couch_bg night eatpizza:
        subpixel True
        yalign 0.0
        ease 10.0 zoom 1.2 xalign 0.9
    show denise_macy_pd livingroom night pizza lookmovie3 bellyrub conditional:
        subpixel True
        yalign 0.0
        ease 10.0 zoom 1.4 xalign 0.9
    with dissolve
    "Halfway through the movie, you steal a glance at your eldest [macy_rel_to_pc]."

    show denise_macy_pd livingroom night pizza lookmovie bellyrub conditional
    with dissolve
    "She notices your furtive look from the corner of her eyes."

    show denise_macy_pd livingroom night pizza lookmovie3 bellyrub conditional
    with dissolve
    "Without looking up, she calls you out."

    show denise_macy_pd livingroom night pizza lookmovie bellyrub conditional
    with dissolve
    macy "What? Do I have sauce on my cheek?"

    menu:
        "[abgreen]Compliment her.":
            pc "No, just thinking to myself my [macy_rel_to_pc] is a beautiful woman."

            show denise_macy_pd livingroom night pizza lookmovie2 bellyrub conditional
            with dissolve
            macy "Yeah, right. Sorry I asked."
            "As she turns her attention back to the movie, you can see a faint smile playing around her lips."
            if macy_love < 5:
                call macy_add_love from _call_macy_add_love_1

            show livingroom_couch_bg night eatpizza:
                subpixel True
                ease 10.0 zoom 1.0 xalign 0.5
            show denise_macy_pd livingroom night pizza lookmovie2 bellyrub conditional:
                subpixel True
                ease 10.0 zoom 1.0 xalign 0.5
            with dissolve
        "Don't.":

            "You're not above latching on to an excuse when it's handed to you."
            pc "Yeah you do."
            pc "Just... there a bit..."
            "You make a vague gesture across your cheek with your right hand."

            show black:
                alpha 1.0
            with dissolve
            "She starts rubbing at the nonexistent stain while you turn your attention back to the movie."

            show black:
                alpha 0.0
            show livingroom_couch_bg night eatpizza:
                subpixel True
                0.5
                ease 10.0 zoom 1.0 xalign 0.5
            show denise_macy_pd livingroom night pizza lookmovie bellyrub conditional:
                subpixel True
                0.5
                ease 10.0 zoom 1.0 xalign 0.5
            with dissolve

    "The movie finishes."
    if w01d05_s05_pc_picked_movie:
        pc "I have to admit, I enjoyed that."

        show denise_macy_pd livingroom night pizza lookmovie3 bellyrub conditional
        with dissolve
        deni "Yah. And it didn't need {i}an interesting meta-story that twists and subverts common horror movie tropes{/i}."

        show denise_macy_pd livingroom night pizza lookmovie bellyrub conditional
        with dissolve
        macy "Although that one did have that actor from Thor going for it..."

        show denise_macy_pd livingroom night pizza lookmovie3 bellyrub conditional
        with dissolve
        pc "So you were paying attention."
    else:
        pc "Good choice."

        show denise_macy_pd livingroom night pizza lookmovie3 bellyrub conditional
        with dissolve
        deni "See, and not a single puppy in the entire movie."

        show denise_macy_pd livingroom night pizza lookmovie bellyrub conditional
        with dissolve
        macy "Yeah. I'm impressed."

    $ persistent.unlock_naked_pizza_night = True

    scene black
    with fade
    "You clean up the leftovers together."
    "[macy_name] goes to the bathroom, and [denise_name] decides to hang with you for a few more minutes."

    scene livingroom_couch_bg night
    show denise_pd livingroom night couch talk
    with fade
    deni "I enjoyed hanging out with both of you."

    show denise_pd livingroom night couch thoughtfull
    with dissolve
    deni "And you didn't argue once."

    show denise_pd livingroom night couch talk
    with dissolve
    deni "Well, nothing serious anyway."

    show denise_pd livingroom night couch headrub happy
    with dissolve
    deni "I like us doing fun things together as a [group_adr_as], like we used to do."

    menu:
        "[abgreen]Agree.":
            pc "Yeah, I loved it."
            pc "We should do this more often."

            show denise_pd livingroom night couch headrub happy eyesclosed
            with dissolve
        "Say nothing.":

            pc "..."

            show denise_pd livingroom night couch headrub sad
            with dissolve

    "You hear the bathroom door opening and closing."

    show denise_pd livingroom night couch thoughtfull
    with dissolve
    deni "Oh, [macy_name]'s done."

    show denise_pd livingroom night couch askjoin
    with dissolve
    deni "Goodnight, [denise_adr_pc_as]."

    if macy_love >= 5:
        "[macy_name] puts her head round the door."
        macy "Goodnight, [player_name]."

        show denise_pd livingroom night couch empty
        with dissolve

        call music_fade_slow from _call_music_fade_slow_90

        pc "Goodnight, angel. Goodnight, princess."
        play audio [ "<silence 0.7>", "sounds/doorslam.ogg" ]
        macy "Hmpf."
        deni "Hey, don't slam the door in my face! I was going to the bathroom."
    else:

        call music_fade_slow from _call_music_fade_slow_91

        show denise_pd livingroom night couch empty
        with dissolve
        pc "Goodnight, angel."

    scene black
    with fade

    pause 2.0

    return
