init 3 python:
    if persistent.active_mods.get("coxSluttery", False):
        ModdedMenuOption(
            target_script = "game/Locations/Home/Mom_Bedroom/mom_closet_events.rpy",
            target_line = 3,
            menu_label = "The {color=ff91e8}Cox{/color} Closet",
            destination_label = "coxCloset",
            prefered_index = -1)
        
        ModdedMenuOption(
            target_script = "game/Locations/Home/Livingroom/mall_events.rpy",
            target_line = 19,
            menu_label = "{color=ff91e8}Cox Beauty Emporium{/color}",
            destination_label = "coxEnterEmporium",
            prefered_index = -1)
            
        ModdedMenuOption(           
            target_script = "game/Locations/Home/Mom_Bedroom/mom_sewing_events.rpy",
            target_line = 3,
            menu_label = "*Adjust the skirt of your work outfit further*",
            kwargs = {"corruption_requirement": 4, "stress_requirement": 10, "advance_time": True},
            destination_label = "coxSewSkirt",
            requirement_function = lambda:cutdown_teacher_outfit.unlocked and not mom.has_corruption_tag("coxSewedSkirtAgain"),
            prefered_index = -1)
                    
        
        config.label_overrides.update({"change_location":"coxChangeLocation",
                                    "dress_daily":"coxDressDaily",
                                    "cheerleader_dresser_interact":"coxCheerDresser"})
    
label coxChangeLocation(new_location, with_black = False):
    $ mom.current_location = new_location
    $ coxLocationDick["Previous"] = coxLocationDick["Current"]
    $ coxLocationDick["Current"] = new_location.name
    
    if coxExtendCasual:
        if coxLocationDick[new_location.name] != coxLocationDick[coxLocationDick["Previous"]]:  # if the value tied to the name of the new location is not the same as the value tied to the previous location (for instance, went from "Home" to "Shopping")
            if coxLocationDick[new_location.name] == "Church" and coxPlusOneChurch:
                $ mom.default_homewear = coxCasualChurch
                $ mom.set_current_outfit(mom.default_homewear)
            elif coxLocationDick[new_location.name] == "Shopping":
                $ mom.default_homewear = coxCasualShopping
                $ mom.set_current_outfit(mom.default_homewear)
                $ mom.reset_outfit()
            elif (coxLocationDick[coxLocationDick["Previous"]] == "Shopping" or coxLocationDick[coxLocationDick["Previous"]] == "Church") and coxLocationDick[coxLocationDick["Current"]] == "Home":
                $ mom.default_homewear = lListExtendedCasual[time_of_day]
                $ mom.set_current_outfit(mom.default_homewear)
    if with_black:
        show screen expression new_location.screen_name with Fade(0.2, 0.1, 0.2)
    else:
        show screen expression new_location.screen_name with Dissolve(0.1)
    return

label coxDressDaily():
    call dress_underwear()
    
    if coxExtendCasual and coxLocationDick[mom.current_location.name] == "Home" and mom.default_homewear is not lListExtendedCasual[time_of_day]: # if we're at home when this is called and the current default_homewear does not correspond to the time-based outfit
        $ mom.default_homewear = lListExtendedCasual[time_of_day]  # index corresponds to save slots for time-based outfits
        
    if mom.default_homewear and mom.default_homewear.check_visible():
        $ mom.set_current_outfit(mom.default_homewear)
    else:
        call dress_options(list_of_outfits, do_dress = True)
        $ mom.default_homewear = _return
    return

label coxCheerDresser():        #codeBlc
    menu menuCheerDresser:
        mom "I'll just organise her outfits a bit..."
        "*Pick a home outfit*":
            $ cheerleader.outfit_manager.apply_outfit(coxCheerDefaultHome)
            call npc_display(cheerleader)
            call coxChooseOutfit(lOutfits=lListCheerHomeOutfits, thePerson=cheerleader, mom_say="What should [cheerleader.first_name] wear at home?")
            if _return == "Back":
                $ cheerleader.reset_outfit()
                call npc_exit(cheerleader)
                jump menuCheerDresser
            else:
                $ cheerleader.outfit_manager.apply_outfit(_return)
                $ coxCheerDefaultHome = _return
                "You pick out [cheerleader.first_name]\'s home outfit."
                $ cheerleader.reset_outfit()
                call npc_exit(cheerleader)
                jump menuCheerDresser
                
        "*Pick a school outfit*":
            $ cheerleader.outfit_manager.apply_outfit(coxCheerDefaultSchool)
            call npc_display(cheerleader)
            call coxChooseOutfit(lOutfits=lListCheerSchoolOutfits, thePerson=cheerleader, mom_say="What should [cheerleader.first_name] wear to school?")
            if _return == "Back":
                $ cheerleader.reset_outfit()
                call npc_exit(cheerleader)
                jump menuCheerDresser
            else:
                $ cheerleader.outfit_manager.apply_outfit(_return)
                $ coxCheerDefaultSchool = _return
                "You pick out [cheerleader.first_name]\'s school outfit."
                $ cheerleader.reset_outfit()
                call npc_exit(cheerleader)
                jump menuCheerDresser
                
        "*Pick underwear*":
            $ cheerleader.outfit_manager.set_shirt_off(True)
            $ cheerleader.outfit_manager.set_pants_off(True)
            call npc_display(cheerleader)
            call coxChooseOutfit(lOutfits=lListCheerUnderwear, thePerson=cheerleader, mom_say="What should [cheerleader.first_name] wear at home?")
            if _return == "Back":
                $ cheerleader.reset_outfit()
                call npc_exit(cheerleader)
                jump menuCheerDresser
            else:
                $ cheerleader.outfit_manager.apply_outfit(_return)
                $ coxCheerDefaultUnderwear = _return
                "You pick out [cheerleader.first_name]\'s underwear."
                $ cheerleader.reset_outfit()
                call npc_exit(cheerleader)
                jump menuCheerDresser
        
        "The {color=ff91e8}Cox{/color} Closet":
            call coxCloset(thePerson=cheerleader)
        "*Step away*":
            pass
    return                  #endBlc

