
#####################################################################
#					KROGNEATH		
#####################################################################
label interact_krogneath(interaction, item = False, tags=[]):

    if False:
        kro "\"I don't know you, Human.\""

        return()

    #####################################################################
    #                USE ITEM ON
    #####################################################################
    if interaction == "use":
        "You better not do that."

    #####################################################################
    #                DIRECT INTERACT
    #####################################################################
    elif interaction == "interact":
        $ mCondOptions = [
            "Buy Weapons/m", "True",
            "Chat/c", "True",
            "Done/x", "True"
        ]

        # Compile options

        while True:
            call screen menu_interactive_scr(" ", mCondOptions, [])
            play sound "audio/click.wav"
            if _return == "Done":
                return()

            #####################################################################
            #                MISSIONS
            #####################################################################

            elif _return == "Buy Weapons":
                if "pirate_affiliate" not in GAME.mc.done:
                    kro "\"I sell weapons only to members and affiliates...\""
                elif GAME.mc.attr["NOT"] < 5:
                    kro "\"Never heard of your exploits.\""
                    mc "{i}\"Hmm, I better up my notoriety a bit to impress him...\"{/i}"
                else:
                    kro "\"Visit me in my ship during the day.\""
                    $ renpy.say(kro, vary("\"I just ordered a bottle of Voronian Vortex...|I'm out with my pet tonight...|I have other business to attend to now...|I have other plans tonight...\""))
                    
    
            #####################################################################
            #                IDLETALK
            #####################################################################

            elif _return == "Chat":

                #####################################################################
                #                CHAT INTERCEPTS
                #####################################################################
                if GAME.questSys.inProgress("QID_SERAPHINE_KRELL_SPONSOR"):
                    queue sound "audio/notify.wav"
                    mc "\"As a good customer, I need a favour...\""
                    kro "\"What kind of favour?\""
                    mc "\"I need an Endorsement for trade missions into Krell Space...\""
                    kro "\"Our Systems are dangerous places for Non-Krell.\""
                    kro "\"You seem capable enough to not embarass me, Human.\""
                    kro "\"And more trade is always good.\""
                    kro "\"Especially if it helps to crush your opposition.\""
                    kro "\"Rule of Commerce 43...\""
                    mc "\"Ahem, ...of course.\""
                    kro "\"I will inform the Grand Trademaster regarding my Endorsement.\""
                    kro "\"Bring me Krell Bio-Wares from time to time.\""
                    kro "\"Those are hard to get here and yield a considerable profit in Iltari.\""
                    kro "\"And don't make me look bad.\""
                    mc "\"I will do my best.\""
                    kro "\"One other thing...\""
                    mc "\"Yes?\""
                    kro "\"One day, and that day might never come, I will ask you for a favour in return...\""
                    mc "\"I see.\""
                    mc "\"Agreed.\""
                    $ GAME.mc.hasDone("endorsement_krogneath")
                    $ GAME.starSys["SSIDArellarti"].unlocked = True
                    call simple_notify("STAR SYSTEM UNLOCKED", "Arellarti (Krell Space)", ["Continue"], "05_gui/ico_gui_quest.png") from _call_simple_notify_119 
                    call quest_updater() from _call_quest_updater_217 
                    return()
                    
                elif GAME.questSys.inProgress('QID_TRIS_PET_KICKOFF'):
                    queue sound "audio/notify.wav"
                    kro "\"Ah, thank you for finally showing up...\""
                    mc "\"I was delayed in Arellarti...\""
                    mc "\"Things got kind of out of hand there...\""
                    kro "\"Yes, I've heard.\""
                    mc "\"You did?\""
                    kro "\"Really outlandish things if you ask me...\""
                    kro "\"A Princess enters the System but then mysteriously escapes...\""
                    kro "\"It is rumoured three Krell Lashers were destroyed!\""
                    kro "\"A foreign agent, if you ask me..."
                    mc "\"Maybe the Lizard People of Zebulon Three?\""
                    kro "\"Maybe...\""
                    kro "\"I have no doubt they will find the perpetrator...\""
                    mc "\"Certainly.\""
                    kro "\"But back to business...\""
                    kro "\"I need your services...\""
                    mc "\"In what capacity?\""
                    kro "\"I have had a string of bad luck with logistics lately.\""
                    kro "\"I need for someone to go to Arellarti and procure Krell Speciality Goods for me.\""
                    mc "\"Which goods?\""
                    kro "\"Plasmoid Spheres, Bio Activators or Bio Weapons.\""
                    kro "\"Any of those are fine, but I need at least 100t.\""
                    mc "\"I'll get right to it.\""
                    kro "\"You can expect a handsome profit delivering them to me.\""
                    kro "\"They sell for a premium here in Iltari System.\""
                    mc "\"I'll be back with the wares soon.\""
                    kro "\"Excellent.\""
                    $ krogneath.hasDone("delivery_request")
                    call quest_updater() from _call_quest_updater_218 
                    return()

                elif GAME.questSys.inProgress("QID_MAIN_SWARMKROG"):
                    queue sound "audio/notify.wav"
                    kro "\"Well met again, Human!\""
                    kro "\"I hope business is going well...\""
                    mc "\"Yes, about that...\""
                    mc "\"I have discovered interesting information regarding the Quthor Gate...\""
                    kro "\"Continue...\""
                    mc "\"It seems one Gate Module is missing...\""
                    mc "\"Conveniently shutting down the Connection to Iltari...\""
                    kro "\"Don't you say!\""
                    kro "\"It was one of those Lizards from Zebulon III, no doubt.\""
                    mc "\"The signatures we detected were indubitably of Krell Origin...\""
                    kro "\"That is a serious accusation...\""
                    kro "\"One could lose a lot spreading such unsubstantiated rumours...\""
                    kro "\"One's life for example...\""
                    mc "\"Let's not be hasty here...\""
                    mc "\"I have a business proposition...\""
                    kro "\"I am listening...\""
                    mc "\"For certain reasons I need that Gate Connection to be restored...\""
                    mc "\"If it were, any Trader in Iltari would greatly benefit...\""
                    mc "\"Imagine the profits with Quthor Wares...\""
                    kro "\"They would be substantial...\""
                    mc "\"Belit sends her regards in that respect...\""
                    kro "\"I see...\""
                    mc "\"I could, ahem... advance that situation...\""
                    mc "\"Without anyone else needing to get involved...\""
                    mc "\"So if someone could point me in the right direction...\""
                    kro "\"If there were such a hypothetical someone...\""
                    kro "\"It stands to reason he would contact you at some time... \""
                    mc "\"I see...\""
                    mc "\"Thank you for your time...\""
                    kro "\"May your profits multiply ...\""
                    stop music
                    hide screen displayPresentActors
                    scene intermission with fade 
                    "You make your way back to the ship..."
                    scene room_cargo_smart with fade 
                    "As you enter the Cargo Bay..."
                    queue sound "audio/notify.wav"
                    nim "\"Captain, we have received an encrypted transmission...\""
                    mc "\"What does it say?\""
                    nim "\"It is from an anonymous sender...\""
                    mc "\"Can you decipher it?\""
                    nim "\"It points out a site in Arellarti Asteroid Belt...\""
                    nim "\"A Secret Military Base...\""
                    tri "\"Well defended no doubt...\""
                    khe "\"We could go in and blow those toads to pieces!\""
                    tri "\"I advise we use a more stealthy approach.\""
                    tri "\"Deploying a high end Infiltrator might help us again...\""
                    mc "\"Mark the coordinates on the Nav Map...\""
                    mc "\"We'll think about our strategy when we arrive...\""
                    queue sound "audio/beep.wav"
                    nim "\"Understood.\""
                    $ krogneath.hasDone("gate_inquiry")
                    call quest_updater() from _call_quest_updater_219 
                    call sandbox_interior_navigate_to("LOCCargo") from _call_sandbox_interior_navigate_to_92 
                    return() 

                elif GAME.questSys.inProgress('QID_SERAPHINE_SUB_KICKOFF'):
                    # WIP 1.60 Improve causality / Sera trigger review
                    queue sound "audio/notify.wav"
                    kro "\"Well met Human.\""
                    if not krogneath.hasDone("seraphine_talk"):
                        kro "\"And just in time...\""
                        mc "\"What is up?\""
                        kro "\"Some disconcerting news has reached my ears...\""
                        mc "\"Such as?\""
                        kro "\"It concerns that vanished Princess...\""
                        mc "\"Some say she has been abducted by the Lizards...?\""
                        kro "\"That is one way to put it...\""
                        kro "\"One could also say that it was a ruse...\""
                        kro "\"Another way to put it is that it was a ruse conducted by a certain Human...\""
                        kro "\"And yet another way to put it is to say that Human is you...\""
                        mc "\"Well, ahem..., I can explain that.\""
                        mc "\"I was attacked by three Krell ships...\""
                        mc "\"Totally unprovoked...\""
                        kro "\"No need to worry as long as we come to an agreement...\""
                        mc "\"What kind of agreement?\""
                        kro "\"Those ships about to capture the Princess were from the Plaskor Trade League...\""
                        kro "\"I do not bemoan their passing...\""
                        kro "\"That organization has been like Gripkelp around my neck for years now...  \""
                        mc "\"They have?\""
                        kro "\"Yes, and they slowly crept into many positions of power...\""
                        kro "\"I need to re-establish my standing with a splash!\""
                        mc "\"How can I help?\""
                        kro "\"If I announce I captured the Princess from the Lizards of Zebulon...\""
                        kro "\"And presented her in a big parade in Arellarti...\""
                        kro "\"Decked out in the finest Pony Regalia...\""
                        kro "\"My reputation would soar!\""
                        mc "\"Without doubt...\""
                        mc "\"Assuming I actually had such a Princess on my ship...\""
                        mc "\"I'm not sure I would want to sell her...\""
                        kro "\"It would help you with your predicament as well...\""
                        mc "\"How so...?\""
                        kro "\"After the Parade, I could 'sell' her to a very affluent Trader...\""
                        kro "\"Who in turn would gain in reputation as well...\""
                        kro "\"And now had an explanation why she would be on his ship...\""
                        kro "\"And not be hounded by suspicious Krell Executors...\""
                        kro "\"Or even entire Krell Sanction Fleets...\""
                        mc "\"The proposal sounds more appealing by the minute...\""
                        kro "\"I know it would...\""
                        kro "\"Of course that Trader would have to pay me 20 Million Credits...\""
                        mc "\"20 Million!?\"" with vpunch
                        kro "\"She is a Princess after all...\""
                        kro "\"From another Galaxy no less...\""
                        mc "\"But still...\""
                        kro "\"We are talking about a very affluent Trader, remember?\""
                        mc "\"Ah, yes, vaguely...\""
                        kro "\"Are you interested?\""
                        mc "\"I'd have to convince that increasingly less hypothetical Princess...\""
                        mc "\"She's a bit difficult you know...\""
                        kro "\"That's why I'm only asking for 20 Million...\""
                    else:
                        kro "\"Have you reconsidered my offer?\""
                        mc "\"I might...\""
                    kro "\"What do you say?\""
                    queue sound "audio/notify.wav"
                    call large_notify("AN OFFER YOU CAN'T REFUSE", "Krogneath has offered you a clever way to 'legalize' Seraphine's presence on your ship. Of course you would have to pay him 20 Million and convince Seraphine...\n\nWhat do you say?", ["Accept", "Decline"], "05_gui/ico_Seraphine.png") from _call_large_notify_95
                    if _return == "Accept" and GAME.money >= 20000000:
                        mc "\"Deal!\""
                        kro "\"Excellent.\""
                        $ krogneath.hasDone("seraphine_deal")
                        call transaction("Krogneath's Deal", -20000000, True) from _call_transaction_54
                        call sandbox_interior_navigate_to("LOCPirateDock") from _call_sandbox_interior_navigate_to_93
                        call quest_updater() from _call_quest_updater_220
                    elif _return == "Accept":
                        kro "\"You lack the funds for that deal...\""
                        mc "\"Ah, right...\""
                        mc "\"I am a bit short...\""
                        kro "\"I suggest you focus on your business and contact me when you're ready...\""
                        mc "\"Will do...\""
                        kro "\"I could give you a credit...\""
                        kro "\"Only 10 percent interest per week...\""
                        mc "\"I'll get the money, don't worry...\""
                        kro "\"Don't take too much time...\""
                    else:
                        mc "\"I have to think about that...\""
                        kro "\"Don't take too much time...\""
                    return()

                elif GAME.questSys.inProgress('QID_SERAPHINE_SUB_REPORT'):
                    queue sound "audio/notify.wav"
                    kro "\"I would have expected you sooner...\""
                    mc "\"It took some time to, ahem.. prepare Seraphine.\""
                    kro "\"Yes, those Princesses...\""
                    kro "\"Great for status but very high maintenance...\""
                    mc "\"You could say so...\""
                    mc "\"So how do we proceed?\""
                    kro "\"Meet me in the Krell Dome.\""
                    mc "\"They won't let me dock, I think...\""
                    kro "\"I will register your ship as a part of my trade fleet...\""
                    kro "\"And nominate you as one of my commercial representatives...\""
                    mc "\"Excellent...\""
                    mc "\"Where exactly do we meet?\""
                    kro "\"Just dock at the Dome and I'll contact you the next morning...\""
                    mc "\"Right.\""
                    mc "\"I'll meet you there as fast as I can...\""
                    $ krogneath.hasDone("plan_started")
                    $ krogneath.hasDoneToday("plan_started")
                    call quest_updater() from _call_quest_updater_221
                    return()

                #####################################################################
                #				REGULAR CHAT
                #####################################################################
                $ chat = [
                    [["ACTKRO"],"any", "DIAGeneric001", {}, "True", [],
                    [ "kr", "<The most beautiful women in the Sector serve onboard my ship...|I like human women...|I like gold...|What do you think of my latest Pet?|Princess Pets are very high maintenance...|One of my Pets once won the Dome Pony Tournament...>",
                    "mc", "<Well,...|Interesting...|Ahem...>"]
                    ]
                ]

                call npc_talk(krogneath, chat) from _call_npc_talk_23 

