label w01d04_s01:
    scene black
    show text "{size=+18}{font=fonts/typeo___.ttf}Thursday...{/font}{/size}" at truecenter
    with fade
    $ renpy.pause(2.0, hard='True')

    scene black
    with fade

    deni "{size=-4}[denise_adr_pc_as_cap]...{/size}"

    pc "Mnyeah...?"

    call theme_denise from _call_theme_denise_5
    deni "[denise_adr_pc_as_cap]!"

    scene setpiece kitchen morning denise towel wakeup
    with openeyestrans

    deni "Are you coming?"
    pc "<yawn>"
    pc "Oh, is it that time again?"

    deni "Yeah..."

    pc "I'll be right there..."

    scene black
    with fade
    "You get up and join [denise_name] in the bathroom, again."

    scene setpiece hallway morning bathroomdoor
    with fade
    menu:
        "[abgreen]Knock.":
            "You knock."
            deni "You can come in."
        "Just enter.":

            "The door is unlocked."

    scene bathroom_bg morning
    show denise_pd bathroom morning lowertowel unhappy
    with fade
    "You enter the bathroom."
    deni "I'm ready, [denise_adr_pc_as]."

    show denise_pd bathroom morning lowertowel lifthair rash
    with dissolve
    "She turns around and lifts her hair up as you put some of the ointment on your hands."

    scene setpiece bathroom morning denise applylotion shoulders
    with fade
    "You begin massaging the liquid into her skin, concentrating on the angry red spots."

    menu:
        "[abgreen]Make smalltalk.":
            pc "How are you feeling this morning, angel?"

            show setpiece bathroom morning denise applylotion shoulders closedeyes
            with dissolve
            deni "Okay, I guess."
            if w01d03_s08_understanding_home_evening:
                deni "At least I don't have to go outside for a while."

                show setpiece bathroom morning denise applylotion shoulders
                with dissolve
                deni "I get really anxious just thinking about it."
                pc "Well, don't. At least not yet."
                pc "First, I want you to calm down and build up some confidence."

                show setpiece bathroom morning denise applylotion shoulders closedeyes
                with dissolve
                deni "Thank you, [denise_adr_pc_as]."
            else:
                deni "Just..."

                show setpiece bathroom morning denise applylotion shoulders
                with dissolve
                deni "When I think about having to go back to school soon..."
                deni "I get really anxious."
                pc "I know angel."
                pc "But it's for the best. You'll thank me later."

                show setpiece bathroom morning denise applylotion shoulders closedeyes
                with dissolve
                deni "If you say so [denise_adr_pc_as]."
        "Don't.":
            show setpiece bathroom morning denise applylotion shoulders closedeyes
            with dissolve
            "You rub the ointment on the red spots on her skin in silence."

    show setpiece bathroom morning denise applylotion back
    with dissolve
    "The massaging action of your fingers rubbing in the ointment seems to relax [denise_name]."

    show setpiece bathroom morning denise applylotion back closedeyes
    with dissolve
    "She closes her eyes as you move your hands gently over her skin."
    deni "<sigh>"

    pc "Does it feel good, angel?"

    show setpiece bathroom morning denise applylotion back
    with dissolve
    deni "Yes, [denise_adr_pc_as]."

    menu:
        "[abgreen]Talk about the rash.":
            pc "It's looking a bit better today."

            show setpiece bathroom morning denise applylotion back closedeyes
            with dissolve
            deni "It feels better too. Less itchy than yesterday"
            show setpiece bathroom morning denise applylotion back
            with dissolve
            deni "But I think I felt a few new spots on my back."

            show setpiece bathroom morning denise applylotion shoulders closedeyes
            with dissolve
            pc "Don't worry, I'll apply some ointment to those as well."

            show setpiece bathroom morning denise applylotion back closedeyes
            with dissolve
            pc "You're not scratching it, are you?"
            deni "No, [denise_adr_pc_as]."

            show setpiece bathroom morning denise applylotion back
            with dissolve
            deni "Well, maybe a {i}little{/i} bit. But only when it gets real bad."

            show setpiece bathroom morning denise applylotion flanks
            with dissolve
            pc "Well, stop it."
            deni "Sorry. I'll try not to do it anymore."
        "Don't.":

            show setpiece bathroom morning denise applylotion back closedeyes
            with dissolve
            "You keep massaging in the ointment."

    show setpiece bathroom morning denise applylotion flanks closedeyes
    with dissolve
    pc "Almost done."

    show setpiece bathroom morning denise applylotion flanks
    with dissolve
    deni "Already?"
    "She sounds a little disappointed."

    show setpiece bathroom morning denise applylotion flanks closedeyes
    with dissolve
    deni "I think I could get used to these early morning massages."

    default w01d04_s01_pc_enjoys_massage_too = True
    menu:
        "[abgreen]'Me too...'":
            $ w01d04_s01_pc_enjoys_massage_too = True
            show setpiece bathroom morning denise applylotion back closedeyes
            with dissolve
            pc "Me too, angel."
            show setpiece bathroom morning denise applylotion flanks closedeyes
            with dissolve
            pc "I enjoy making you feel better."

            show setpiece bathroom morning denise applylotion flanks
            with dissolve
        "Say nothing.":

            $ w01d04_s01_pc_enjoys_massage_too = False
            show setpiece bathroom morning denise applylotion flanks
            with dissolve
            pc "..."

    pc "Aaaand... we're done."
    deni "Thank you, [denise_adr_pc_as]."

    scene bathroom_bg morning
    show denise_pd bathroom morning lowertowel happy
    with fade
    "She turns around."

    deni "Close your eyes while I adjust my towel, [denise_adr_pc_as]."

    scene black
    with closeeyestrans

    deni "..."
    deni "Okay, you can look again"

    scene bathroom_bg morning
    show denise_pd bathroom morning towel happy
    with openeyestrans

    deni "It felt real nice, [denise_adr_pc_as]."

    if w01d04_s01_pc_enjoys_massage_too:
        show denise_pd bathroom morning closeup embrace
        with dissolve
        pause 1.0
        show denise_pd bathroom morning closeup peck
        with dissolve
        deni "Mwah."

        show denise_pd bathroom morning closeup embrace
        with dissolve
        pc "Now {i}I{/i} could get used to this post-massage TLC."
        deni "You deserve a little reward for taking such good care of me, [denise_adr_pc_as]!"

    call music_fade_slow from _call_music_fade_slow_20
    show denise_pd bathroom morning towel smiling
    with dissolve
    deni "Now, you know the drill..."

    call sound_doorslam from _call_sound_doorslam_1
    scene setpiece hallway morning bathroomdoor
    with hpunch
    "Again, you are persuasively ushered out."

    pc_thought "Incredible... these girls could make a fortune working as nightclub bouncers."

    scene black
    with fade
    "You leave [denise_name] to finish up in the bathroom."

    return
