label w02d03_s08:

    call theme_household from _call_theme_household_7

    scene kitchen_bg lookatsink nighttime
    show denise_pd kitchen night unhappy:
        subpixel True
        xanchor 1.0 xpos 0.0 yalign 1.0
        0.5
        easein 0.9 xalign 0.0
    show macy_pd kitchen night workwear sad:
        subpixel True
        xanchor 0.0 xpos 1.0 yalign 1.0
        1.2
        easein 1.9 xalign 1.0
    with fade
    "When you get home, [denise_name] is anxiously awaiting your arrival."

    show denise_pd kitchen night unhappy:
        subpixel True
        0.5
        parallel:
            ease 1.8 xalign 0.7
            parallel:
                choice:
                    2.2
                choice:
                    1.2
                choice:
                    0.7
                choice:
                    0.5
                pass


                choice:
                    ease 1.9 xalign 0.2
                choice:
                    ease 2.3 xalign 0.2
                pass


                choice:
                    2.2
                choice:
                    1.2
                choice:
                    0.7
                choice:
                    0.5
                pass


                choice:
                    ease 1.9 xalign 0.8
                choice:
                    ease 2.3 xalign 0.8

                repeat
            parallel:

                choice:
                    0.4
                choice:
                    1.2
                choice:
                    3.1
                ease 0.15 zoom 1.01
                ease 0.15 zoom 1.0
                repeat
    show macy_pd kitchen night workwear sad:
        0.5
        ease 2.6 xalign 0.5
    with dissolve
    "She hops around [macy_name], inspecting her from each side."

    show macy_pd kitchen night workwear eyeroll
    with dissolve
    macy "Quit jumping around me like a hungry cat. I'm fine!"

    show denise_pd kitchen night angry
    with dissolve
    deni "You could have been hurt!"

    show denise_pd kitchen night unhappy
    with dissolve
    deni "Badly!"

    show denise_pd kitchen night angry
    with dissolve

    deni "I'm not taking any chances."

    show macy_pd kitchen night workwear shocked
    with dissolve
    macy "What, you think you're gonna find a knife sticking out of my back that they missed at the police station?"

    show denise_pd kitchen night unhappy
    with dissolve

    deni "Don't joke about that!"

    show macy_pd kitchen night workwear thoughtful
    with dissolve
    macy "Sorry."

    show macy_pd kitchen night workwear frown:
        2.1
        ease 1.8 xalign 0.75
    show denise_pd kitchen night unhappy:
        1.5
        parallel:
            ease 0.1 zoom 1.01
            ease 0.1 zoom 1.0
        parallel:
            ease 1.3 xalign 0.25
    with dissolve
    macy "Now stop moving around or I swear to god I'll trip you up!"

    show macy_pd kitchen night workwear neutral
    with dissolve
    macy "Thank you!"

    show denise_pd kitchen night angry
    with dissolve
    deni "You're not walking home alone in the dark anymore."

    show macy_pd kitchen night workwear eyeroll
    with dissolve
    macy "Well how am I going to get home from work then?"

    show denise_pd kitchen night smile
    with dissolve
    deni "[denise_adr_pc_as_cap]'s going to pick you up."

    show denise_pd kitchen night neutral
    with dissolve
    deni "And drop you off."

    show macy_pd kitchen night workwear shocked
    with dissolve
    macy "That's ridiculous. It's not even dark when I go to work."

    show denise_pd kitchen night angry
    with dissolve
    deni "Well, he {i}is{/i} going to pick you up at night."

    default w02d03_s08_pc_objected = False
    menu:
        "[abgreen]Agree.":
            $ w02d03_s08_pc_objected = False
            pc "I can do that."
            show denise_pd kitchen night happy
            with dissolve
            deni "See! [denise_adr_pc_as_cap] agrees."

            show denise_pd kitchen night angry
            with dissolve
            deni "I'm not going to take no for an answer."

            show macy_pd kitchen night workwear eyeroll
            with dissolve
            macy "Fine."

            show denise_pd kitchen night happy
            with dissolve
            deni "..."
        "Object.":

            $ w02d03_s08_pc_objected = True
            pc "Hey, I didn't agree to anything."

            show denise_pd kitchen night unhappy
            with dissolve
            with hpunch
            deni "[denise_adr_pc_as_cap]!"

            show denise_pd kitchen night angry
            with dissolve
            deni "[macy_name] is not going to walk home in the dark, and that's final!"

            show denise_pd kitchen night neutral
            with dissolve
            deni "I'm not going to take no for an answer."
            "You realize that it's no use arguing."
            pc "If you feel that strongly about it, angel..."

            show denise_pd kitchen night angry
            with dissolve
            deni "I do."

            show denise_pd kitchen night happy
            with dissolve
            deni "[macy_name], you're riding home with [denise_adr_pc_as] from now on."

            show macy_pd kitchen night workwear eyeroll
            with dissolve
            macy "Fine."

    show macy_pd kitchen night workwear neutral
    with dissolve
    macy "Now, if you'll excuse me, I really want to clean up and go to bed."

    play audio [ "<silence 1.8>", "sounds/doorslam.ogg" ]
    show macy_pd kitchen night workwear neutral:
        subpixel True
        easeout 1.8 xanchor 0.0 xpos 1.0
    show denise_pd kitchen night happy:
        subpixel True
        1.2
        ease 0.7 xalign 0.5

    "She leaves the room."

    show denise_pd kitchen night unhappy
    with dissolve
    "[denise_name] gives you a pained look."

    show denise_pd kitchen night angry
    with dissolve
    deni "You keep her safe from now on, [denise_adr_pc_as]! You hear?"
    pc "I hear you, angel."

    show denise_pd kitchen night happy
    with dissolve
    deni "Good. Thank you."

    show denise_pd kitchen night neutral
    with dissolve
    deni "Goodnight."

    call music_fade_slow from _call_music_fade_slow_96
    play audio [ "<silence 1.8>", "sounds/doorslam.ogg" ]
    show denise_pd kitchen night neutral:
        subpixel True
        easeout 1.8 xanchor 0.0 xpos 1.0
    "She hurries after her [macy_rel_to_denise], anxious to make sure she's doing okay."

    pc "Goodnight, angel!"

    scene black
    with fade
    pause 2.0

    return