#####################################################################
#					VIGO		
#####################################################################
label interact_vigo(interaction, item = False, tags=[]):

    if  "met_vigo" not in GAME.mc.done:
        queue sound "audio/notify.wav"
        vig "\"A new face...\""
        vig "\"Interesting.\""
        vig "\"You're not from around here?\""
        mc "\"Ahem,... you could say that.\""
        vig "\"Nimhe said you would come by...\""
        vig "\"Give her my thanks for the present...\""
        mc "\"I will.\""
        vig "\"Down to business.\""
        vig "\"What do you want here?\""
        mc "\"I'd like to explore the, ahem... commercial possibilities of this base.\""
        mc "\"Selling bots, buying weapons...\""
        vig "\"Hold your horses.\""
        vig "\"A landing permit is one thing.\""
        vig "\"Doing business is another.\""
        mc "\"It is?\""
        vig "\"I might endorse your membership in our association...\""
        vig "\"...if you do me a small favour.\""
        mc "\"What kind of favour?\""
        vig "\"There is Ghad, a troublesome individual, you could deal with for me.\""
        vig "\"He is hiding in the Asteroid Field.\""
        vig "\"Preying on colonists, engaging in slave trade and the likes...\""
        vig "\"That's bad for business...\""
        vig "\"Drive him out and you'll be approved for doing business here.\""
        mc "\"I'd probably need some form of weapon for that...\""
        vig "\"If you don't want to be killed, yes.\""
        vig "\"A shield would be advisable too.\""
        mc "\"Where can I get those?\""
        vig "\"Iltari Station sells some basic gear.\""
        vig "\"You can ask there for a weapons license.\""
        vig "\"You need that anyway for 'camouflage'.\""
        vig "\"Can't have people flying around here flouting their illegal weapons...\""
        vig "\"That would draw undue attention.\""
        mc "\"Fine, I'll get one.\""
        vig "\"Come back once you have.\""
        $ GAME.mc.hasDone("met_vigo")
        call quest_updater() from _call_quest_updater_222 
        return()

    if GAME.questSys.inProgress("QID_PIRATE_TASK"):
        vig "\"You have a task to do.\"" 
        return()

    if GAME.questSys.inProgress("QID_PIRATE_LANDING"):
        queue sound "audio/notify.wav"
        vig "\"Excellent, you defeated Ghad.\""
        vig "\"Good riddance.\"" 
        vig "\"I hereby assign you the title of 'Affiliate'.\""
        vig "\"This should give you access to weapons and more.\""
        vig "\"Also, if you are interested in hiring help...\""
        vig "\"Khelara, an acquaintance of mine is available for hire.\""
        vig "\"She's an excellent engineer.\""
        mc "\"Great!\""
        mc "\"I will consider that.\""
        vig "\"As Affiliate, you're eligible for transport or bounty missions.\""
        vig "\"Those will help you make a name for yourself.\""
        mc "\"Thanks.\""
        $ GAME.mc.hasDone("pirate_affiliate")
        call quest_updater() from _call_quest_updater_223 
        call quest_updater() from _call_quest_updater_224 
        call quest_updater() from _call_quest_updater_225 
        return()
       

    #####################################################################
    #                USE ITEM ON
    #####################################################################
    if interaction == "use":
        "You better not do that."

    #####################################################################
    #                DIRECT INTERACT
    #####################################################################
    elif interaction == "interact":
        $ mCondOptions = [
            "Base Purchase/b", "'base_talk' in vigo.done and not GAME.base.unlocked", # CR-XXXX
            "Missions/m", "True",
            "Combat Advice/a", "True",
            "Chat/c", "True",
            "Done/x", "True"
        ]

        # Compile options

        while True:
            call screen menu_interactive_scr(" ", mCondOptions, [])
            play sound "audio/click.wav"
            if _return == "Done":
                return()

            #####################################################################
            #                MISSIONS
            #####################################################################

            elif _return == "Base Purchase":
                queue sound "audio/notify.wav"
                mc "\"I've made up my mind.\""
                mc "\"I would like to purchase the Base on Tenaris...\""
                vig "\"Excellent.\""
                vig "\"Approve the Credit Transfer here...\""
                queue sound "audio/notify.wav"
                call simple_notify("TRANSFER REQUEST", "Amount: 4,500,000 Cr", ["Authorize", "Abort"], "08_items/ico ITMCoin.png") from _call_simple_notify_120 
                if _return == "Abort":
                    vig "\"Don't wait too long.\""
                    vig "\"There might be other takers...\""
                elif _return == "Authorize" and GAME.money < 4500000: # CR-0877
                    mc "\"I don't have the amount yet.\""
                    vig "\"I see...\""
                else:                
                    mc "\"Here you go...\""
                    call transaction("Base Purchase", -4500000, True) from _call_transaction_55 
                    vig "\"Great.\""
                    vig "\"Make the most of it.\""
                    queue sound "audio/notify.wav"
                    call simple_notify("PLAYER BASE TENARIS", "You have acquired a Base!", ["Continue"], "05_gui/ico Ship.png", "orange") from _call_simple_notify_121 
                    mc "\"I will.\""
                    $ GAME.base.unlocked = True     
                    $ GAME.surfaces["SUIDTenaris"].found = True     

  
            #####################################################################
            #                MISSIONS
            #####################################################################

            elif _return == "Missions":
                if not "pirate_affiliate" in GAME.mc.done:
                    vig "\"For members and affiliates only.\""
                else:
                    # Note: missions are created in night_passes 
                    vig "\"Available missions are continously transmitted to your data terminal.\""
                    if not GAME.mc.hasDone("concerns_missions"):
                        vig "\"They will be updated nightly.\""
                        mc "\"Are these transmissions safe?\""
                        vig "\"What do you mean?\""
                        mc "\"Some of those missions might not be exactly legal...\""
                        vig "\"They are encrypted to your transponder code.\""
                        vig "\"Perfectly safe.\""
                        mc "\"I see.\""
                    else:
                        mc "\"Ah yes.\""
                    # select mission
                    # call screen mission_selector_scr(vigo.missions)
                    # if _return:
                    #     $ mission = _return[1]
                    #     $ fee = int(mission.reward*0.05)
                    #     if len(GAME.missionSys.getDueMissions()) > 2:
                    #         vig "\"I suggest you finish those missions you have already.\""
                    #     elif GAME.money < fee:
                    #         vig "\"You can't afford the signing bonus.\""
                    #     else:
                    #         call transaction("Signing Fees", -fee, True)
                    #         $ GAME.missionSys.acceptMission(mission)
                    #         vig "\"Signing herewith confirmed.\""
                    #         vig "\"Don't kill yourself.\""
                    #         $ vigo.missions.remove(mission)
                    # else:
                    #     mc "\"Maybe another time...\""
                    #     vig "\"Suit yourself.\""

            #####################################################################
            #                COMBAT ADVICE
            #####################################################################

            elif _return == "Combat Advice":

                #######################################################
                #				REGULAR CHAT
                #####################################################################
                $ advice = [
                    [["ACTVIG"],"any", "ADVMOBGEN", {}, "True", [],
                    [ "vi", "<It is advisable to take cover and end your turn before the enemy attacks.>",
                    "mc", "<I see...|Interesting.>"]
                    ],

                    [["ACTVIG"],"daily", "ADVMOBMAR", {}, "True", [],
                    [ "vi", "<Marauders have only light shields and cannons.>",
                    "vi", "<They should be easily defeatable with basic equipment.>",
                    "mc", "<I see..|Interesting.>"]
                    ],

                    [["ACTVIG"],"daily", "ADVMOBBRI", {}, "True", [],
                    [ "vi", "<Brigands have medium shields and cannons.>",
                    "vi", "<A neutronium shield and cannon is recommended.>",
                    "mc", "<I see...|Interesting.>"]
                    ],

                    [["ACTVIG"],"daily", "ADVMOBEXE", {}, "True", [],
                    [ "vi", "<Executors are heavily armed and shielded.>",
                    "vi", "<Go well prepared.>",
                    "vi", "<Quantum gear and at least neutronium torpedoes are recommended.>",
                    "vi", "<They spawn seeker drones, that will home in and detonate in proximity.>",
                    "mc", "<I see...|Interesting.>"]
                    ],

                    [ ["ACTVIG"],"daily", "ADVMOBKRE", {}, "True", [],
                    ["vi", "<Krell Lashers are heavily armed and shielded.>",
                    "vi", "<Go well prepared.>",
                    "vi", "<Quantum gear and at least neutronium torpedoes are recommended.>",                    
                    "vi", "<Take out their seeker with torpedoes and make use of their area effect.>",
                    "vi", "<Never end your actions without taking cover.>",
                    "vi", "<And have your engine geared up with dynamics modules...>",                    
                    "mc", "<I see...|Interesting.>"]],

                    [["ACTVIG"],"daily", "ADVMOBSWA", {}, "True", [],
                    [ "vi", "<Swarms attack in open space with little cover.>",
                    "vi", "<They have medium shields and weapons.>",
                    "vi", "<Take out groups at a time by maneuvering intelligently.>",
                    "vi", "<Without neutronium or better torpedoes you will not prevail.>",
                    "mc", "<I see...|Interesting.>"]
                    ]                                   
                ]

                call npc_talk(vigo, advice) from _call_npc_talk_24 
            #####################################################################
            #                IDLETALK
            #####################################################################

            elif _return == "Chat":

                #####################################################################
                #                CHAT INTERCEPTS
                #####################################################################
                if GAME.base.unlocked == False and GAME.mc.getAttr("NOT")+GAME.mc.getAttr("REP") >= 30 and "base_talk" not in vigo.done: # CR-0582
                    $ vigo.hasDone("base_talk") # CR-XXXX
                    queue sound "audio/notify.wav"
                    vig "\"If it isn't Captain [GAME.mc.name]!\""
                    mc "\"The same...\""
                    vig "\"You've left quite an impression in this system...\""
                    mc "\"Thank you...\""
                    vig "\"I might have an opportunity for you to improve your Merchant credibility further...\""
                    mc "\"Really?\""
                    vig "\"As it happens, I have acquired a small Base on Tenaris...\""
                    vig "\"It is well hidden and can be used to store goods and for other things...\""
                    mc "\"Sounds interesting...\""
                    vig "\"I am willing to part with it as I cannot visit Tenaris as often as I like...\""
                    vig "\"For an appropriate sum I would be willing to sell it to you.\""
                    vig "\"You will get the Base Access Keys and the Coordinates on Tenaris' surface...\""
                    mc "\"How much will this set me back?\""
                    vig "\"4.5 Million...\""
                    mc "\"Whooaahh...\""
                    vig "\"A reasonable price for a Base of your own...\""
                    mc "\"I need to think about it...\""
                    vig "\"Let me know once you made up your mind...\""
                    mc "\"I will...\""

                #####################################################################
                #				REGULAR CHAT
                #####################################################################
                $ chat = [
                    [["ACTVIG"],"any", "DIAGeneric001", {}, "True", [],
                    [ "vi", "<The bribes I pay are killing me...|The Krell are getting more difficult to control with each day...|That Precursor Junkyard attracts adventurers of the craziest kind...|Some more dangerous brigands transport spare AI-Cores...>",
                    "mc", "<Is that so?|Indeed.|Really?|Interesting.>"]
                    ]
                ]

                call npc_talk(vigo, chat) from _call_npc_talk_25 

