label w02d04_s03:

    if not w02d01_s02_agree:

        scene setpiece office midday desk
        with fade

        "It's the day before a big release, and everyone is trying to get their work finished in time."
        "It's no different for you, or, you presume, [brooke_name]."

        scene black
        with fade

        pause 2.0

        return

    call theme_brooke from _call_theme_brooke_7

    scene office_bg midday:
        subpixel True
        xalign 0.5 yalign 0.0 zoom 1.0
        0.5
        ease 19 zoom 1.1
    show brooke_pd office midday cubicle talk:
        subpixel True
        xalign 0.5 yalign 0.0 zoom 1.0
        0.5
        ease 19 zoom 1.2
    with fade

    "Later that afternoon, [brooke_name] saunters by."

    show brooke_pd office midday cubicle flirt
    with dissolve
    "She catches your eye and gives a small jerk with her head to indicate you should follow."

    scene black
    with fade

    scene office_bg midday copier:
        subpixel True
        xalign 0.5 yalign 0.5 zoom 1.0
        0.5
        ease 45.0 zoom 1.05 xalign 0.6 yalign 0.2
    show brooke_pd office midday copier neutral:
        subpixel True
        xalign 0.5 yalign 0.5 zoom 1.0
        0.5
        ease 45.0 zoom 1.1 xalign 0.6 yalign 0.2
    with fade

    "You meet up at the copier."

    show brooke_pd office midday copier thoughtful
    with dissolve
    broo "Shit! That was close yesterday!"

    show brooke_pd office midday copier serious
    with dissolve
    broo "I crawled under the desks to the stairwell and slipped out that way."

    show brooke_pd office midday copier talk
    with dissolve
    broo "Did you manage to get out unseen?"

    pc "Not quite."
    pc "I got caught by The Coven."

    menu:
        "'They know.'":
            pc "They know about it."

    show brooke_pd office midday copier thoughtful
    with dissolve
    broo "They know?! Know what?"
    pc "They know I'm involved."

    show brooke_pd office midday copier concerned
    with dissolve
    broo "Do they... know about me?"
    pc "I don't think so."
    pc "I mean, they know of you."
    pc "They're big fans of you, actually."

    show brooke_pd office midday copier smile
    with dissolve
    broo "Really?"
    pc "Well, they're fans of the Asshole Bomber to be accurate, but... yeah."

    if w02d03_s03_pc_said_yes:
        "They think I'm your sidekick and dubbed me {i}the Purple Avenger{/i}."

        show brooke_pd office midday copier happy
        with dissolve
        broo "Really? I would have gone with the Mad Dicker, but Purple Avenger has a good ring to it."

    if w02d01_s03_pc_copied_dick:
        pc "They found the images after you put them in."
    else:
        pc "They found the image after you put it in."

    show brooke_pd office midday copier thoughtful
    with dissolve
    broo "Fuck..."

    pc "But instead of blowing the whistle, they made sure it all got through undetected."

    show brooke_pd office midday copier happy
    with dissolve
    broo "No way!"

    show brooke_pd office midday copier flirt
    with dissolve
    broo "What do they want?"

    pc "I'm not sure."
    pc "And I'm not sure I want to find out either."

    show brooke_pd office midday copier serious
    with dissolve
    broo "I think we should be careful about being seen together in the office for a while."

    show brooke_pd office midday copier talk
    with dissolve
    broo "At least until this blows over."

    default w02d04_s03_pc_disagreed = False
    menu:
        "Agree.":
            $ w02d04_s03_pc_disagreed = False
            pc "I agree."
        "[abgreen]Don't.":
            $ w02d04_s03_pc_disagreed = True
            pc "What? Why?"
            show brooke_pd office midday copier thoughtful
            with dissolve
            broo "If Johnson ever found out we were involved, we'd be fired on the spot for sure."
            show brooke_pd office midday copier concerned
            with dissolve
            broo "And getting a job somewhere else is going to be pretty hard with something like that on our résumé."
            show brooke_pd office midday copier talk
            with dissolve
            broo "So you see, we can't take any chances."

    show brooke_pd office midday copier thoughtful
    with dissolve
    broo "Let's exchange phone numbers."

    show brooke_pd office midday copier neutral
    with dissolve
    broo "We can stay in touch that way."

    "You exchange numbers."

    show brooke_pd office midday copier smile
    with dissolve
    broo "We should head out."

    show brooke_pd office midday copier serious
    with dissolve
    broo "You go first, I'll linger for a few minutes and follow later."

    if w02d03_s03_cunied_brooke:
        show brooke_pd office midday copier flirt
        with dissolve
        broo "And don't think I've forgotten that I still owe you a world-shaking orgasm."

        show brooke_pd office midday copier thoughtful
        with dissolve
        broo "Now go on, get!"

        call music_fade_slow from _call_music_fade_slow_137
        scene black
        with dissolve
        "She ushers you into the hallway."
    else:

        call music_fade_slow from _call_music_fade_slow_138
        scene black
        with dissolve
        "You return to your workplace."

    pause 2.0

    return
