label w05d06_s01:

    if (denise_locked_out or macy_locked_out):
        show text "{size=+18}{font=fonts/typeo___.ttf}Saturday.{/font}{/size}" as text1 at truecenter:
            alpha 0.0
            1.0
            easein 1.5 alpha 0.8
            5.0
            easeout 1.5 alpha 0.0
        with openeyestrans
        $ renpy.pause(3.0, hard='True')

        "You are awoken by the smell of breakfast."

        pause 2.0

        return

    scene cabin_morning_bg layonbed_2560x1440:
        subpixel True
        xalign 1.0 yalign 1.0 zoom 1.1
        0.5
        ease 15.0 xalign 0.75 yalign 0.75 zoom ((1920.0/2560.0) * 1.3)
    show charlotte_pd vacation_bedroom_morning_2560x1440 layonbed_wakeup eyesclosed:
        subpixel True
        xalign 1.0 yalign 1.0 zoom 1.2
        0.5
        ease 15.0 xalign 0.75 yalign 0.75 zoom ((1920.0/2560.0) * 1.4)
    show dreamsequcence_corona inv:
        subpixel True
        alpha 0.2
    show black:
        alpha 0.0
    show text "{size=+18}{font=fonts/typeo___.ttf}Saturday.{/font}{/size}" as text1 at truecenter:
        alpha 0.0
        1.0
        easein 1.5 alpha 0.8
        5.0
        easeout 1.5 alpha 0.0
    with openeyestrans
    $ renpy.pause(3.0, hard='True')

    show black:
        alpha 1.0
    with closeeyestrans

    $ renpy.pause(1.0, hard='True')

    show black:
        alpha 0.0
    with openeyestrans

    $ renpy.pause(4.0, hard='True')

    call theme_charlotte_dramatic from _call_theme_charlotte_dramatic_3

    "Morning comes, and you wake up slowly, feeling warm and comfortable and loved."

    show cabin_morning_bg layonbed_2560x1440:
        0.5
        parallel:
            ease 8.5 xalign 0.5 yalign 0.15
        parallel:
            ease 26.0 zoom (1920.0/2560.0)
    show charlotte_pd vacation_bedroom_morning_2560x1440 layonbed_wakeup eyesclosed:
        0.5
        parallel:
            ease 8.5 xalign 0.5 yalign 0.15
        parallel:
            ease 26.0 zoom (1920.0/2560.0)
        parallel:
            7.0
            "charlotte_pd vacation_bedroom_morning_2560x1440 layonbed_wakeup" with dissolve
    hide text1
    with dissolve

    $ renpy.pause(7.0, hard='True')

    char "Good morning babe..."
    pc "Mmh..."

    show cabin_morning_bg layonbed_2560x1440
    show charlotte_pd vacation_bedroom_morning_2560x1440 layonbed_looksad
    with dissolve
    char "The girls are already up. Time for us to wake up too..."

    show black:
        alpha 1.0
    with closeeyestrans

    hide black
    hide dreamsequcence_corona
    show cabin_morning_bg layonbed_2560x1440
    show charlotte_pd vacation_bedroom_morning_2560x1440 pc_alone
    with openeyestrans

    char "Time {size=-7}to {/size}{size=-11}go...{/size}"

    show cabin_morning_bg layonbed_2560x1440:
        0.5
        parallel:
            ease 16.1 xalign 0.9 yalign 0.1
        parallel:
            ease 38.4 zoom ((1920.0/2560.0) * 1.15)
    show charlotte_pd vacation_bedroom_morning_2560x1440 pc_alone:
        0.5
        parallel:
            ease 16.1 xalign 0.9 yalign 0.1
        parallel:
            ease 38.4 zoom ((1920.0/2560.0) * 1.2)
    with dissolve
    "You take a deep breath."
    default w05d06_s01_say_something = False
    menu:
        "[abgreen]Say something.":
            $ w05d06_s01_say_something = True
            pc "Good morning to you too, my love."
        "Don't.":
            $ w05d06_s01_say_something = False
            pc "..."

    "Noises rise up from downstairs, accompanied by the smell of breakfast."

    scene black
    with fade

    call music_fade_slow from _call_music_fade_slow_431

    "You look around for your clothes, but they're nowhere in sight."
    "In the end, you make your way down in your underwear."

    pause 2.0

    return