#####################################################################
#					TERI		
#####################################################################
label interact_teri(interaction, item = False, tags=[]):

    if False:
        ter "\"I'm busy.\""

        return()

    #####################################################################
    #                USE ITEM ON
    #####################################################################
    if interaction == "use":
        "You better not do that."

    #####################################################################
    #                DIRECT INTERACT
    #####################################################################
    elif interaction == "interact":
        $ mCondOptions = [
            "Chat/c", "True",
            "Done/x", "True"
        ]

        # Compile options

        while True:
            call screen menu_interactive_scr(" ", mCondOptions, [])
            play sound "audio/click.wav"
            if _return == "Done":
                return()
            
            #####################################################################
            #                IDLETALK
            #####################################################################

            elif _return == "Chat":

                #####################################################################
                #                CHAT INTERCEPTS
                #####################################################################
                if False:
                    return()
                    
                #####################################################################
                #				REGULAR CHAT
                #####################################################################
                $ chat = [
                    [["ACTTER"],"any", "DIATeri001", {}, "True", [],
                    [ "te", "<Once Krogneath offered me my weight in gold...|Tipping has gone down lately...|We're always looking for bots improving our Arcade|The Entertainment Floor is currently under renovation...|Did you know that Krogneath's latest pet is a real Princess?|I heard they do Ponygirl Races at The Dome...|I once worked as an extra in a Galaxina Episode...>",
                    "mc", "<Is that so?|Indeed.|Really?|Interesting.>"]
                    ],
                    [["ACTTER"],"daily", "DIATeri002", {}, "True", [],
                    [   "mc", "<I like your outfit...|Nice rack...>",
                        "te", "<I wear the required service personnel outfit.|Every thing you see is natural...|Working with my tits out took some getting used to...|It greatly helps with tips...>",
                        "te", "<I wish we were allowed bottoms, though.| I wish my outfit came with bottoms, though...>",
                        "mc", "<I see.>"]
                    ],
                    [["ACTTER"],"daily", "DIATeri003", {}, "True", [],
                    [   "mc", "<Is the Upper Floor open?>",
                        "te", "It's under renovation.",
                        "mc", "<I see.|Interesting...>"]
                    ],        
                    [["ACTTER"],"daily", "DIATeri004", {}, "True", [],
                    [   "mc", "<Do you have Bots or, ahem... Service Personnel on the Upper Floor?>",
                        "te", "Both.",
                        "mc", "<I see.|Interesting...>"]
                    ],    
                    [["ACTTER"],"daily", "DIATeri005", {}, "True", [],
                    [   "mc", "<Do you work on the Upper Floor as well?>",
                        "te", "Occasionally.",
                        "mc", "<I see.|Interesting...>"]
                    ]                  
                ]

                call npc_talk(teri, chat) from _call_npc_talk_26 

