
label coxSewSkirt():    #codeBlc
    
    mom "It's still okay if I show just a bit more of my legs at school, right?"
    mom "Worst case scenario, I'm sure I can convince principal [principal.last_name] to allow me as a special case..."
    "You go through some slutty mental gymnastics to convince yourself that school regulations don't necessarily have to apply to you."
    
    if mom.outfit_manager.pants_set == 3 and not coxSlotHasSwap(nSlot=TEXTURE_PANTS, oOutfit=mom.current_outfit): # The latter is only a check fully compatible with outfits that use my mod, but it's better than nothing.
        $ mom.set_pants_off(True)
        call mc_frame_display("butt_frame")
        "As you're about to modify it, you remove your skirt, and put it on the table with the sewing machine, before sliding out the stool."
        if mom.outfit_manager.panties_set == -3 and mom.arousal >= 50:
            $ mom.play_animation(butt_bounce_1_animation)
            "Your pent-up arousal has left your bare pussy wet, and it makes a slight squish as you sit down.\nYou glance over your shoulder."
            mom "Perhaps I should masturbate later..."
        elif mom.outfit_manager.panties_set == -3:
            $ mom.play_animation(butt_bounce_1_animation)
            "As you sit down, you almost yelp when your bare pussy touches the chilly stool."
            $ mom.change_arousal(5)
        else:
            "Your bum feels cold against the chilly stool as you sit down on it."
    else:
        "You bring your skirt out, putting it on the table with the sewing machine, before sliding out the stool and sitting down."
    "You take a deep breath as you reach for your scissors and measuring tape, and consider how you want to change your skirt."
    call clear_frames(mom)
    $ modification_set = set()
    menu menuSkirtMod:
        set modification_set
        mom "Hmm.. how should I go about this?"
        
        "*Make it shorter*":
            "You roll up the hem of the skirt, getting a gauge for where you want it."
            mom "There was definitely a rip right here, so I had to adjust its length."
            "You cut the skirt to a length where you can just {i}barely{/i} see your ass cheeks hanging out."
            mom "Yes, that's my story. Besides, if people comment on my skirt, it means they're watching too closely."
            jump menuSkirtMod
            
        "*Make it tighter*":
            "You smile to yourself as you start cutting open the seam on one side of the skirt."
            mom "The regulations don't really specify exactly how tight the skirt can be.."
            "You cut off a slightly generous amount of fabric from each side of the former seam, before turning the inside of the skirt out."
            "You put the ends together and line it up on your sewing machine, sewing a new seam quickly, before using your scissors to clean up the hem on the inside, so it doesn't fit strangely or itch."
            "Then you turn the skirt the right way out again."
            jump menuSkirtMod
    
    
    call advance_time()
    $ mom.change_stress(10)
    $ coxTinyBlackSkirt.unlocked = True
    if mom.outfit_manager.pants_off == False:
        $ mom.set_pants_off(True)
    "As you finally finish, you inspect your work for a bit, before deciding to try the skirt on."
    call mc_frame_display("butt_frame")
    "You attempt to pull the skirt up, but it's {i}really{/i} tight."
    $ mom.play_animation(butt_shake_animation)
    "You wiggle your hips from side to side, slowly sliding the skirt onto yourself.\nYou're starting to suspect you might have made it a bit {i}too{/i} tight."
    mom "Come onnnnn...."
    $ mom.outfit_manager.pants_set = 3
    $ mom.outfit_manager.active_texture_swaps.extend([coxTinyBlackSkirt.pants_texture, coxTinyBlackSkirt.pants_butt_texture])
    $ mom.outfit_manager.refresh_texture_swaps()
    $ mom.set_pants_off(False)
    "You huff in satisfaction as the skirt finally manages to get past the thickest part of your bum, now sliding up much more easily."
    $ mom.end_animation(butt_shake_animation)
    "Almost instantly, the skirt slips upward, popping off from your ass."
    mom "Okay, so I may have been a bit over-zealous with my scissors..."
    "You pull down on the hem of the skirt as best you can, but you can only just barely get it to stay over one of your cheeks."
    "Looking at yourself in the mirror, you see it's completely unable to cover your pussy, as well."
    
    if mom.corruption_level < coxTinyBlackSkirt.corruption_requirement:
        call mc_display("embarrassed")
        mom "Oh my, I can't wear this at all, this is way too much..."
        $ mom.play_animation(butt_bounce_1_animation)
        "You twist and turn frantically in the mirror, poking at your bum and trying to get the skirt's hem lower, but to no avail."
        $ mom.play_animation(butt_bounce_2_animation)
        mom "I really can't...have I totally ruined it?"
        if coxVisitedEmporium:
            mom "Maybe I should have a look in the Emporium, to see if I can find something else I can wear..."
        elif coxCoxTutorial:
            mom "That crazy lady did mention she runs a clothing store, perhaps I should check it out to see if I can find something else to wear..."
    else:
        call mc_display("aroused")
        mom "Well, this isn't what I had intended at all, but it's pretty sexy..."
        $ mom.play_animation(butt_bounce_1_animation)
        "You poke your butt a bit, satisfied with how great it looks in the skirt."
        $ mom.play_animation(butt_bounce_2_animation)
        mom "I wonder how the boys in school will like it..."
        if coxVisitedEmporium:
            mom "I wonder if I can find a nice blouse to go with it at the Emporium..."
            mom "I'm not sure how much I can adjust my current one..."
            mom "I should probably go there and have a look."
        elif coxCoxTutorial:
            mom "That crazy girl who randomly showed up did mention she runs a clothing store at the mall.."
            mom "Perhaps I should go there and see if I can find a cute blouse to go with this skirt."
            mom "I don't think I can adjust my current blouse all that much more."
    call mc_display("neutral")
    $ mom.set_pants_off(True)
    "You slowly but surely wiggle your way out of the tiny skirt again, then put it away in your closet before getting dressed."
    call clear_frames(mom)
    call dress_daily()
    $ mom.add_corruption_tag("coxSewedSkirtAgain")
        
        
    return  #endBlc

