label w03d02_s06:

    scene gasstation_backdrop arrive:
        subpixel True
        xalign 0.3 yalign 0.7 zoom 1.15
        easein 22.3 zoom 1.0
    show setpiece gasstation night arrive:
        subpixel True
        xalign 0.3 yalign 0.7 zoom 1.3
        easein 22.3 zoom 1.0
    with dissolve
    "As you take the offramp, the engine comes to a trembling stop."
    "You manage to coast the last bit, stopping at an abandoned gas station."

    macy "Classy."
    macy "Now what?"

    scene black
    with fade
    "You both get out into the crisp evening air."

    call theme_macy_fate from _call_theme_macy_fate_2

    scene gasstation_bg leantrunk:
        subpixel True
        xalign 0.8 yalign 0.1 zoom 1.15
        ease 58.3 zoom 1.0
    show macy_pd gasstation leantrunk thoughtful:
        subpixel True
        xalign 0.8 yalign 0.1 zoom 1.3
        ease 58.3 zoom 1.0
    with fade
    pc "Let's give it a bit of time to cool off and see if that'll let it take us home."

    show gasstation_bg leantrunk
    show macy_pd gasstation leantrunk frown
    with dissolve
    macy "Well this sucks..."

    pc "It was bound to happen sooner or later."
    pc "This old piece of junk is the best we can afford right now, but it's really just held together with duct tape and wire at this point."

    show gasstation_bg leantrunk
    show macy_pd gasstation leantrunk thoughtful
    with dissolve
    macy "It's vintage right?"

    show gasstation_bg leantrunk
    show macy_pd gasstation leantrunk neutral
    with dissolve
    macy "It must be worth something."

    pc "Nah. It's rusted through, and it doesn't even come with the original engine."
    pc "Someone swapped that out a long time ago."
    pc "It's all looks and no substance."

    default w03d02_s06_just_like_me = False
    menu:
        "'Just like me.'":
            $ w03d02_s06_just_like_me = True
            pc "Hehe, just like me."

            show gasstation_bg leantrunk
            show macy_pd gasstation leantrunk shocked
            with dissolve
            macy "Yeah, but in the case of the car, looking old and weathered adds character."
            pc "Hey, I got heaps of character!"

            show gasstation_bg leantrunk
            show macy_pd gasstation leantrunk frown
            with dissolve
            macy "Riiight..."

            show gasstation_bg leantrunk
            show macy_pd gasstation leantrunk smile
            with dissolve
            macy "And like the car, a lot of people think you don't look half bad until they notice the grime, the rust and especially the smell."
            pc "Ouch."
            pc "Say, is that a really awkward way to tell me you think I'm good-looking?"

            show gasstation_bg leantrunk:
                ease 58.3 zoom 1.15
            show macy_pd gasstation leantrunk secretsmile eyesclosed:
                ease 58.3 zoom 1.3
            with dissolve
            macy "Take it any way you want to, [macy_adr_pc_as_nice]."

            show gasstation_bg leantrunk
            show macy_pd gasstation leantrunk secretsmile
            with dissolve
        "[abgreen]'Just like you.'":

            $ w03d02_s06_just_like_me = False
            pc "Sorta like you, really."

            show gasstation_bg leantrunk
            show macy_pd gasstation leantrunk smile
            with dissolve
            macy "At least you have the good sense to acknowledge my looks."

            show gasstation_bg leantrunk
            show macy_pd gasstation leantrunk eyeroll
            with dissolve
            macy "I may have some rough edges, but the bodywork is classic."

            default w03d02_s06_agree_bodywork = False
            menu:
                "[abgreen]Agree.":
                    $ w03d02_s06_agree_bodywork = True
                    pc "That it is, princess."

                    show gasstation_bg leantrunk
                    show macy_pd gasstation leantrunk frown
                    with dissolve
                    macy "I know..."

                    show gasstation_bg leantrunk
                    show macy_pd gasstation leantrunk secretsmile eyesclosed
                    with dissolve
                    macy "Don't think I didn't see you sneak a peek at the tail lights back in the bar."

                    show gasstation_bg leantrunk
                    show macy_pd gasstation leantrunk secretsmile
                    with dissolve
                    pc "I... ah..."
                "Say nothing.":

                    $ w03d02_s06_agree_bodywork = False
                    pc "..."

            show gasstation_bg leantrunk:
                ease 58.3 zoom 1.15
            show macy_pd gasstation leantrunk smile eyesclosed:
                ease 58.3 zoom 1.3
            with dissolve
            macy "Hehe, cat got your tongue, [macy_adr_pc_as_nice]?"

            show gasstation_bg leantrunk
            show macy_pd gasstation leantrunk smile
            with dissolve

    if macy_adr_pc_as_sir:
        pc "I..."
        pc "I'm happy to hear you call me '[macy_adr_pc_as_nice]' again."

        show gasstation_bg leantrunk
        show macy_pd gasstation leantrunk frown
        with dissolve
        macy "Just so you know, that can change in a heartbeat if you start acting like a dick again..."
        pc "Noted."

    if not w03d02_s06_just_like_me or macy_adr_pc_as_sir:
        show gasstation_bg leantrunk
        show macy_pd gasstation leantrunk smile
        with dissolve

    "With the mood substantially lightened, you spend a few more minutes joking and talking."

    show gasstation_bg leantrunk
    show macy_pd gasstation leantrunk thoughtful eyesclosed
    with fade
    macy "..."

    show gasstation_bg leantrunk
    show macy_pd gasstation leantrunk thoughtful
    with dissolve
    pc "Your [denise_rel_to_macy] will be pleased."

    show gasstation_bg leantrunk
    show macy_pd gasstation leantrunk neutral
    with dissolve
    macy "How's that?"
    pc "That we've cleared the air between us."

    show gasstation_bg leantrunk
    show macy_pd gasstation leantrunk shocked
    with dissolve
    macy "A bit. We cleared the air a bit."
    pc "Alright, that we cleared the air a bit."

    show gasstation_bg leantrunk
    show macy_pd gasstation leantrunk thoughtful
    with dissolve
    macy "Yeah."

    pc "She came to me the morning after, all worried about what had happened last Saturday."

    show gasstation_bg leantrunk
    show macy_pd gasstation leantrunk neutral
    with dissolve
    macy "What did she say?"
    pc "She told me how you told her about hitting me, and she wanted to know all the details."

    show gasstation_bg leantrunk
    show macy_pd gasstation leantrunk frown
    with dissolve
    macy "Wait! She told you {i}I{/i} told her?"
    pc "Yeah. Wasn't she supposed to tell me?"

    show gasstation_bg leantrunk
    show macy_pd gasstation leantrunk shocked
    with dissolve
    macy "No, no that's fine."

    show gasstation_bg leantrunk
    show macy_pd gasstation leantrunk thoughtful
    with dissolve
    macy "So did you? Tell her the details?"
    if w02d07_s01_confessed:
        pc "Yeah. I didn't want to keep it from her."
    else:
        pc "No. I couldn't bring myself to tell her."

    show gasstation_bg leantrunk:
        ease 34.9 zoom 1.0
    show macy_pd gasstation leantrunk thoughtful eyesclosed:
        ease 34.9 zoom 1.0
    with dissolve
    macy "Alright."

    show gasstation_bg leantrunk
    show macy_pd gasstation leantrunk neutral
    with dissolve
    macy "Do you think we can try again?"
    pc "Try what?"

    show gasstation_bg leantrunk
    show macy_pd gasstation leantrunk eyeroll
    with dissolve
    macy "The car, dummy!"

    show gasstation_bg leantrunk
    show macy_pd gasstation leantrunk shocked
    with dissolve
    macy "Wait! Did you think I wanted to punch you in the face again?! Or...?"
    pc "Noooo..."

    show gasstation_bg leantrunk
    show macy_pd gasstation leantrunk frown
    with dissolve
    macy "Don't tempt me."
    pc "Not in a million years. I learned my lesson."

    show gasstation_bg leantrunk
    show macy_pd gasstation leantrunk sad
    with dissolve
    macy "..."

    show gasstation_bg leantrunk
    show macy_pd gasstation leantrunk sad eyesclosed
    with dissolve
    macy "{size=-7}That's... good...{/size}"

    pause 1.2

    scene black
    with dissolve

    pause 1.2

    call music_fade_slow from _call_music_fade_slow_246

    "You decide you've waited long enough, and try starting the car."
    "The engine starts, but it's running shakily, and cuts out almost immediately when you try to set off."

    default w03d02_s06_called_service = False
    menu:
        "Call repair service.":
            $ w03d02_s06_called_service = True
            "You decide to call a repair service."
            "Someone comes by quickly, and is able to fix the issue within minutes of popping the hood."
            "After paying your dues, you're ready to set off."
        "[abgreen]Tinker yourself.":

            $ w03d02_s06_called_service = False
            "You decide to pop the hood and have a quick look."
            "You can see a few wires have come lose, causing some cylinders to stop firing."
            "With the tools you had laying in the trunk for just such an occasion, you quickly fasten the wires again, solving the problem."

    "You drive home without incident."

    pause 2.0

    return
