label w01d02_s06:

    call theme_denise_sad from _call_theme_denise_sad_2
    "Later that evening, [denise_name] joins you on the couch."

    scene livingroom_couch_bg night
    show denise_pd livingroom night couch playphone
    with fade
    pc "What are you watching?"

    show denise_pd livingroom night couch thoughtfull
    with dissolve
    deni "Reaction videos of people watching the puppy vlog."

    show denise_pd livingroom night couch playphone
    with dissolve
    pc "Oh... kay... Whatever floats your boat, angel."

    deni "..."
    show denise_pd livingroom night couch talk
    with dissolve
    deni "..."
    deni "[denise_adr_pc_as_cap]?"
    pc "Yes, angel?"

    show denise_pd livingroom night couch unhappy
    with dissolve
    deni "Were you happy at my age?"
    pc "What do you mean?"

    show denise_pd livingroom night couch sad
    with dissolve
    deni "Like... did you enjoy school? Have friends? Do fun things?"

    default pc_was_happy_at_school = False
    menu:
        "[abgreen]I guess so.":
            $ pc_was_happy_at_school = True
            pc "I guess I did, angel."
            pc "I didn't really think about it then."
            pc "Looking back on it now, I think I was pretty happy."
        "Not really.":

            $ pc_was_happy_at_school = False
            pc "Not really, angel."
            pc "I had a hard time fitting in."
            pc "But I guess that's normal for some people."
            pc "Eventually, I found my place in the world, and things became a lot better."

    pc "Why are you asking?"

    show denise_pd livingroom night couch unhappy
    with dissolve
    deni "I'm worried something's wrong with me."

    show denise_pd livingroom night couch sad
    with dissolve
    deni "I just, I don't know..."

    show denise_pd livingroom night couch talk
    with dissolve
    deni "I'm scared all the time. Especially when I'm outside or with people I don't know."

    show denise_pd livingroom night couch thoughtfull
    with dissolve
    deni "I only feel good when I'm at home with you and [macy_name]."

    show denise_pd livingroom night couch sad
    with dissolve
    deni "But even then, sometimes I get scared of losing that too, and that's even worse."

    menu:
        "[abgreen]Reassure her.":
            show denise_pd livingroom night couch headrub sad
            with dissolve
            pc "I'll always be here to look after you, angel."

            show denise_pd livingroom night couch headrub sad eyesclosed
            with dissolve
            pc "Me and your [macy_rel_to_denise]."

            show denise_pd livingroom night couch headrub happy
            with dissolve
            deni "Thanks, [denise_adr_pc_as]. I really needed to hear that."

            call denise_remove_angst from _call_denise_remove_angst
            tuto "Note, the negative emotion [denise_name] feels has just decreased."
            call tuto_explain_angstremove from _call_tuto_explain_angstremove
        "Tell her to be tough.":

            show denise_pd livingroom night couch unhappy
            with dissolve

            pc "Oh angel, you have to realize you can't always control the situation around you."
            pc "Your [macy_rel_to_denise] and me won't always be around."
            pc "You just need to be tougher."

            show denise_pd livingroom night couch sad
            with dissolve
            deni "I'll try, [denise_adr_pc_as]."
            tuto "Note, by choosing this option, you missed an opportunity to lower the negative emotion [denise_name] feels."
            call tuto_explain_angstremove from _call_tuto_explain_angstremove_1

    show denise_pd livingroom night couch talk
    with dissolve
    deni "Can I just lie with you for a bit?"
    pc "Sure, angel."

    show denise_pd livingroom night couch headinlap neutral
    with dissolve
    pc "..."
    pc "[denise_name], did you find some candy on the kitchen counter?"

    show denise_pd livingroom night couch headinlap happytalk
    with dissolve
    deni "No, [denise_adr_pc_as]. Why?"
    pc "No reason. I just thought I left it there."

    show denise_pd livingroom night couch headinlap neutral
    with dissolve
    "You stroke her hair."

    show denise_pd livingroom night couch headinlap neutral eyesclosed
    with dissolve
    call music_fade_slow from _call_music_fade_slow_22
    "You hang out together until [denise_name] goes to bed."

    scene black
    with fade

    pause 2.0

    return

label tuto_explain_angstremove:
    tuto "For [denise_name], the negative emotion is anxiety."
    tuto "Building her confidence and providing stability will help to lower it."