#####################################################################
#					VERITY		
#####################################################################
label interact_verity(interaction, item = False, tags=[]):
    if False:
        vet "\"I'm busy.\""

        return()

    #####################################################################
    #                USE ITEM ON
    #####################################################################
    if interaction == "use":
        # CR-2132 START
        if "ITMDrink" in item.ID:
        # CR-2132 END
            queue sound "audio/notify.wav"
            if not verity.hasDoneToday("drink"):
                vet "\"Nice, free drinks!\""
                $ GAME.mc.remItem(item.ID)
                $ verity.doneToday.append(item.ID)
                queue sound "audio/notify.wav"
                call attr_mod(verity, "APP", 1, 8, 100, True) from _call_attr_mod_89 
                queue sound "audio/potion.wav"
                vet "\"Has a great twist to it!\""           
            elif verity.doneToday.count("drink") == 1:
                $ GAME.mc.remItem(item.ID)
                $ verity.doneToday.append("drink")
                $ verity.doneToday.append(item.ID)
                queue sound "audio/notify.wav"
                vet "\"Nice, another one...\""
                queue sound "audio/potion.wav"
                vet "\"Tastes great!\""
                vet "\"I'd like to have such a replicator...\""
            else:
                vet "\"I should slow down with the drinks...\""
                vet "\"I need to move a bit to work that off...\""
                return()

        elif item.ID in ["ITMFlyboy01", "ITMFlyboy02"]:
            vet "\"Flyboy Magazine!\""
            vet "\"I had a Special in one of those once!\""
            mc "\"Interesting...\""

        elif item.ID == "ITMOutfitPony":
            vet "\"Oh, a Ponygirl Costume!\""
            vet "\"Quexnor had me wear these for promotion events...\""
            vet "\"Mine was golden and had a white plume!\""

        elif item.ID == "ITMShaverKrell":
            vet "\"A Pet Shaver!\""
            vet "\"I used one of those while working for Quexnor...\""
            vet "\"Krell like their Pets well shaved...\""
            mc "\"Indeed...\""

        else:
            mc "{i}\"I better not do that...\"{/i}"


    #####################################################################
    #                DIRECT INTERACT
    #####################################################################
    elif interaction == "interact":
        $ mCondOptions = [
            "Bridge Tour/b", "verity.doneToday.count('ITMDrinkStarburst69') >= 2",
            "Pole Dance/d", "verity.doneToday.count('drink') >= 2",
            "Chat/c", "True",
            "Done/x", "True"
        ]

        # Compile options

        while True:
            call screen menu_interactive_scr(" ", mCondOptions, [])
            play sound "audio/click.wav"
            if _return == "Done":
                return()
            #####################################################################
            #              BRIDGE TOUR
            #####################################################################
            elif _return == "Bridge Tour":
                mc "\"Would you care for a visit on the Bridge?\""
                vet "\"Awesome!\""
                hide screen displayPresentActors
                scene intermission with fade 
                "A while later..."
                scene expression("10_anims/ani_verity_bridge_00.jpg") with fade 
                window hide 
                pause
                vet "\"Let's go!\""
                scene ani_verity_bridge with fade 
                window hide 
                pause 
                queue sound "audio/squish.wav"
                mc "\"Aaaarghhh\"" with whiteflash 
                queue sound "audio/squish.wav"
                mc "\"Aaaarghhh\"" with whiteflash 
                queue sound "audio/squish.wav"
                scene expression("10_anims/ani_verity_bridge_00.jpg") with whiteflash
                mc "\"Aaaarghhh\"" 
                vet "\"I better get home now...\""
                scene room_bridge_smart with fade
                vet "\"Thanks for the 'tour'...(giggle...)\""
                mc "\"My pleasure...\""
                vet "\"See you later...\""
                $ GAME.galleryAdd(111)
                call attr_mod(verity, "SLU", 1,2,100, True) from _call_attr_mod_90 
                call hour_passes() from _call_hour_passes_101 
                $ GAME.mc.hasDoneToday("verity_met")
                $ GAME.mc.tally["Last Done (Day)"] = GAME.day
                call sandbox_interior_navigate_to("LOCBridge") from _call_sandbox_interior_navigate_to_94 
                return()

            #####################################################################
            #              POLEDANCE
            #####################################################################
            elif _return == "Pole Dance":
                if not verity.hasDone("poledance_intro"):
                    mc "\"Did you see our nice Dancing Stage?\""
                    vet "\"Yes!\""
                    vet "\"Even with a Pole!\""
                    mc "\"Do you know how to use it?\""
                    vet "\"Of course!\""
                    vet "\"I often danced for Quexnor's guests...\""
                    mc "\"Let's see it then...\""
                else:
                    mc "\"How about a Dance Performance?\""

                if verity.getAttr("APP") <= 6:
                    vet "\"Next time...\""
                    mc "\"I'll remind you...\""
                    queue sound "audio/drone_beep.wav"
                    bb2 "\"I will too!\""
                    vet "\"I promise!\""
                    return()
                vet "\"Challenge accepted!\""
                vet "\"Let me get prepared real quick...\""
                queue sound "audio/equip.wav"
                hide screen displayPresentActors
                play music "audio/sjx_custom_spacebar.mp3" 
                scene expression("06_cutscenes/cutscene_verity_pole_start.jpg") with fade
                window hide 
                pause 
                if not verity.hasDone("nude_comment"):
                    mc "\"You're dancing naked?\""
                    vet naked "\"Of course...\""
                else:
                    vet naked "\"Let's go.\""
                scene intermission with fade 
                "Verity proceeds to show off her skills..."
                scene expression("06_cutscenes/cutscene_verity_pole_APP_{}.jpg".format(capValue(verity.getAttr("APP"),5,8))) with fade 
                window hide 
                pause
                queue sound "audio/drone_beep.wav"
                $ renpy.say(bb2, vary("\"<Impressive...|Almost as good as Captain Jennings...|Excellent coordination...|Quite talented...|Well practiced...>\""))
                if verity.getAttr("APP") in [7,8]:
                    $ GAME.galleryAdd({7:108, 8:109}[verity.getAttr("APP")])
                vet naked "\"That was fun....\""
                stop music fadeout 2.0
                scene room_mess_room_smart with fade
                vet "\"I better get back now...\""
                vet "\"Thanks for the invitation...\""
                mc "\"My pleasure...\""
                call hour_passes() from _call_hour_passes_102 
                $ GAME.mc.hasDoneToday("verity_met")
                return()
            #####################################################################
            #                IDLETALK
            #####################################################################

            elif _return == "Chat":

                #####################################################################
                #                CHAT INTERCEPTS
                #####################################################################
                if False:
                    return()
                    
                #####################################################################
                #				REGULAR CHAT
                #####################################################################
                $ chat = [
                    [["ACTVTY"],"any", "DIAVerity001", {}, "True", [],
                    [ "vet", "<Iltari Station is quite boring...>",
                    "mc", "<At least it is safe...|Indeed.>"]
                    ],
                    [["ACTVTY"],"any", "DIAVerity002", {}, "True", [],
                    [ "vet", "<Vortex based cocktails are the best!>",
                    "mc", "<I can imagine...|They should be...|I heard that much...>"]
                    ],
                    [["ACTVTY"],"any", "DIAVerity003", {}, "True", [],
                    [ "vet", "<Krell really can party!|Krell have tons of money!>",
                    "mc", "<I've heard these rumours...|That's what people say...>"] # CR-0858
                    ],
                                      
                ]
                call npc_talk(verity, chat) from _call_npc_talk_27 
    return()

#####################################################################
#					AUDRA		
#####################################################################
label interact_audra(interaction, item = False, tags=[]):

    if audra.getAttr("APP") <= 0 and GAME.mc.getTally("Slaves Rescued") == 0:
        aud "\"I'm busy drinking.\""
        return()

    #####################################################################
    #                USE ITEM ON
    #####################################################################
    if interaction == "use":

        if item.ID == "ITMLiquorDrengar" and "drink" not in audra.doneToday:
            aud "\"A full bottle is a bit much but I wouldn't mind a cocktail...\""
        
        elif item.ID == "ITMLiquorDrengar":
            aud "\"You better be careful with that.\""
            aud "\"I heard it can throw a wrench in your gears if you're male...\""
            aud "\"Standing power wise...\""
            mc "\"Yeah, definitely.\""
        
        else:
            "You better not do that." 
        return()   

    if audra.getAttr("APP") <= 0 and GAME.mc.getTally("Slaves Rescued") > 0 and "expressed_app" not in audra.doneToday:
        queue sound "audio/notify.wav"
        aud "\"Heard regarding the Slaves you rescued.\""
        mc "\"You did?\""
        aud "\"Good job.\""
        mc "\"Thank you.\""
        aud "\"Haven't seen you around here...\""
        mc "\"I'm [GAME.mc.name], a ahem... merchant passing through these systems...\""
        aud "\"My name is Callan, Sergeant in the Iltari Space Guard.\""
        mc "\"Just Callan, no last name?\""
        aud "\"Callan is my last name.\""
        mc "\"No first name?\""
        aud "\"Audra.\""
        mc "\"Pleasure meeting you, Audra, ahem... Sergeant\""
        $ audra.name = "Audra"
        aud "\"Audra is fine.\""
        aud "\"Keep up the good work.\""
        call attr_mod(audra,"APP", 1,1,100 ,True) from _call_attr_mod_91 
        $ audra.hasDoneToday("expressed_app")
        return()

    elif GAME.mc.getTally("Slaves Rescued") >= 5 and audra.getAttr("APP") < 2 and "expressed_app" not in audra.doneToday:
        queue sound "audio/notify.wav"
        aud "\"Good to hear you are continuing your efforts.\""
        aud "\"Slavery needs to be stamped out!\""
        mc "\"Glad I could be of service to Iltari.\"" 
        aud "\"Keep up the good work.\""
        call attr_mod(audra,"APP", 1,2,100 ,True) from _call_attr_mod_92 
        $ audra.hasDoneToday("expressed_app")

    elif GAME.mc.getTally("Slaves Rescued") >= 10 and audra.getAttr("APP") < 3 and "expressed_app" not in audra.doneToday:
        queue sound "audio/notify.wav"
        aud "\"Great job again out in the System.\""
        aud "\"Slavery is a scourge to be abolished!\""
        mc "\"Glad I could be of service to Iltari.\"" 
        aud "\"I am beginning to like you, you know.\""
        call attr_mod(audra,"APP", 1,3,100 ,True) from _call_attr_mod_93 
        $ audra.hasDoneToday("expressed_app")

    elif GAME.mc.getTally("Slaves Rescued") >= 20 and audra.getAttr("APP") < 4 and "expressed_app" not in audra.doneToday:
        queue sound "audio/notify.wav"
        aud "\"The Freedom Champion of Iltari!\""
        aud "\"Great Job!\""
        mc "\"Glad I could help.\"" 
        aud "\"Keep up the good work!\""
        call attr_mod(audra,"APP", 1,4,100 ,True) from _call_attr_mod_94 
        $ audra.hasDoneToday("expressed_app")



    #####################################################################
    #                DIRECT INTERACT
    #####################################################################
    elif interaction == "interact":
        # Compile options
        $ mCondOptions = [
            "Chat/c", "True",
            "Buy Drink/b", "audra.getAttr('APP') >= 1",
            "Invite Over/a", "audra.getAttr('APP') >= 4 and 'drink' in audra.doneToday",            
            "Done/x", "True"
        ]
        mc "\"Hi again.\""
        aud "\"Hello.\""
        while True:
            call screen menu_interactive_scr(" ", mCondOptions, [])
            play sound "audio/click.wav"
            if _return == "Done":
                return()

            #####################################################################
            #                INVITE OVER
            #####################################################################
            elif _return == "Invite Over":
                mc "\"You care to take a, ahem... tour of my ship?\""
                aud "\"I wouldn't mind actually...\""
                mc "\"Great, let's go.\""
                stop music fadeout 2.0
                $ audra.hasDoneToday("tour_ship")
                hide screen displayPresentActors
                call cutscene("audra_sex") from _call_cutscene_35 
                return()

            #####################################################################
            #                DRINK
            #####################################################################
            elif _return == "Buy Drink":    
                if audra.hasDoneToday("drink"):
                    aud "\"Thanks for the offer, but I've had enough drinks for tonight...\""
                    aud "\"Need to be careful with those Drengarian cocktails...\""
                else:
                    "You buy Audra a Drengarian Ice-Tea."
                    queue sound "audio/notify.wav"
                    aud "\"Much appreciated.\""
                    aud "\"Those Drengarian Ice-Teas are no joke...\""
                    $ renpy.say (aud, vary("\"<I once had three of those and was dancing naked on the tables...|One is already enough if you're no Drengarian...|The best choice if you want to get hammered...|They are illegal in some stations...|Too many of those and you'll pass out without fail...>\""))
                    $ audra.hasDoneToday("drink")

            #####################################################################
            #                IDLETALK
            #####################################################################

            elif _return == "Chat":
                #####################################################################
                #                CHAT INTERCEPTS
                #####################################################################
                if False:
                    return()
                    
                #####################################################################
                #				REGULAR CHAT
                #####################################################################
                # CR-1091 START
                $ chat = [
                    [["ACTAUDRA"],"any", "DIAAudra001", {}, "True", [],
                    [ "au", "<Space Patrol pay could be better...|We're always looking for new recruits...|The Krell are a pirating bunch...|Neutron storms are getting stronger this year...>",
                    "mc", "<Is that so?|Indeed.|Really?|Interesting.>"]
                    ]                  
                ]
                # CR-1091 END

                call npc_talk(audra, chat) from _call_npc_talk_28 


    return()

