label w04d01_s06:

    "The drive home is uneventful."

    if denise_locked_out or macy_locked_out:

        scene kitchen_bg dinnertable evening:
            subpixel True
            xalign 0.8 yalign 0.3 zoom 1.0
            0.5
            ease 14.3 zoom 1.05
        show denise_pd kitchen evening eating takebite:
            subpixel True
            xalign 0.9 yalign 0.2 zoom 1.0
            0.5
            ease 14.3 zoom 1.1
        show macy_pd kitchen evening eating lookdenise:
            subpixel True
            xalign 0.9 yalign 0.2 zoom 1.0
            0.5
            ease 14.3 zoom 1.1
        with fade
        "You have dinner with your girls."
        jump w04d01_s06_end_scene

    call theme_household_beauty from _call_theme_household_beauty_1

    scene kitchen_bg evening:
        subpixel True
        xalign 0.5 yalign 0.3
    show macy_pd kitchen_lookatsink workwear evening neutral:
        subpixel True
        xalign 0.2 yalign 0.3
        ease 2.2 xpos 0.0 xanchor 1.0
    show denise_pd kitchen_lookatsink evening camisole neutral:
        subpixel True
        xalign 0.4 yalign 0.3
        0.5
        ease 2.1 xalign 0.1
    with fade
    "You arrive home to find your girls setting the table for dinner."

    show kitchen_bg evening
    show denise_pd kitchen_lookatsink evening camisole happy:
        0.5
        ease 2.4 xalign 0.5
    show macy_pd kitchen_lookatsink workwear evening neutral
    with dissolve
    deni "Hi, [denise_adr_pc_as]."

    if denise_love >= 9:
        default w04d01_s06_denise_peck = False
        $ w04d01_s06_denise_peck = True

        show kitchen_bg evening
        show denise_pd kitchen_lookatsink evening camisole closeup hug
        show macy_pd kitchen_lookatsink workwear evening neutral
        with dissolve
        pause 0.4

        show kitchen_bg evening
        show denise_pd kitchen_lookatsink evening camisole closeup peck
        show macy_pd kitchen_lookatsink workwear evening shocked:
            0.5
            easein 1.1 xpos 0.0 xanchor 0.4
        with dissolve
        pause 0.7

        show kitchen_bg evening
        show denise_pd kitchen_lookatsink evening camisole closeup hug
        show macy_pd kitchen_lookatsink workwear evening shocked
        with dissolve
        deni "Mmmmmwah!"


    show kitchen_bg evening
    show denise_pd kitchen_lookatsink evening camisole smile
    show macy_pd kitchen_lookatsink workwear evening shocked:
        0.5
        easeout 1.3 xpos 0.0 xanchor 1.0
    with dissolve
    deni "I made something special for your dinner today."

    menu:
        "'That's nice.'":
            pc "That's nice, angel."

    show kitchen_bg evening
    show denise_pd kitchen_lookatsink evening camisole unhappy:
        0.5
        0.4
        parallel:
            ease 0.7 xalign 0.6
            0.3
            ease 1.1 xalign 0.5
        parallel:
            ease 0.1 zoom 1.05 yalign 1.0
            ease 0.1 zoom 1.00 yalign 0.3
    show macy_pd kitchen_lookatsink workwear evening rolleyes:
        0.5
        easein 1.1 xpos 0.0 xanchor 0.4
    with dissolve
    macy "It's not."

    show kitchen_bg evening
    show denise_pd kitchen_lookatsink evening camisole angry:
        0.5
        ease 0.9 xalign 0.4
    show macy_pd kitchen_lookatsink workwear evening rolleyes:
        0.5
        1.1
        easeout 1.1 xpos 0.0 xanchor 1.0
    with dissolve
    deni "Sshh!"

    show kitchen_bg evening
    show denise_pd kitchen_lookatsink evening camisole happy:
        0.5
        ease 1.9 xalign 0.5
    show macy_pd kitchen_lookatsink workwear evening rolleyes
    with dissolve
    if denise_love >= 9:
        deni "I made it because I love you a lot, [denise_adr_pc_as]!"
    elif denise_love >= 6:
        deni "I made it because I love you, [denise_adr_pc_as]!"
    else:
        deni "I made it because I care for you, [denise_adr_pc_as]."

    show kitchen_bg evening
    show denise_pd kitchen_lookatsink evening camisole unhappy:
        0.5
        0.3
        parallel:
            ease 0.7 xalign 0.6
            0.3
            ease 1.1 xalign 0.5
        parallel:
            ease 0.1 zoom 1.05 yalign 1.0
            ease 0.1 zoom 1.00 yalign 0.3
    show macy_pd kitchen_lookatsink workwear evening smile:
        0.5
        easein 1.1 xpos 0.0 xanchor 0.4
    with dissolve
    macy "What's that thing they say again, about hurting the ones we love the most?"

    show kitchen_bg evening
    show denise_pd kitchen_lookatsink evening camisole angry:
        0.5
        parallel:
            ease 0.7 xalign 0.3
        parallel:
            ease 0.1 zoom 1.05 yalign 1.0
            ease 0.1 zoom 1.00 yalign 0.3
    show macy_pd kitchen_lookatsink workwear evening shocked:
        0.5
        parallel:
            0.3
            ease 0.1 zoom 1.05 yalign 1.0
            ease 0.1 zoom 1.00 yalign 0.3
        parallel:
            0.8
            easeout 1.1 xpos 0.0 xanchor 1.0
    with dissolve
    deni "[macy_name]!"

    show kitchen_bg evening
    show denise_pd kitchen_lookatsink evening camisole happy:
        0.5
        ease 1.2 xalign 0.5
    show macy_pd kitchen_lookatsink workwear evening shocked
    with dissolve
    deni "It's full of good flavours."

    show denise_pd kitchen_lookatsink evening camisole angry:
        0.5
        0.3
        ease 0.4 xalign 0.55
        0.3
        ease 0.9 xalign 0.4
    show macy_pd kitchen_lookatsink workwear evening neutral:
        0.5
        easein 1.1 xpos 0.0 xanchor 0.4
    with dissolve
    macy "It's a salad."

    show denise_pd kitchen_lookatsink evening camisole unhappy:
        0.5
        0.4
        ease 1.7 xalign 0.5
    show macy_pd kitchen_lookatsink workwear evening neutral:
        0.5
        easein 1.1 xpos 0.0 xanchor 1.0
    with dissolve
    deni "It's... it's a salad."

    show denise_pd kitchen_lookatsink evening camisole smile
    show macy_pd kitchen_lookatsink workwear evening neutral
    with dissolve
    deni "But it's got celery and papayas and nice fresh herbs, and a dressing made with lemon."

    show denise_pd kitchen_lookatsink evening camisole angry:
        0.5
        0.2
        ease 0.1 zoom 1.05 yalign 1.0
        ease 0.1 zoom 1.00 yalign 0.3
    show macy_pd kitchen_lookatsink workwear evening rolleyes:
        0.5
        easein 1.1 xpos 0.0 xanchor 0.4
    with dissolve
    macy "It's a salaaaad."

    show denise_pd kitchen_lookatsink evening camisole neutral
    show macy_pd kitchen_lookatsink workwear evening rolleyes:
        0.5
        easein 1.1 xpos 0.0 xanchor 1.0
    with dissolve
    default w04d01_s06_ate_salad_meal = False
    default w04d01_s06_ate_salad_side = False
    menu:
        "[abgreen]'Thank you.'":
            $ w04d01_s06_ate_salad_meal = True
            pc "Thank you angel. That sounds really nice."
            call w04d01_s06_yay from _call_w04d01_s06_yay
        "'No, thank you.'":

            pc "Ah... thanks, but no thanks, angel."
            pc "I don't really like salads."

            show denise_pd kitchen_lookatsink evening camisole unhappy
            show macy_pd kitchen_lookatsink workwear evening neutral
            with dissolve
            deni "Aww..."

            show denise_pd kitchen_lookatsink evening camisole angry:
                0.5
                0.2
                ease 0.1 zoom 1.05 yalign 1.0
                ease 0.1 zoom 1.00 yalign 0.3
            show macy_pd kitchen_lookatsink workwear evening rolleyes:
                0.5
                easein 1.1 xpos 0.0 xanchor 0.4
            with dissolve
            macy "Told you..."

            show denise_pd kitchen_lookatsink evening camisole unhappy
            show macy_pd kitchen_lookatsink workwear evening neutral:
                0.5
                easein 1.1 xpos 0.0 xanchor 1.0
            with dissolve
            deni "Will you at least eat some of it, [denise_adr_pc_as]? As a side?"

            menu:
                "'Alright.'":
                    $ w04d01_s06_ate_salad_side = True
                    pc "Alright, angel. If it means that much to you."
                    call w04d01_s06_yay from _call_w04d01_s06_yay_1
                "'No.'":

                    pc "No thank you, angel."

                    show denise_pd kitchen_lookatsink evening camisole unhappy
                    show macy_pd kitchen_lookatsink workwear evening frown:
                        0.5
                        easein 1.1 xpos 0.0 xanchor 0.3
                    with dissolve
                    macy "Stop pushing [macy_adr_pc_as_nice]. He said he doesn't want it."

                    show denise_pd kitchen_lookatsink evening camisole angry:
                        0.5
                        ease 1.8 xalign 0.4
                    show macy_pd kitchen_lookatsink workwear evening frown
                    with dissolve
                    deni "I'm doing this for your benefit too, you know."

                    show denise_pd kitchen_lookatsink evening camisole angry:
                        0.5
                        0.7
                        easeout 4.1 xpos 0.0 xanchor 1.0
                    show macy_pd kitchen_lookatsink workwear evening shocked:
                        0.5
                        easeout 3.1 xpos 0.0 xanchor 1.0
                    with dissolve
                    macy "Leave me out of this, please."

    if w04d01_s06_ate_salad_meal:
        scene kitchen_bg dinnertable evening:
            subpixel True
            xalign 0.8 yalign 0.3 zoom 1.0
            0.5
            ease 14.3 zoom 1.05
        show denise_pd kitchen evening eating happy:
            subpixel True
            xalign 0.8 yalign 0.3 zoom 1.0
            0.5
            ease 14.3 zoom 1.1
        show macy_pd kitchen evening eating lookdenise:
            subpixel True
            xalign 0.8 yalign 0.3 zoom 1.0
            0.5
            ease 14.3 zoom 1.1
        with fade
        "You have your dinner, your girls eating the usual and you having the salad your [denise_rel_to_pc] made for you."
        "As salads go, it's actually not bad."
    elif w04d01_s06_ate_salad_side:
        scene kitchen_bg dinnertable evening:
            subpixel True
            xalign 0.8 yalign 0.3 zoom 1.0
            0.5
            ease 14.3 zoom 1.05
        show denise_pd kitchen evening eating neutral:
            subpixel True
            xalign 0.8 yalign 0.3 zoom 1.0
            0.5
            ease 14.3 zoom 1.1
        show macy_pd kitchen evening eating lookdenise:
            subpixel True
            xalign 0.8 yalign 0.3 zoom 1.0
            0.5
            ease 14.3 zoom 1.1
        with fade

        "You have your usual dinner, with some of the salad your [denise_rel_to_pc] made on the side."
        "As salads go, it's actually not bad."
    else:
        scene kitchen_bg dinnertable evening:
            subpixel True
            xalign 0.8 yalign 0.3 zoom 1.0
            0.5
            ease 34.3 zoom 1.05
        show denise_pd kitchen evening eating upset:
            subpixel True
            xalign 0.8 yalign 0.3 zoom 1.0
            0.5
            ease 34.3 zoom 1.1
        show macy_pd kitchen evening eating lookdenise:
            subpixel True
            xalign 0.8 yalign 0.3 zoom 1.0
            0.5
            ease 34.3 zoom 1.1
        with fade

        "You have your usual dinner."

    if w04d01_s06_ate_salad_meal or w04d01_s06_ate_salad_side:
        pc "That's pretty tasty, angel."

        show kitchen_bg dinnertable evening
        show denise_pd kitchen evening eating neutraltalk
        show macy_pd kitchen evening eating lookdenise
        with dissolve
        deni "Thank you, [denise_adr_pc_as]."

        show kitchen_bg dinnertable evening
        show denise_pd kitchen evening eating neutraltalk
        show macy_pd kitchen evening eating unhappy
        with dissolve
        macy "For real?"

        show kitchen_bg dinnertable evening
        show denise_pd kitchen evening eating angryatmacy
        show macy_pd kitchen evening eating unhappy
        with dissolve
        deni "[macy_name]!"

        show kitchen_bg dinnertable evening
        show denise_pd kitchen evening eating angryatmacy
        show macy_pd kitchen evening eating underbreath
        with dissolve
        macy "Just askin'."

        show kitchen_bg dinnertable evening
        show denise_pd kitchen evening eating happy
        show macy_pd kitchen evening eating underbreath
        with dissolve
        deni "If you like, I'll make it some more, from time to time."
        pc "I'd love that, angel."
    else:

        show kitchen_bg dinnertable evening
        show denise_pd kitchen evening eating unhappy
        show macy_pd kitchen evening eating neutraltalk
        with dissolve
        "[denise_name] doesn't look too happy, but keeps her thoughts to herself."

    label w04d01_s06_end_scene:

    if not (denise_locked_out or macy_locked_out):
        call music_fade_slow from _call_music_fade_slow_301


    scene black
    with fade

    "You clear the table with [denise_name] while [macy_name] leaves for work."

    pause 2.0

    return

label w04d01_s06_yay:

    show denise_pd kitchen_lookatsink evening camisole happy
    show macy_pd kitchen_lookatsink workwear evening neutral
    with dissolve
    deni "Yay!"
    if denise_love <= 6:
        call denise_add_love from _call_denise_add_love_14

    show denise_pd kitchen_lookatsink evening camisole smile:
        1.1
        easeout 5.5 xpos 0.0 xanchor 1.0
    show macy_pd kitchen_lookatsink workwear evening neutral
    with dissolve
    deni "I hope you like it."
    pc "I'm sure I will."
    return
