label w02d02_s07:

    call theme_pc_sad from _call_theme_pc_sad_6

    scene backdrop darkblue
    show setpiece livingroom night pc sleepcouch:
        subpixel True
        zoom 1.2 xalign 0.2 yalign 0.2
        0.5
        ease 29 zoom 1.0
    with fade

    "Sleep doesn't come easy."

    $ w02d02_s06_thought_about_home = False
    $ w02d02_s06_thought_about_work = False
    $ w02d02_s06_tried_to_fall_asleep = False

    label w02d02_s06_try_to_fall_asleep:
    menu:
        "[abgreen]Think about your home situation." if not w02d02_s06_thought_about_home:
            $ w02d02_s06_thought_about_home = True
            "You think about the situation at home."
            pc_thought "[denise_name] seems happy when she's at home, but I'm worried that she has trouble leaving the house."
            pc_thought "The constant arguments [macy_name] and I keep having don't help with that either."
            pc_thought "And I should definitely get a handle on these embarrassing reactions my body's been having in the presence of my [denise_rel_to_pc]."

        "[abgreen]Think about work." if not w02d02_s06_thought_about_work:
            $ w02d02_s06_thought_about_work = True
            "You think about the situation at work."
            if w02d01_s02_agree:
                pc_thought "What the hell was I thinking last Monday?!"
                pc_thought "That stunt with [brooke_name] was absolutely crazy."
                pc_thought "I could lose my job over it."
                pc_thought "If that happened, we could lose the house."
                if not w01d04_s03_rejected_brooke:
                    pc_thought "And there's more."

            if not w01d04_s03_rejected_brooke:
                pc_thought "I'm not sure what is happening between [brooke_name] and me..."
                pc_thought "...but [macy_name]'s made it quite clear she's having none of it."
                pc_thought "I really don't need to introduce another reason for us to butt heads."

            if (not w02d01_s02_agree) and w01d04_s03_rejected_brooke:
                pc_thought "It's nice that [brooke_name] and I get along as colleagues..."
                pc_thought "...but it's got me thinking about this job."
                pc_thought "Do I really want to spend the rest of my life in a cubicle working for a slowly dying company?"
                pc_thought "It's only a matter of time before the next round of downsizing, and that could be it for me."

        "Try to focus on falling asleep." if not w02d02_s06_tried_to_fall_asleep:
            $ w02d02_s06_tried_to_fall_asleep = True
            "You try to focus on falling asleep, clearing your mind deliberately."
            "Of course, it doesn't work."

    if not (w02d02_s06_thought_about_home and w02d02_s06_thought_about_work):
        jump w02d02_s06_try_to_fall_asleep

    call music_fade_slow from _call_music_fade_slow_84

    "You toss and turn, waiting for the sweet release of sleep to claim you."

    scene black
    with closeeyestrans
    "Finally, it does."

    pause 2.0

    return