#####################################################################
#              ADMIN PET
#####################################################################

label interact_adminPet(interaction, item = False, tags=[]):
    #####################################################################
    #              USE
    #####################################################################
    if interaction == "use":
        show screen displayPresentActors("LOCArellartiAdmin")
        if item.ID == "ITMOutfitPony":
            queue sound "audio/equip.wav"
            "Chief Admin Pet" "\"A standard Pony Outfit it seems.\""
            "Chief Admin Pet" "\"Tested and certified by this Office.\""
            mc "\"I see...\""
            return()
        if item.ID == "ITMPlugKrell":
            queue sound "audio/equip.wav"
            "Chief Admin Pet" "\"Thank you, but we are issued our own in the Office.\""
            return()
        if item.ID == "ITMLiquorVortex":
            queue sound "audio/potion.wav"
            mc "\"I have a small token of appreciation for the hard working Sub-Administrator...\""
            queue sound "audio/notify.wav"
            "Chief Admin Pet" "\"Voronian Vortex!\""
            "Chief Admin Pet" "\"Thank you, a very thoughtful gesture.\""
            "Chief Admin Pet" "\"I will inform the Sub-Administrator.\""
            if GAME.questSys.inProgress("QID_MOIRA_SUB_PET_APPOINTMENT"):
                
                mc "\"Ahem, how about that appointment...?\""
                "Chief Admin Pet" "\"Let me confirm...\""       
                queue sound "audio/notify.wav"         
                "Chief Admin Pet" "\"I see an appointment has just opened up...\""
                mc "\"Excellent!\""     
                "Chief Admin Pet" "\"Come back tomorrow at 15:00.\""
                "Chief Admin Pet" "\"And don't forget to bring your Pet.\""
                $ GAME.locs["LOCArellartiAdmin"].attr["orlok"] = GAME.day+1
                $ GAME.mc.hasDone("appointment_confirmed")
                $ GAME.mc.hasDoneToday("appointment_confirmed")
                $ GAME.timerSet("T_ORLOK", 1)
                call quest_updater() from _call_quest_updater_226
            return()
        else:
            mc "{i}\"I better not do that...\"{/i}"
        return()
    #####################################################################
    #              INTERACT
    #####################################################################
    if interaction == "interact":
        $ mCondOptions = [
            "Chat/c", "True",
            "Pet Affairs/a", "not GAME.questSys.isDone('QID_MOIRA_SUB_PET_PRESENT')", # blown Off
            "Pet Affairs/a", "GAME.questSys.inProgress('QID_MOIRA_SUB_PET_REEDUCATED')",
            "Appointment/a", "False", # Orlok
            "Done/x", "True"
        ]

        # Compile options

        "Chief Admin Pet" "\"How can I help you?\""

        while True:
            call screen menu_interactive_scr(" ", mCondOptions, [])
            play sound "audio/click.wav"
            if _return == "Done":
                "Chief Admin Pet" "\"I wish you a good day.\""
                return()


            elif _return == "Chat":
                mc "\"How are things going?\""
                "Chief Admin Pet" "\"I have a busy schedule and little time for idle talk.\""

            elif _return == "Pet Affairs":
                if not moira.getLocOverride() == "LOCPetwalk":
                    "Chief Admin Pet" "\"You need to be accompanied by the Pet in question....\""
                    mc "\"Ah, right...\""    
                    call sandbox_interior_navigate_to("LOCArellartiStationDA") from _call_sandbox_interior_navigate_to_95
                    return()  
                if not GAME.mc.hasDone("orlok_request"):
                    mc "\"I wish to see someone called Orlok.\""
                    mc "\"I have an important Pet Registration matter to attend to...\""
                    "Chief Admin Pet" "\"Sub-Administrator Orlok is extremely busy.\""
                    mc "\"When can I see him?\""
                    "Chief Admin Pet" "\"There are no appointments available at this time.\""
                    mc "\"But I must see him!\"" with vpunch
                    "Chief Admin Pet" "\"The demands on Sub-Administrator Orlok's time are formidable.\""
                    queue sound "audio/notify.wav" 
                    moi "\"Listen, Pet...\""
                    moi "\"Get up from your chair, adjust your plug and tell Orlok we are here to see him...\""
                    "Chief Admin Pet" "\"Your Pet is quite unruly.\""
                    "Chief Admin Pet" "\"Might I suggest a Pet Gag for her...\""
                    mc "\"Moira, don't make things worse...\""
                    moi "\"Hrrrmpf....\""
                    "Chief Admin Pet" "\"As I said, there are no appointments available at this time.\""
                    "Chief Admin Pet" "\"Please step aside for the next in line...\"" 
                    mc "\"Another time then...\""                   
                    call sandbox_interior_navigate_to("LOCArellartiStationDA") from _call_sandbox_interior_navigate_to_96
                elif GAME.questSys.inProgress("QID_MOIRA_SUB_PET_PRESENT"):
                    if GAME.locs["LOCArellartiAdmin"].attr["orlok"] > GAME.day:
                        queue sound "audio/notify.wav"
                        mc "\"I'm here to see Sub-Administrator Orlok.\""
                        "Chief Admin Pet" "\"Your appointment is tomorrow at 15:00.\""    
                        mc "\"Ah, right...\""  
                        return()   
                    if GAME.locs["LOCArellartiAdmin"].attr["orlok"] == GAME.day and GAME.hour < 15:
                        queue sound "audio/notify.wav"
                        mc "\"I'm here to see Sub-Administrator Orlok.\""
                        "Chief Admin Pet" "\"You are too early.\""
                        "Chief Admin Pet" "\"The appointment is today at 15:00.\""
                        mc "\"Ah, right.\""
                        return()

                    if GAME.locs["LOCArellartiAdmin"].attr["orlok"] < GAME.day or GAME.hour > 15:
                        queue sound "audio/notify.wav"
                        mc "\"I'm here to see Sub-Administrator Orlok.\""
                        "Chief Admin Pet" "\"You missed your appointment....\""    
                        mc "\"Ah, I had a ship emergency...\""
                        "Chief Admin Pet" "\"An emergency?\"" 
                        mc "\"An act of sabotage.\""
                        "Chief Admin Pet" "\"Sabotage!?\"" 
                        mc "\"Evidence points to Lizard activities...\""        
                        "Chief Admin Pet" "\"I wouldn't put it past them...\""    
                        mc "\"Definitely...\""    
                        "Chief Admin Pet" "\"Those are extenuating circumstances...\""
                    else:
                        queue sound "audio/notify.wav"
                        mc "\"I'm here to see Sub-Administrator Orlok.\""
                        "Chief Admin Pet" "\"Right on time.\""   
                    queue sound "audio/equip key.wav"
                    "Chief Admin Pet" "\"Here, have your Pet wear one of these tags before we go...\""
                    moi "\"A tag!?\""
                    "Chief Admin Pet" "\"We can't have untagged Pets roam the corridors...\""
                    moi "\"Where is your tag?\""
                    "Chief Admin Pet" "\"Our plugs have locator and identification features...\""
                    mc "\"Moira, don't be difficult...\""
                    moi "\"Fine, hand it over then...\""
                    hide screen displayPresentActors
                    scene intermission with fade  
                    scene room_arellarti_admin_smart with fade
                    $ moira.tags.append("krell_tag")
                    moi "\"Happy?\""
                    mc "\"That looks great!\""
                    mc "\"Maybe we introduce those on the ship as well...\""
                    moi "\"Don't push it...\"" 
                    ap "\"Follow me to the Sub-Adminstrator's Office..\""
                    scene expression ("06_cutscenes/cutscene_appointment_one.jpg")
                    window hide 
                    pause
                    call cutscene_moira("orlok_appointment") from _call_cutscene_moira_8
                    return()
                elif GAME.questSys.inProgress("QID_MOIRA_SUB_PET_REEDUCATED"):
                    mc "\"I'm here to present my Pet Certificate for Dr. Moira.\""
                    "Chief Admin Pet" "\"I assume your Pet is well educated now so we don't need a gag......\""
                    moi "\"Hrmpfff...\""
                    queue sound "audio/equip key.wav"
                    "Chief Admin Pet" "\"Equip this tag on your Pet....\""
                    mc "\"One moment...\""
                    hide screen displayPresentActors
                    scene intermission with fade  
                    scene room_arellarti_admin_smart with fade
                    $ moira.tags.append("krell_tag")
                    moi "\"Happy?\""
                    ap "\"Follow me to the Sub-Adminstrator's Office..\""
                    scene expression ("06_cutscenes/cutscene_appointment_one.jpg") with fade
                    window hide  
                    pause
                    call cutscene_moira("orlok_appointment") from _call_cutscene_moira_9
                    return()
                        
                else:
                    mc "\"Is Sub-Administrator Orlok available?.\""
                    "Chief Admin Pet" "\"As I have told you, Sub-Administrator Orlok is extremely busy\""   
                    mc "\"Aaarggh...\""
                queue sound "audio/notify.wav"
                mc "{i}\"That didn't go too well...\"{/i}"
                mc "{i}\"I should think of a way to support my request...\"{/i}"
                mc "{i}\"Or I'll never get that appointment...\"{/i}"
                mc "{i}\"Maybe if I leave a small present for Orlok...\"{/i}"
                return()
            
#####################################################################
#              ADMIN ORLOK
#####################################################################

