label w02d01_s04:
    if not w02d01_s02_agree:
        return

    $ s3_love_at_start = s3_love
    $ s3_name_at_start = s3_name

    label w02d01_s04_retry_conversation:

    $ s3_love = s3_love_at_start
    $ s3_name = s3_name_at_start

    call theme_s3_battle from _call_theme_s3_battle
    scene office_bg midday conferenceroom:
        subpixel True
        xalign 0.5 yalign 0.2 zoom 1.1
        0.5
        ease 14 zoom 1.0
    show brooke_pd office midday conferenceroom sneak papers neutral:
        xpos 1.0 xanchor 0.0 yalign 0.3 zoom 0.9
    show s3_pd office daytime conferenceroom neutral:
        subpixel True
        xalign 0.5 yalign 0.2 zoom 1.2
        0.5
        ease 14 zoom 1.0
    with fade

    "You step out of the elevator, and see three ladies talking in the hallway."
    "They must be your target."
    "Your heart is racing as you walk up to them."

    show s3_pd office daytime conferenceroom question
    with dissolve
    s3 "Yes? Can we help you?"

    show brooke_pd office midday conferenceroom sneak papers happy:
        subpixel True
        0.5
        ease 3.2 xalign 1.0
    with dissolve
    "The second elevator opens, and from the corner of your eye you see [brooke_name] insinuating herself into the hallway."

    show brooke_pd office midday conferenceroom sneak papers neutral
    with dissolve

    default w02d01_s04_say_something_clever = False
    menu:
        "[abgreen]Introduce yourself.":
            $ w02d01_s04_say_something_smart = False
            pc "Hi, I don't think we've met before."
            pc "I'm [player_name]. [player_name] [player_last_name]."
            s3 "..."
            pc "I work with the legacy software team."

            show s3_pd office daytime conferenceroom neutral
            show brooke_pd office midday conferenceroom sneak papers happy
            with dissolve
            s3 "Yes, we've seen you around."

            show s3_pd office daytime conferenceroom excited
            show brooke_pd office midday conferenceroom sneak papers neutral
            with dissolve
            s3 "Nice to finally put a name to the face."
        "Say something clever.":

            $ w02d01_s04_say_something_smart = True
            pc "I don't know, can you help me?"
            pc_thought "Pathetic!"

            show s3_pd office daytime conferenceroom shock
            show brooke_pd office midday conferenceroom sneak papers unhappy
            with dissolve
            s3 "..."
            pc "..."
            s3 "..."
            pc "..."
            call s3_remove_love from _call_s3_remove_love

            show s3_pd office daytime conferenceroom angry
            with dissolve
            s3 "And you are?"
            pc "I'm [player_name]. [player_name] [player_last_name]."
            pc "I'm one of the whiz-kids from the legacy software team."
            pc_thought "Sheesh, could I come up with something more corny?!"

            show s3_pd office daytime conferenceroom shock
            show brooke_pd office midday conferenceroom sneak papers neutral
            with dissolve
            s3 "Rrright..."

    $ s3_name = sara_name + ", " + zarah_name + " and " + sierra_name
    $ met_s3 = True
    show s3_pd office daytime conferenceroom neutral
    show brooke_pd office midday conferenceroom sneak papers neutral:
        subpixel True
        0.5
        ease 3.2 xalign 0.32
    with dissolve
    s3 "We're [s3_name]."

    default w02d01_s04_aka_s3 = False
    menu:
        "Joke.":
            $ w02d01_s04_aka_s3 = True
            pc "A.K.A. The Coven."

            show s3_pd office daytime conferenceroom shock
            show brooke_pd office midday conferenceroom sneak papers unhappy
            with dissolve
            s3 "..."

            pc "Right?"

            show brooke_pd office midday conferenceroom sneak papers unhappy:
                subpixel True
                ease 3.2 xpos 0.0 xanchor 1.0

            "Behind [s3_name], [brooke_name] slips into the copy room."

            pc "It's just, that's what I've heard people call you."

            show s3_pd office daytime conferenceroom angry
            show brooke_pd office midday conferenceroom sneak papers neutral
            with dissolve
            call s3_remove_love from _call_s3_remove_love_1
        "[abgreen]Don't.":

            $ w02d01_s04_aka_s3 = False
            pc "So nice to meet you."

            show brooke_pd office midday conferenceroom sneak papers neutral:
                subpixel True
                ease 3.2 xpos 0.0 xanchor 1.0

            "Behind [s3_name], [brooke_name] slips into the copy room."

            pc "I've heard a lot about you ladies."

            show s3_pd office daytime conferenceroom excited
            show brooke_pd office midday conferenceroom sneak papers happy
            with dissolve


    s3 "Really...?"

    show s3_pd office daytime conferenceroom question
    with dissolve
    s3 "What have you heard about us?"

    default w02d01_s04_best_ever = ""
    menu:
        "'Best secretary team ever.'":
            $ w02d01_s04_best_ever = "secretary"
            pc "Just that you're the best secretary team ever."

            show s3_pd office daytime conferenceroom angry
            show brooke_pd office midday conferenceroom sneak nopapers unhappy:
                subpixel True
                0.5
                ease 1.7 xanchor 0.35
                2.0
                ease 1.7 xanchor 1.0
            with dissolve
            s3 "Secretary team?"
            pc "Yes?"

            show s3_pd office daytime conferenceroom shock
            with dissolve
            s3 "..."
            call s3_remove_love from _call_s3_remove_love_2
        "[abgreen]'Best MA team ever.'":

            $ w02d01_s04_best_ever = "MA"
            pc "Just that you're the best MA team ever."

            show s3_pd office daytime conferenceroom neutral
            s3 "People say that?"
            pc "Yeah. Most people seem really impressed with you from what I hear."

            show s3_pd office daytime conferenceroom excited
            show brooke_pd office midday conferenceroom sneak nopapers happy:
                subpixel True
                0.5
                ease 1.7 xanchor 0.35
                2.0
                ease 1.7 xanchor 1.0
            with dissolve
            s3 "Is that so?"
        "'Best receptionist team ever.'":

            $ w02d01_s04_best_x_team_ever = "receptionist"
            pc "Just that you're the best receptionist team ever."

            show s3_pd office daytime conferenceroom angry
            show brooke_pd office midday conferenceroom sneak nopapers unhappy:
                subpixel True
                0.5
                ease 1.7 xanchor 0.35
                2.0
                ease 1.7 xanchor 1.0
            with dissolve
            s3 "Receptionist team?"
            pc "Yes?"

            show s3_pd office daytime conferenceroom shock
            with dissolve
            s3 "..."
            call s3_remove_love from _call_s3_remove_love_3

    $ w02d01_s04_when_are_you_due = False
    $ w02d01_s04_single_parent = False
    $ w02d01_s04_festivals_coming_up = False
    $ w02d01_s04_s3_reminder_given = False

    default w02d01_s04_due_chose = ""
    default w02d01_s04_single_parent_chose = ""
    default w02d01_s04_festival_chose = ""
    $ w02d01_s04_due_chose = ""
    $ w02d01_s04_single_parent_chose = ""
    $ w02d01_s04_festival_chose = ""

    $ nr_of_times_spoken = 0

    label w02d01_s04_have_conversation:

    if s3_love <= 1:
        show s3_pd office daytime conferenceroom angry
        with dissolve
        s3 "I think it's time for you to leave."
        pc "Oh..."
        "You messed up. Let's try that again."
        jump w02d01_s04_retry_conversation

    if not w02d01_s04_s3_reminder_given:
        $ w02d01_s04_s3_reminder_given = True
        pc_thought "Okay, [brooke_name] is in the copy room, doing her thing."
        pc_thought "Now I have to keep them distracted until she's done."
        pc_thought "What did [brooke_name] say again? A hormonal train wreck, a harried single mom and a party animal with daddy issues."
        pc_thought "Here goes nothing..."

    menu:
        "(To [sara_name]) 'When are you due?" if not w02d01_s04_when_are_you_due:
            $ w02d01_s04_when_are_you_due = True
            pc "So, when are you due?"

            show s3_pd office daytime conferenceroom neutral:
                subpixel True
                0.5
                xalign 0.0
                ease 2.3 zoom 1.3
            with dissolve
            s3 "Oh, it's still a few months away."

            show s3_pd office daytime conferenceroom excited
            with dissolve
            s3 "But I have to say, they can't pass quickly enough in my opinion."

            show s3_pd office daytime conferenceroom shock
            with dissolve
            s3 "It's getting pretty uncomfortable."

            show s3_pd office daytime conferenceroom question
            with dissolve
            s3 "You must know how it is."

            pc "Uh... yeah."
            pc "With... your...?"
            menu:
                "[abgreen]'Swollen...'":
                    $ w02d01_s04_due_chose = "feet"
                    pc "What with your swollen..."

                    show s3_pd office daytime conferenceroom neutral
                    with dissolve
                    s3 "..."
                    pc "...feet?"
                    pc "Does your partner massage them?"

                    show s3_pd office daytime conferenceroom angry
                    with dissolve
                    s3 "No he doesn't."
                    pc "I would."
                    pc "It's the least you can do for the woman carrying the fruit of your love."

                    call w02d01_s04_show_brooke_happy_during_conversation from _call_w02d01_s04_show_brooke_happy_during_conversation
                    show s3_pd office daytime conferenceroom excited:
                        subpixel True
                        2.1
                        ease 2.3 zoom 1.0
                        xalign 0.5
                    with dissolve
                    s3 "That's so sweet."
                    call s3_add_love from _call_s3_add_love
                "'Sore...'":

                    $ w02d01_s04_due_chose = "nipples"
                    pc "What with your sore..."

                    show s3_pd office daytime conferenceroom neutral
                    with dissolve
                    s3 "..."
                    pc "...nipples?"

                    show s3_pd office daytime conferenceroom shock
                    with dissolve
                    s3 "Excuse me?"
                    pc "I read... somewhere... that they get really sore in the third trimester."

                    call w02d01_s04_show_brooke_unhappy_during_conversation from _call_w02d01_s04_show_brooke_unhappy_during_conversation
                    show s3_pd office daytime conferenceroom angry:
                        subpixel True
                        2.1
                        ease 2.3 zoom 1.0
                        xalign 0.5
                    with dissolve
                    s3 "I'm sure I'm not about to discuss my nipples with you."
                    call s3_remove_love from _call_s3_remove_love_4
                "'Aching...'":

                    $ w02d01_s04_due_chose = "back"
                    pc "What with your aching..."

                    show s3_pd office daytime conferenceroom neutral
                    with dissolve
                    s3 "..."
                    pc "...back?"

                    show s3_pd office daytime conferenceroom shock:
                        subpixel True
                        2.1
                        ease 2.3 zoom 1.0
                        xalign 0.5
                    with dissolve
                    s3 "You have no idea. It's awful."

        "(To [zarah_name]) 'Being a single [pc_rel_to_denise]...'" if not w02d01_s04_single_parent:
            $ w02d01_s04_single_parent = True
            pc "I tell you, it's not easy being a single [pc_rel_to_denise]."

            show s3_pd office daytime conferenceroom question:
                subpixel True
                0.5
                xalign 0.5
                ease 2.3 zoom 1.3
            with dissolve
            s3 "Tell me about it."

            menu:
                "'My eldest is completely out of control.'":
                    $ w02d01_s04_single_parent_chose = "eldest"
                    pc "My eldest is completely out of control."

                    show s3_pd office daytime conferenceroom shock
                    with dissolve
                    s3 "Is she now?"
                    pc "Yeah. Tattoos, piercings, the works."
                    pc_thought "Did I have to drag [macy_name] into this?"
                    pc "I have no idea what's up with her."

                    call w02d01_s04_show_brooke_unhappy_during_conversation from _call_w02d01_s04_show_brooke_unhappy_during_conversation_1
                    show s3_pd office daytime conferenceroom angry:
                        subpixel True
                        0.5
                        ease 0.7 xalign 1.0
                    with dissolve
                    s3 "I'm sure if you just gave her the attention she needs, your relationship would be a whole lot better."
                    call s3_remove_love from _call_s3_remove_love_5
                    pc "Oh... kay..."
                    show s3_pd office daytime conferenceroom angry:
                        subpixel True
                        2.1
                        ease 2.3 zoom 1.0
                        xalign 0.5

                    if w02d01_s04_festival_chose == "bringeldest":
                        pc_thought "Daddy issues!"
                    else:
                        pc_thought "Daddy issues?"
                "'My youngest is very insecure.'":

                    $ w02d01_s04_single_parent_chose = "youngest"
                    pc "My youngest is sooo insecure."
                    pc "Honestly, I don't know how I can help her."
                    pc_thought "Did I have to drag [denise_name] into this?"

                    show s3_pd office daytime conferenceroom neutral
                    with dissolve
                    s3 "Their emotions are all over the place at that age."

                    show s3_pd office daytime conferenceroom angry
                    with dissolve
                    s3 "My eldest just wants to play computer games all day long."

                    show s3_pd office daytime conferenceroom question
                    with dissolve
                    s3 "The youngest spends hours a day fussing over his social media."

                    show s3_pd office daytime conferenceroom shock:
                        subpixel True
                        2.1
                        ease 2.3 zoom 1.0
                        xalign 0.5
                    with dissolve
                    s3 "It's enough to drive you crazy!"
                    pc "Right."
                "[abgreen]'It's not all bad.'":

                    $ w02d01_s04_single_parent_chose = "notbad"
                    pc "It's not all bad though."
                    pc "Every once in a while, you get a little bit of appreciation for your sacrifices."
                    pc "Those are the days I live for."

                    show s3_pd office daytime conferenceroom excited
                    with dissolve
                    s3 "That is sooo true."

                    show s3_pd office daytime conferenceroom shock
                    with dissolve
                    s3 "Just to hear one of my boys tell me 'mom, I love you'..."

                    call w02d01_s04_show_brooke_happy_during_conversation from _call_w02d01_s04_show_brooke_happy_during_conversation_1
                    show s3_pd office daytime conferenceroom excited:
                        subpixel True
                        2.1
                        ease 2.3 zoom 1.0
                        xalign 0.5
                    with dissolve
                    s3 "Keeps me going for weeks, it does."
                    call s3_add_love from _call_s3_add_love_1

        "(To [sierra_name]) 'Any good festivals coming up?'" if not w02d01_s04_festivals_coming_up:
            $ w02d01_s04_festivals_coming_up = True

            pc "So, any good festivals coming up this season?"

            show s3_pd office daytime conferenceroom neutral:
                subpixel True
                0.5
                xalign 1.0
                ease 2.3 zoom 1.3
            with dissolve
            s3 "Why do you ask?"

            menu:
                "'I like to party hard.'":
                    $ w02d01_s04_festival_chose = "party"
                    pc "I like to party hard."
                    pc "Live fast, die young, if you know what I mean."

                    call w02d01_s04_show_brooke_unhappy_during_conversation from _call_w02d01_s04_show_brooke_unhappy_during_conversation_2
                    show s3_pd office daytime conferenceroom shock
                    with dissolve
                    s3 "No, I don't."

                    show s3_pd office daytime conferenceroom angry:
                        subpixel True
                        2.1
                        ease 2.3 zoom 1.0
                        xalign 0.5
                    with dissolve
                    s3 "Nothing sorrier at a festival than some old geezer with a family back home trying to keep up with the kids."
                    call s3_remove_love from _call_s3_remove_love_6
                "'I like to meet single ladies.'":

                    $ w02d01_s04_festival_chose = "single"
                    pc "I feel like I'm ready to meet someone new."
                    pc "I've been single long enough, I think."

                    show s3_pd office daytime conferenceroom shock:
                        subpixel True
                        0.5
                        ease 0.7 xalign 0.5
                    with dissolve
                    s3 "I'm sure there's plenty of other places where you could meet a single lady closer to your own age."
                    show s3_pd office daytime conferenceroom shock:
                        subpixel True
                        2.1
                        ease 2.3 zoom 1.0
                        xalign 0.5
                "[abgreen]'I'd like to take my eldest [macy_rel_to_pc].'":

                    $ w02d01_s04_festival_chose = "bringeldest"
                    pc "I'd like to take my eldest [macy_rel_to_pc] some day."
                    pc "I really want to spend more time with her."
                    pc "It's very important for me to be a part of her life."

                    call w02d01_s04_show_brooke_happy_during_conversation from _call_w02d01_s04_show_brooke_happy_during_conversation_2
                    show s3_pd office daytime conferenceroom shock
                    with dissolve
                    s3 "Really? That's so sweet."

                    show s3_pd office daytime conferenceroom excited:
                        subpixel True
                        2.1
                        ease 2.3 zoom 1.0
                        xalign 0.5
                    with dissolve
                    s3 "She's very lucky to have a [pc_rel_to_macy] that shows an interest in her."
                    call s3_add_love from _call_s3_add_love_2

                    if w02d01_s04_single_parent_chose == "eldest":
                        pc_thought "Daddy issues!"
                    else:
                        pc_thought "Daddy issues?"

    if nr_of_times_spoken == 1:
        show brooke_pd office midday conferenceroom sneak nopapers happy:
            subpixel True
            0.5
            ease 3.2 xalign 0.34
        with dissolve
        "[brooke_name] emerges from the copy room."
        show brooke_pd office midday conferenceroom sneak nopapers neutral
        with dissolve

    elif nr_of_times_spoken == 2:
        show brooke_pd office midday conferenceroom sneak nopapers neutral:
            subpixel True
            0.5
            ease 3.2 xalign 1.0
        with dissolve
    $ nr_of_times_spoken += 1

    if not (w02d01_s04_when_are_you_due and w02d01_s04_single_parent and w02d01_s04_festivals_coming_up):
        jump w02d01_s04_have_conversation

    "You can see [brooke_name] is about to step into the elevator, and that's your cue to disengage."

    pc "Well, it's been great talking to you ladies."

    call music_fade_slow from _call_music_fade_slow_70
    show brooke_pd office midday conferenceroom sneak nopapers neutral:
        subpixel True
        0.5
        ease 3.2 xpos 1.0 xanchor 0.0
    pc "I was told my team lead was here, but I guess they've already gone to the cafeteria."
    pc "Talk to you later."

    if s3_love <= 4:
        show s3_pd office daytime conferenceroom neutral
        with dissolve
        s3 "Goodbye."
    else:
        show s3_pd office daytime conferenceroom neutral
        with dissolve
        s3 "Great talking to you, too."
        show s3_pd office daytime conferenceroom excited
        with dissolve
        s3 "Take care."
        pc "You too. Bye-bye."

    scene black
    with dissolve
    "You step into the elevator, and punch a button."
    "You punch it again, just to be sure."
    "For an eternity, nothing happens."
    "As the door finally starts to close at a snails pace, you half expect someone in the hallway to yell 'not so fast!'"
    "They never do."
    "You ride the elevator down and head to the copier, where [brooke_name] is already waiting for you."

    call theme_brooke from _call_theme_brooke_3
    scene office_bg midday copier:
        subpixel True
        xalign 0.6 yalign 0.2 zoom 1.05
        0.5
        ease 7.0 zoom 1.0 xalign 0.5 yalign 0.5
    show brooke_pd office midday copier neutral:
        subpixel True
        xalign 0.6 yalign 0.2 zoom 1.1
        0.5
        ease 7.0 zoom 1.0 xalign 0.5 yalign 0.5
    with fade
    pc "Did you do it?"

    show brooke_pd office midday copier smile
    with dissolve
    broo "Yeah, I inserted the images right before the section detailing profit before taxes."

    show brooke_pd office midday copier serious
    broo "They are in for one hell of a surprise."

    pc "Yeah."

    show brooke_pd office midday copier happy
    with dissolve
    broo "That was... awesome!"

    show brooke_pd office midday copier neutral
    with dissolve
    broo "Good job on [s3_name]!"

    if w01d05_s04_manly_charms_cando:
        show brooke_pd office midday copier flirt lookaway
        with dissolve
        broo "You weren't lying when you said 'can do'."

        show brooke_pd office midday copier happy
        with dissolve
        broo "I could smell the pheromones from where I was standing."
        pc "Piece. Of. Cake."
    else:

        show brooke_pd office midday copier smile
        with dissolve
        broo "I told you you could do it."
        pc "You did."

        show brooke_pd office midday copier happy
        with dissolve
        broo "I am so proud."

    show brooke_pd office midday copier flirt
    with dissolve
    broo "You had them wrapped around your finger."
    pc "I did, didn't I?"

    default w02d01_s04_contemplated_expression = False
    menu:
        "Contemplate the expression.":
            $ w02d01_s04_contemplated_expression = True
            pc "It's a pretty weird thing to say, if you think about it."

            show brooke_pd office midday copier thoughtful
            with dissolve
            broo "What?"
            pc "Having a girl wrapped around your finger."
            pc "If you truly think about it... "
            pc "...one of the few ways that could be said to be physically true is when..."

            show brooke_pd office midday copier concerned
            with dissolve
            broo "Yeah..."
            show brooke_pd office midday copier thoughtful
            with dissolve
            broo "Yeah, I get the picture."

            show brooke_pd office midday copier smile
            with dissolve
            broo "Now, as much as I'd love to explore this mental image further, we should head out."
        "[abgreen]Don't.":

            $ w02d01_s04_contemplated_expression = False
            pc "..."
            show brooke_pd office midday copier smile
            with dissolve
            broo "What?"
            pc "Nothing."

    show brooke_pd office midday copier serious
    with dissolve
    broo "We should get back to work and act as if nothing happened."

    show brooke_pd office midday copier concerned
    with dissolve
    broo "Tomorrow, I'm all filled up with meetings, and sadly I won't be in the conference room when they go over the numbers."

    show brooke_pd office midday copier neutral
    with dissolve
    broo "But that's probably a good thing; suspicion is less likely to fall on me if I'm not there."

    show brooke_pd office midday copier talk
    with dissolve
    broo "And I've got my fly on the wall there, so I'll have a firsthand account of how it went down."

    show brooke_pd office midday copier happy
    with dissolve
    broo "I'll find you on Wednesday and tell you all about it."

    default w02d01_s04_expressed_doubt = False
    menu:
        "[abgreen]Agree.":
            $ w02d01_s04_expressed_doubt = False
            pc "Sounds good."
        "Express doubt.":
            $ w02d01_s04_expressed_doubt = True
            if not w02d01_s03_pc_copied_dick:
                pc "Say, what if someone skips ahead a few pages and stumbles on your images prematurely?"
            else:
                pc "Say, what if someone skips ahead a few pages and stumbles on our images prematurely?"

            show brooke_pd office midday copier neutral
            with dissolve
            broo "They won't."

            show brooke_pd office midday copier thoughtful
            with dissolve
            broo "Johnson is very adamant on everyone being on the same page."

            show brooke_pd office midday copier serious
            with dissolve
            broo "He's a man of little imagination, so in his case, that means literally."

            show brooke_pd office midday copier happy
            with dissolve
            broo "No one will dare skip ahead."

            pc "I see."

    show brooke_pd office midday copier neutral
    with dissolve
    broo "Oh, and..."

    show brooke_pd office midday copier concerned
    with dissolve
    broo "Thanks."

    show brooke_pd office midday copier happy
    with dissolve
    broo "I couldn't have done this without you."

    show brooke_pd office midday copier smile
    with dissolve
    broo "I'll make it up to you, I promise."

    default w02d01_s04_no_need = False
    menu:
        "'No need.'":
            $ w02d01_s04_no_need = True
            pc "No need, it was my pleasure."

            show brooke_pd office midday copier flirt
            with dissolve
            broo "{size=-8}Not yet, but it could be...{/size}"
        "[abgreen]'I'll hold you to it.'":

            $ w02d01_s04_no_need = False
            pc "I'll hold you to it."
            show brooke_pd office midday copier flirt
            with dissolve
            broo "{size=-8}I might just let you...{/size}"

    pc "What was that?"

    call music_fade_slow from _call_music_fade_slow_71
    show brooke_pd office midday copier flirt lookaway
    with dissolve
    broo "Er... nothing. Let's go."

    call brooke_add_love from _call_brooke_add_love_2

    scene black
    with fade
    "You return to your workplace and attempt to look busy."

    scene setpiece office midday desk
    with fade
    "But by the end of the day, you've gotten very little work done."
    "With a sigh, you pack up and go home."

    scene black
    with fade
    pause 2.0

    return

label w02d01_s04_show_brooke_unhappy_during_conversation:
    if nr_of_times_spoken <= 1:
        show brooke_pd office midday conferenceroom sneak nopapers unhappy:
            1.0
            ease 1.7 xanchor 0.35
            2.0
            ease 1.7 xanchor 1.0
        with dissolve
    else:
        show brooke_pd office midday conferenceroom sneak nopapers unhappy
    with dissolve
    return

label w02d01_s04_show_brooke_happy_during_conversation:
    if nr_of_times_spoken <= 1:
        show brooke_pd office midday conferenceroom sneak nopapers happy:
            1.0
            ease 1.7 xanchor 0.35
            2.0
            ease 1.7 xanchor 1.0
        with dissolve
    else:
        show brooke_pd office midday conferenceroom sneak nopapers happy
    with dissolve
    return