label interact_adminOrlok(interaction, item = False, tags=[]):
    #####################################################################
    #              USE
    #####################################################################
    if interaction == "use":
        if item.ID == "ITMLiquorVortex":
            queue sound "audio/potion.wav"
            mc "\"I have a small token of appreciation for the hard working Sub-Administrator...\""
            queue sound "audio/notify.wav"
            "Chief Admin Pet" "\"I appreciate the gesture, Human.\""
            "Chief Admin Pet" "\"But this would constitute an undue influence on my decisions...\""
            mc "\"I understand...\""                
            return()
        else:
            mc "{i}\"I better not do that...\"{/i}"
        return()

    #####################################################################
    #              INTERACT
    #####################################################################
    if interaction == "interact":
        $ mCondOptions = [
            "Chat/c", "True",
            "Pet Exemption/e", "GAME.questSys.inProgress('QID_MOIRA_SUB_PET_PRESENT')", 
            "Pet Certificate/c", "GAME.questSys.inProgress('QID_MOIRA_SUB_PET_REEDUCATED')", 
            "Done/x", "True"
        ]

        # Compile options

        while True:
            call screen menu_interactive_scr(" ", mCondOptions, [])
            play sound "audio/click.wav"
            if _return == "Done":
                "Sub-Administrator Orlok" "\"I wish you profitable endevours...\""
                call sandbox_interior_navigate_to("LOCArellartiAdmin") from _call_sandbox_interior_navigate_to_97
                call hour_passes() from _call_hour_passes_103
                return()

            #####################################################################
            #              CHAT
            #####################################################################
            #####################################################################
            #              CHAT INTERCEPTS
            #####################################################################

            elif _return == "Chat":
                mc "\"I hope everything is well, worthy Sub-Administrator...\""                
                "Sub-Administrator Orlok" "\"I do not have time for idle conversation...\""
                "Sub-Administrator Orlok" "\"I am a very busy Civil Servant.\""
                return()

            elif _return == "Pet Exemption":
                call cutscene_moira("case_presentation") from _call_cutscene_moira_10
                $ GAME.mc.hasDone("case_presentation")
                call sandbox_interior_navigate_to("LOCArellartiAdmin") from _call_sandbox_interior_navigate_to_98
                call hour_passes() from _call_hour_passes_104
                return()

            elif _return == "Pet Certificate":
                call cutscene_moira("certificate_presentation") from _call_cutscene_moira_11
                $ moira.hasDone("certificate_shown")
                call sandbox_interior_navigate_to("LOCArellartiAdmin") from _call_sandbox_interior_navigate_to_99
                call hour_passes() from _call_hour_passes_105
                return()

#####################################################################
#					PET OWNER - ARELLARTI PLAZA
#####################################################################
label interact_petOwner(interaction, item = False, tags=[]):

    #####################################################################
    #              INTERACT
    #####################################################################
    if interaction == "interact":
        $ mCondOptions = [
            "Pet Talk/t", "tris.isHere()",
            "Praise Pet/p", "'intro_petOwner' in GAME.mc.done",
            "Rumours/r", "'pet_praised' in GAME.mc.done",
            "Chat/c", "True",
            "Done/x", "True"
        ]

        # Compile options

        while True:
            call screen menu_interactive_scr(" ", mCondOptions, [])
            play sound "audio/click.wav"
            if _return == "Done":
                return()

            #####################################################################
            #                IDLETALK
            #####################################################################

            elif _return == "Pet Talk":
                $ chat = [
                    [["ACTMC"],"any", "DIAPet001", {}, "True", [],
                    [ "pto", "<Pets have become more expensive of late...|Voronian pets are hard to come by.|Twin pets are valued highly!>",
                    "mc", "<Well,...|Interesting...|Ahem...>"],                 
                    ],
                    [["ACTMC"],"any", "DIAPet002", {}, "True", [],
                    [ "pto", "<There is an excellent Pet Trainer here on Arellarti Station.>",
                    "mc", "<I see.>"]],

                    [["ACTMC"],"any", "DIAPet003", {}, "True", [],
                    [ "pto", "<Pets can be a time consuming hobby.>",
                    "mc", "<Undoubtedly.>"]],

                    [["ACTMC"],"any", "DIAPet004", {}, "True", [],
                    [ "pto", "<There is a Ponygirl Tournament at The Dome soon.>",
                    "pto", "I plan to enter my Pet into the Tournament.",
                    "mc", "<Interesting...>"]],

                    [["ACTMC"],"any", "DIAPet005", {}, "True", [],
                    [ "None", "<You hear no interesting rumours...|A pet pageant is planned for the Dome next month...|Voronian pets are especially popular at the moment...|Grelak's Pet Training School offers discount rates at the moment...>",
                    "mc", "<Hmmm...>"]
                    ]
                ]
                call npc_talk(GAME.mc, chat) from _call_npc_talk_29 

            #####################################################################
            #                IDLETALK
            #####################################################################

            elif _return == "Praise Pet":
                mc "\"That's a nice pet you have there.\""
                pto "\"Do you think so?\""
                pto "\"Have a closer look...\""
                hide screen displayPresentActors
                scene expression("06_cutscenes/cutscene_pet_owner.png") with fade
                window hide  
                pause   
                mc "\"Nice.\""
                "Pet Owner" "\"A Tarakian!\""
                "Pet Owner" "\"Those are not easy to train.\""
                mc "\"I can imagine that.\""
                mc "{i}\"These Krell are weird...\"{/i}"
                scene room_arellarti_plaza_smart with fade 
                show screen displayPresentActors("LOCArellartiStationPL")
                $ GAME.mc.hasDone("pet_praised")
                $ GAME.galleryAdd(60)
                return()


            #####################################################################
            #                IDLETALK
            #####################################################################

            elif _return == "Rumours":
                if GAME.questSys.inProgress('QID_SERAPHINE_ARELLARTI_INQUIRE'):
                    mc "\"Hello.\""
                    pto "\"You again.\""
                    mc "\"I am a researcher investigating unusual space phenomena.\""
                    pto "\"Phhh, Research.\""
                    pto "\"A mostly unprofitable venture.\""
                    mc "\"Have you heard of any anomalous events in this System lately?\""
                    pto "\"There was an incident not long ago...\""
                    mc "\"What kind of incident?\""
                    pto "\"Unusual occurrences in Arellati are Krell business only.\""
                    $ GAME.mc.hasDone("arellarti_inquire")
                    mc "\"Well, thanks, anyway.\""
                    scene room_arellarti_plaza_smart with fade 
                    call quest_updater() from _call_quest_updater_227 
                    return()

                elif GAME.questSys.isActive('QID_SERAPHINE_ARELLARTI_PET') and "pet_connection" in GAME.mc.done:         
                    if not GAME.mc.hasDone("princess_info"):
                        pto "\"I might have some special information for a fellow Pet owner...\""
                        mc "\"I am listening...\""
                        pto "\"There are rumours of a special Pet for Sale soon...\""
                        mc "\"Really?\""
                        pto "\"An Outlander of sorts.\""
                        pto "\"Supposed to be a real Princess too.\""
                        mc "\"Interesting...\""
                        pto "\"Hiding out in the Asteroid belt with her ship...\""
                        mc "\"How would you know all that?\""
                        pto "\"Our interceptors have detected an SOS message on a tightbeam hyperspace channel.\""
                        pto "\"It was directed at our closest neighbouring Galaxy!\""
                        pto "\"Can you imagine that!\""
                        mc "\"Extraordinary...\""
                        mc "{i}\"A message to the Milky Way!\"{/i}"
                        pto "\"A group of Lashers has been sent to retrieve her.\""
                        mc "\"No doubt they'll catch her soon...\""
                        mc "{i}\"I must foil their plan and rescue the Princess!\"{/i}"
                        call quest_updater() from _call_quest_updater_228 
                        return()
                    elif GAME.questSys.isDone('QID_SERAPHINE_ARELLARTI_FIND'):
                        pto "\"They say the Princess has been snatched by an unknown vessel!\""
                        mc "\"Really?\""
                        pto "\"Yes.\""
                        pto "\"Our forces are hot on the heels of this perpetrator...\""
                        pto "\"He didn't consider Rule of Commerce Nr. 15.\""
                        mc "\"Which is?\""
                        pto "\"Stealing from a Krell is a profit you regret!\""
                        mc "\"I see.\""
                    else:
                        pto "\"They have not located that Princess yet...\""
                        pto "\"I would really like to add her to my pet collection...\""
                        mc "\"I see...\""
                else:
                    pto "\"There is nothing special going on...\""
                    pto "\"Too calm if you ask me.\""
                    pto "\"Tumultuous times make for better business...\""
                    mc "\"Indeed.\""

                scene room_arellarti_plaza_smart with fade 
                
            #####################################################################
            #                IDLETALK
            #####################################################################

            elif _return == "Chat":

                if GAME.questSys.inProgress('QID_KRELL_KICKOFF') and GAME.questSys.isActive('QID_SERAPHINE_ARELLARTI_FIND'):
                    mc "\"Greetings.\""
                    pto "\"Greetings, Human.\""
                    pto "\"I trust your Pet training is going well?\""
                    mc "\"Going along nicely...\""
                    pto "\"Good to hear.\""
                    mc "\"Listen, I plan to augment my pet at, ahem... Kranor Biolabs.\""
                    mc "\"You'd not happen to know someone who could introduce me?\""
                    pto "\"Never dealt with that Facility.\""
                    pto "\"They are too secretive for my taste.\""
                    pto "\"Something weird going on there if you ask me...\""
                    pto "\"Might even be run by the Lizards of Zebulon III...\""
                    mc "\"Do you know anyone else doing business there?\""
                    pto "\"Now that you ask...\""
                    pto "\"There was a Trader I remember coming from there.\""
                    mc "\"What was his name?\""
                    pto "\"I can't recall..\""
                    pto "\"He had a nice Pet though.\""
                    mc "\"How did she look like?\""
                    pto "\"Human.\""
                    pto "\"And red hair...\""
                    pto "\"She wore a tag with the name 'Verity' I think...\""
                    mc "\"That is interesting...\""
                    pto "\"He refused to sell her to me...\""
                    mc "\"What a pity...\""
                    mc "\"Well, I have to be on my way now...\""
                    pto "\"Goodbye.\""
                    $ GAME.mc.hasDone('pet_owner_lab_talk')
                    queue sound "audio/notify.wav"
                    mc "{i}\"That is interesting...\"{/i}"
                    mc "{i}\"I should ask around in Iltari Station...\"{/i}"
                    mc "{i}\"I remember hearing the name 'Verity' somewhere...\"{/i}"
                    call quest_updater() from _call_quest_updater_229 
                    return()

                #####################################################################
                #                CHAT INTERCEPTS
                #####################################################################
                if not GAME.questSys.isActive("QID_SERAPHINE_ARELLARTI_PET"):
                    pto "\"I have no time for unproductive chatter, Human.\""
                    pto "\"I am busy with my pet...\""
                    mc "\"Sorry to disturb you.\""
                    pto "\"Hrmmpff...\""
                    $ GAME.mc.hasDone("intro_petOwner")
                    return()

                if GAME.questSys.inProgress('QID_MOIRA_SUB_PET_KICKOFF'):
                    queue sound "audio/notify.wav" 
                    pto "\"Ah, my fellow Pet Owner...\""
                    pto "\"How are things going with your Valkoran Pet?\""
                    mc "\"Quite well...\""
                    pto "\"Remember to have a firm hand.\""
                    mc "\"Ah, yes...\""
                    mc "\"Speaking of which, I could use some advice...\""
                    pto "\"What is it?\""
                    mc "\"I have a, ahem...pet which was in possession of an Exemption 41/B.\""
                    pto "\"A quite difficult one to obtain, I might say...\""
                    pto "\"She must have been very well trained...\""
                    mc "\"It has been revoked due to some unfortunate incident...\""
                    mc "\"And I need to renew it...\""
                    pto "\"You should talk to the Arellarti Pet Office.\""
                    mc "\"Where can I find the Pet Office?\""
                    pto "\"It is in the Admin Building in the Main Docking Area.\""
                    mc "\"I see...\""
                    pto "\"Remember to take the Pet for which you want to apply there with you...\""
                    pto "\"And ask for Sub-Administrator Orlok...\""
                    mc "\"Thank you for the information.\""
                    pto "\"To future business...\""
                    $ GAME.mc.hasDone("exemption_help")
                    call hour_passes() from _call_hour_passes_106
                    call quest_updater() from _call_quest_updater_230
                    return()

                if moira.isAt() == "LOCPetwalk" and "pet_owner_comment" not in moira.doneToday:
                    $ moira.hasDoneToday("pet_owner_comment")
                    queue sound "audio/notify.wav"
                    pto "\"Interesting Pet!\""
                    pto "\"Can I have a closer look?\""
                    queue sound "audio/slap.wav"
                    moi "\"Keep your fingers to yourself!\"" with vpunch 
                    pto "\"Oh, I see.\""
                    pto "\"The Pet you have problems with...\""
                    mc "\"Ahem, yes...\""
                    $ renpy.say(pto,  vary("\"Might I suggest a <Dociliation Gag|Behaviour Plug|Refresher Pet Course>... \""))
                    pto "\"That often works wonders...\""
                    mc "\"I'll take it under advisement...\""
                    moi "\"Hrmmmpff....\""
                    return()
                #####################################################################
                #				REGULAR CHAT
                #####################################################################
                $ chat = [
                    [["ACTMC"],"any", "DIAArellartiGossip002", {}, "True", [],
                    [ "pto", "<The 9th Rule Of Commerce is 'Expand Or Perish'.|The 12th Rule of Commerce Is 'Everyone For Himself'.|The 35th Rule of Commerce is 'A Defective Bot can still be sold'|The 23rd Rule of commerce is 'There Is Always A Greater Fool'|The 62nd Rule of Commerce is 'Every Official has His Price'>",
                    "mc", "<Indeed...>"]
                    ]                                                                      
                ]

                call npc_talk(GAME.mc, chat) from _call_npc_talk_30 
    return()

#####################################################################
#					PET OWNER 1 - DOME PLAZA				
#####################################################################
label interact_petOwner1(interaction, item = False, tags=[]):
    #####################################################################
    #              GREETINGS
    #####################################################################
    if seraphine.isAt() == "LOCPetwalk" and not "intro_sera_ptkr1" in seraphine.done:
        $ seraphine.hasDone("intro_sera_ptkr1")
        queue sound "audio/notify.wav"
        ptkr1 "\"An impressive Pet you have here, Human!\""
        queue sound "audio/bell_small.wav"
        ser "\"Nnnggg...!\"" with vpunch
        mc "\"Krogneath sold her to me for 20 Million Credits.\""
        ptkr1 "\"An appropriate price for sure.\""
        ptkr1 "\"You wouldn't want to happen to sell her?\""
        mc "\"Ahem, not at the moment...\""
        queue sound "audio/bell_small.wav"
        ser "\"Nnnggg...nnggg!\"" with vpunch
        queue sound "audio/notify.wav"
        mc "{i}\"Very tempting offer...\"{/i}"
        mc "{i}\"But I better not give that impression to Seraphine...\"{/i}"
        return()

    elif not GAME.mc.hasDone("intro_ptkr1"):
        queue sound "audio/notify.wav"
        ptkr1 "\"Greetings Human.\""
        mc "\"Ahem, ... Greetings.\""
        ptkr1 "\"Very rare to see one of your kind without a leash in the Dome.\""
        mc "\"I am an Emissary of Krogneath.\""
        ptkr1 "\"Yes, I've heard of him.\""
        ptkr1 "\"The presentation of the Princess caused quite a commotion.\""
        ptkr1 "\"Krogneath will go far in the Council.\""
        mc "\"Indeed.\""
        ptkr1 "\"Very well then, may your business prosper, Human.\""
        mc "\"Same to you.\""
        return()

    #####################################################################
    #              INTERACT
    #####################################################################
    if interaction == "interact":
        $ mCondOptions = [
            "Chat/c", "True",
            "Done/x", "True"
        ]

        # Compile options

        while True:
            call screen menu_interactive_scr(" ", mCondOptions, [])
            play sound "audio/click.wav"
            if _return == "Done":
                return()
    
            #####################################################################
            #                IDLETALK
            #####################################################################
            elif _return == "Chat":

                #####################################################################
                #                CHAT INTERCEPTS
                #####################################################################
                if nimhe.isAt() == "LOCPetwalk" and not "intro_nimhe_ptkr1" in nimhe.done:
                    queue sound "audio/notify.wav"
                    ptkr1 "\"That is an unusual Pony you have there...\""
                    ptkr1 "\"I have never seen that kind...\""
                    nim "\"Nnnngggh...!\"" with vpunch
                    mc "\"I am thinking about entering her into the Races...\""
                    ptkr1 "\"That would be something.\""
                    ptkr1 "\"I hope they open Registration again soon...\""
                    $ nimhe.hasDone("intro_nimhe_ptkr1")
                    return()

                #####################################################################
                #				REGULAR CHAT
                #####################################################################
                $ chat = [
                    [["ACTMC"],"any", "DIADomeGossip001", {}, "True", [],
                    [ "Pet Owner", "<Valkoran Pets are hard to come by...|Valkoran Pets are intelligent but easy to distract...|This Pet was an Acolyte at the Grand Library!>",
                    "mc", "<Indeed...>"]
                    ]                                                                   
                ]

                call npc_talk(GAME.mc, chat) from _call_npc_talk_31 
    return()


#####################################################################
#					PET OWNER 2 - DOME PLAZA				
#####################################################################
label interact_petOwner2(interaction, item = False, tags=[]):
    #####################################################################
    #              GREETINGS
    #####################################################################
    if seraphine.isAt() == "LOCPetwalk" and not "intro_sera_ptkr2" in seraphine.done:
        $ seraphine.hasDone("intro_sera_ptkr2")
        queue sound "audio/notify.wav"
        ptkr2 "\"The Imperial Princess!\""
        ptkr2 "\"Impressive!\""
        queue sound "audio/bell_small.wav"
        ser "\"Nnnggg...!\"" with vpunch
        mc "\"I paid a hefty price for her.\""
        queue sound "audio/bell_small.wav"
        ser "\"Nnnggg...!!!\"" with vpunch
        ptkr2 "\"Princesses make excellent status symbols.\""
        ptkr2 "\"But sometimes I wonder whether they are worth the effort...\""
        mc "\"Yes, very high maintenance...\""
        queue sound "audio/bell_small.wav"
        ser "\"Nnnggg...nnggg!\"" with vpunch
        queue sound "audio/notify.wav"
        ptkr2 "\"May your business flourish...\""
        mc "\"Good day to you too...\""
        return()

    elif not GAME.mc.hasDone("intro_ptkr2"):
        queue sound "audio/notify.wav"
        ptkr2 "\"Greetings Human.\""
        mc "\"Ahem, ... nice Pet.\""
        mc "\"A Tarakian Female?\""
        ptkr2 "\"Yes.\""
        ptkr2 "\"And very strong.\""
        ptkr2 "\"She served in the Tarakian Palace Guard.\""
        mc "\"Impressive.\""
        ptkr2 "\"I am considering entering her into the Races.\""
        ptkr2 "\"Unfortunately the Racing equipment Shop is closed at the moment.\""
        mc "\"Is it?\""
        ptkr2 "\"Yes.\""
        ptkr2 "\"It unfairly favors those Krell who already own customized Pony Outfits.\""
        mc "\"I see.\""
        return()

    #####################################################################
    #              INTERACT
    #####################################################################
    if interaction == "interact":
        $ mCondOptions = [
            "Chat/c", "True",
            "Done/x", "True"
        ]

        # Compile options

        while True:
            call screen menu_interactive_scr(" ", mCondOptions, [])
            play sound "audio/click.wav"
            if _return == "Done":
                return()
    
            #####################################################################
            #                IDLETALK
            #####################################################################

            elif _return == "Chat":

                #####################################################################
                #                CHAT INTERCEPTS
                #####################################################################

                if nimhe.isAt() == "LOCPetwalk" and not "intro_nimhe_ptkr2" in nimhe.done:
                    queue sound "audio/notify.wav"
                    ptkr2 "\"An interesting Pony you have there with you...\""
                    ptkr2 "\"She looks like she is a handful...\""
                    nim "\"Nnnngggh...!\"" with vpunch
                    mc "\"We are working on that...\""
                    ptkr2 "\"The Pony Shop has some nice bits for unruly Ponies...\""
                    ptkr2 "\"I wish it would open up again...\""
                    ptkr2 "\"I myself need some conditioning plugs for my Tarakian Pet...\""
                    mc "\"Is she misbehaving?\""
                    ptkr2 "\"Tarakian Pets can be quite volatile if not well trained...\""
                    mc "\"I see...\""
                    $ nimhe.hasDone("intro_nimhe_ptkr2")
                    return()

                #####################################################################
                #				REGULAR CHAT
                #####################################################################
                $ chat = [
                    [["ACTMC"],"any", "DIADomeGossip100", {}, "True", [],
                    [ "Pet Owner", "<Tarakian Pets are known for their strength and endurance...|Many Tarakian Females work as Bodyguaguards for the Krell...|Tarakian Pirates we captured are sometimes up for Indentured Service...>",
                    "mc", "<Indeed...>"]
                    ]                                                                   
                ]

                call npc_talk(GAME.mc, chat) from _call_npc_talk_32 
    return()

#####################################################################
#					PONY KRELL - DOME PLAZA				
#####################################################################
label interact_ponyKrell(interaction, item = False, tags=[]):
    #####################################################################
    #              GREETINGS
    #####################################################################
    if not GAME.mc.hasDone("intro_ponyKrell"):
        queue sound "audio/notify.wav"
        pnkr "\"A Human Trader, how rare in this place.\""
        mc "\"Ahem, ... Greetings.\""
        mc "\"I work for Krogneath.\""
        pnkr "\"Yes, a most worthy Krell.\""
        pnkr "\"It is rumoured he might make it into the Trade Council...\""
        mc "\"I see.\""
        pnkr "\"How can I be of Service?\""
        mc "\"What is this place.\""
        pnkr "\"The Bit and Bridle Pony Shop.\""
        mc "\"Can I have a look?\""
        pnkr "\"We are undergoing a reorganization of stock...\""
        mc "\"Why?\""
        pnkr "\"A devious competitor has alleged I sold illegal Pony Gear...\""
        mc "\"Most devious.\""
        pnkr "\"But a clever move...\""
        pnkr "\"In any case, I need to review all my stock now and recertify...\""
        mc "\"Too bad.\""
        pnkr "\"I also run the Race Registry in the Dome though.\""
        pnkr "\"Just ask once we have reopened...\""
        mc "\"Good to know!\""
        return()
    #####################################################################
    #              INTERACT
    #####################################################################
    if interaction == "interact":
        $ mCondOptions = [
            "Chat/c", "True",
            "Register Pony/r", "True",
            "Done/x", "True"
        ]

        # Compile options

        while True:
            call screen menu_interactive_scr(" ", mCondOptions, [])
            play sound "audio/click.wav"
            if _return == "Done":
                return()

            #####################################################################
            #                IDLETALK
            #####################################################################

            elif _return == "Register Pony":
                pnkr "\"I am still reorganizing my business...\""
                mc "\"Ah, right.\""
                queue sound "audio/notify.wav"
                "Note: Testing ongoing...not unlocked yet in V1.50 BETA"

            #####################################################################
            #                IDLETALK
            #####################################################################

            elif _return == "Chat":

                #####################################################################
                #                CHAT INTERCEPTS
                #####################################################################

                #####################################################################
                #				REGULAR CHAT
                #####################################################################
                $ chat = [
                    [["ACTMC"],"any", "DIADomePony001", {}, "True", [],
                    [ "pnkr", "<Tarakian Ponies have the most stamina..|Active plugs are prohibited at racing now...|Training a racing Pony is expensive...|Selection of the right bit is crucial for a Pony...>",
                    "mc", "<Indeed...|I see...|Interesting...>"]
                    ]                                                                   
                ]

                call npc_talk(GAME.mc, chat) from _call_npc_talk_33 
    return()



#####################################################################
#					SHADY KRELL - DOME PLAZA				
#####################################################################
label interact_shadyKrell(interaction, item = False, tags=[]):
    #####################################################################
    #              GREETINGS
    #####################################################################


    if seraphine.isAt() == "LOCPetwalk" and "intro_shkr" not in seraphine.done:
        $ seraphine.hasDone("intro_shkr")
        shkr "\"Impressive Pet!\""
        mc "\"Thank you...\""
        queue sound "audio/bell_small.wav"
        ser "\"Nnnnng...!\""
        return()

    elif seraphine.isAt() != "LOCPetwalk"  and  "intro_shkr" not in seraphine.done:
        shkr "\"Move along, Human.\""
        return()

    elif nimhe.isAt() == "LOCPetwalk" and "intro_shkr" not in nimhe.done:
        $ nimhe.hasDone("intro_shkr")
        shkr "\"That is an unusual Pet you have here!\""
        mc "\"Thank you...\""
        queue sound "audio/bell_small.wav"
        nim "\"Nnnnng...nnnghh!\""
        return()

    elif not GAME.mc.hasDone("intro_shkr"):
        queue sound "audio/notify.wav"
        shkr "\"Greetings.\""
        mc "\"I am Captain [GAME.mc.name], Emissary of Krogneath.\""
        shkr "\"Ah, I see.\""
        shkr "\"A Human of means.\""
        shkr "\"You wouldn't want to sell that Princess?\""
        mc "\"Sorry, no.\""
        mc "\"Speaking of business, what are you offering here?\"" 
        shkr "\"Anything a Krell of means, or Human for that matter, might require...\"" 
        shkr "\"I specialize in Betting.\""    
        mc "\"A bookmaker?\""
        shkr "\"Nothing so simple...\""
        shkr "\"An influencer of outcomes, one might say...\""
        mc "\"I see...\""
        shkr  "\"Contact me if you require my services...\""
        mc "\"I will...\""
        return()
    
    #####################################################################
    #              INTERACT
    #####################################################################
    queue sound "audio/notify.wav"
    shkr "\"Hello again...\""
    $ insiderinfo_done = False
    if "betting_intro" in bb_2.done and "insider_info" not in GAME.mc.doneToday:
        $ insiderinfo_done = True
    if interaction == "interact":
        $ mCondOptions = [
            "Chat/c", "True",
            "Insider Info/f", "insiderinfo_done",
            "Buy Cheers/b", "'betting_intro' in bb_2.done",
            "Done/x", "True"
        ]

        # Compile options

        while True:
            call screen menu_interactive_scr(" ", mCondOptions, [])
            play sound "audio/click.wav"
            if _return == "Done":
                return()

            #####################################################################
            #              INFLUENCE RACE
            #####################################################################
            elif _return == "Insider Info" and "insider_info" in GAME.mc.doneToday:
                shkr "\"You have the Race Data already.\""
                shkr "\"Go place some bets...\""

            elif _return == "Insider Info":
                queue sound "audio/notify.wav"
                mc "\"I'd like to buy some, ahem... insights...\""
                $ amount = 50000
                $ renpy.say (shkr, "\"That will cost you {:,} Cr.\"".format(amount))
                queue sound "audio/notify.wav"
                call simple_notify("INSIDER INFO", "Buy at {:,} Cr".format(amount), ["Pay", "Decline"], "05_gui/ico_gui_cup.png") from _call_simple_notify_122
                if _return == "Pay" and GAME.money > amount:
                    call transaction("Betting Info", -amount, True) from _call_transaction_56
                    mc "\"Here you go!\""
                    shkr "\"May the Odds be in your favour...\""
                    $ GAME.mc.hasDoneToday("insider_info")
                    queue sound "audio/notify.wav"
                    call simple_notify("DATA RECEIVED", "Insider Information Day [GAME.day]", ["Continue"], "08_items/ico ITMBettingSlip.png") from _call_simple_notify_123
                    return()
                elif _return == "Pay" and GAME.money <= amount:
                    mc "\"I lack the funds at the moment...!\""
                    shkr "\"Don't wait too long to come up with the money...\""
    
                else:
                    mc "\"Some other time...\""
                    shkr "\"Suit yourself.\""

            #####################################################################
            #              BUY CHEERS
            #####################################################################
            elif _return == "Buy Cheers":

                # data init 
                $ GAME.initTodaysRace()
                $ race = GAME.racingSys.getTodaysRace()
                $ ponyNames = [x.name.lower() for x in race.roster if x]

                # dialopue
                if not shadyKrell.hasDone("intro_influence"):
                    shkr "\"Need some support for the Races?\""
                    mc "\"How does this work?\""
                    shkr "\"I can push the crowd to support your favourite.\""
                    mc "\"How so?\""
                    shkr "\"I have a group of claqueurs in the crowd...\""
                    shkr "\"They can incite the crowd to cheer for a specific Pony...\""
                    shkr "\"Works best if it is done on the same day as the Race.\""
                    shkr "\"That can have a huge influence on the outcome for the race...\""
                    mc "\"I see...\""
                    shkr "\"You'll get five cheers a Race for 150,000...\""
                    mc "\"That is pretty steep...\""
                    shkr "\"Imagine the betting wins...\""
                elif race.cheers:
                    shkr "\"You already bought cheers for today's race...\""
                    shkr "\"Buying more would really attract attention...\""
                else:
                    shkr "\"Need support for the Races again?\""
                    mc "\"That would be helpful...\""

                queue sound "audio/notify.wav"
                
                $ PoniesCap= [ponyracer.capitalize() for ponyracer in ponyNames]
                
                call larger_notify("SELECT PONY TO PUSH", "Which Pony would you like to push today?", PoniesCap, "side dome_shady_krell") from _call_large_notify_124p
                $ favourite = _return

                #$ favourite = renpy.input("Name of Pony", ponyNames[0])
                #if favourite.lower() in ["exit", "none", "no pony", "no one"]:
                    #shkr "\"Another time then...\""
                #elif favourite.lower() not in ponyNames:
                    #queue sound "audio/notify.wav"
                    #shkr "\"A Pony named '[favourite]' is not racing today...\""
                    #$ ponies = ", ".join(ponyNames)
                    #shkr "\"On the roster are: [ponies]\""
                #else:
                # CR-2145 START
                $ favourite = favourite.title()
                $ pony = [x for x in race.roster if x.name.lower() == favourite.lower()][0]
                shkr "\"[favourite], hmm? A good selection.\""
                shkr "\"3 Cheers will cost you 150,000 Cr.\""
                queue sound "audio/notify.wav"
                call simple_notify("INFLUENCE RACE", "3 cheers for [favourite], 150,000 Cr.", ["Buy", "Decline"], "08_items/ico ITMBettingSlip.png") from _call_simple_notify_124
                if _return == "Buy" and GAME.money >= 150000:
                    mc "\"Here you go!\""
                    call transaction("Race Cheers", -150000, True) from _call_transaction_57
                    $ race.cheers += [pony]*3
                    shkr "\"An excellent choice!\""
                    shkr "\"May your endeavours be prosperous.\""
                elif _return == "Buy":
                    mc "\"Ahem, I lack the funds for that...\""
                    shkr "\"Sell some stuff...\""
                    shkr "\"Return if you have the money...\""
                       
                else:
                    mc "\"I'll think about it...\""
                    shkr "\"Don't think too long...\""
                    shkr "\"The Early Krell catches the Drilith...\""
                return()
                # CR-2145 END
            #####################################################################
            #                IDLETALK
            #####################################################################

            elif _return == "Chat":

                #####################################################################
                #                CHAT INTERCEPTS
                #####################################################################

                #####################################################################
                #				REGULAR CHAT
                #####################################################################
                $ chat = [
                    [["ACTSHKR"],"any", "DIAShadyKrell001", {}, "True", [],
                    [ "shkr", "<There is a lot of money to be made in the Races...|The popularity of Pony Racing has soared lately...|There is a race almost every day...|Rumours can influence the outcome of a Races...|A well placed ad might make the crowd cheer for your Pony...|I lend money at only 12 points...|I can provide significant influence on race outcomes...|My services are effective but not cheap...>",
                    "mc", "<I see...>"]
                    ]                                                                   
                ]
                # CR-2146 START
                call npc_talk(shadyKrell, chat) from _call_npc_talk_34 
                # CR-2146 END
    return()









